wok-6.x view syslinux/stuff/iso2exe/bootiso.S @ rev 19613

Up: libmpdclient (2.10)
author Alexander Medvedev <devl547@gmail.com>
date Mon Jan 09 19:34:43 2017 +0000 (2017-01-09)
parents 5ba4b4fd03bc
children e619bff66a02
line source
1 .text
2 .code16
3 .org 0
4
5 CODESZ = 0x8000 // 16 sectors = 32Kb
6 #define EXEADRS(x) x+0xC0
7 #define EXELOC(x) x-0x40
8 #define EXESTR(x) x-0x7F40
9
10 .globl _start
11 _start:
12 decw %bp // Magic number: MZ
13 popw %dx
14 jmp start0 // Bytes on last page of file
15 .word (CODESZ+511)/512 // Pages in file
16 .word 0 // Relocations
17 .word (end_header-_start)/16 // Size of header in paragraphs
18 .word 4064-(CODESZ/16) // Minimum extra paragraphs needed
19 .word 4064-(CODESZ/16) // Maximum extra paragraphs needed
20 .word 0xFFF0 // Initial (relative) SS value
21 .word 0xFFFE // Initial SP value
22 .word 0 // Checksum
23 .word EXEADRS(exestart) // Initial IP value
24 .word 0xFFF0 // Initial (relative) CS value
25 initramfssize:
26 .word 0 // File address of relocation table
27 fdcnt: // Overlay number
28 .byte 0 // Bootstrap floppy sector count
29 .ascii "slitaz"
30
31 /////////////////////// Master Boot Record code //////////////////////////////
32
33 moved = 0x8000
34 start0:
35 pushw %dx // restore %sp
36 incw %bp // restore %bp
37 xorw %bx, %bx
38 movw %bx, %ds
39 movb $0x7C, %bh
40 pushw %bx // return address
41 pushaw
42 movw %sp, %bp
43 pushw %es // save %es:%di
44 cld
45 sti
46 pushw %ds
47 popw %es
48 call setreg
49 rep
50 movsw
51 movw $0x80, %dx
52 ljmp $0, $moved+start2
53 .byte 0
54 // .org 60
55 // .long 0x0080 // PE header offset
56 .org 64
57 end_header:
58 comstart:
59 .word 0
60
61 .org 66
62 dxloop:
63 start2:
64 call readsector1 // look for the boot device
65 repe
66 cmpsw
67 je dxfound
68 movb $0, %cl // ch = 0
69 addb $0x7D, %dl // try every hard disk
70 jno dxloop
71
72 dxfound:
73 call readsectorX // read isolinux boot sector
74 movw %dx, 10(%bp)
75 cmpw (%bx), %cx
76 jnc puts // read fail or no isohydrid boot sector
77 popw %es
78 popa // isolinux boot needs %es:%di and %dx
79 putsret:
80 ret
81
82 putstrlp:
83 movw $7, %bx
84 movb $0xE, %ah
85 int $0x10
86 error:
87 lodsb
88 cmp $1, %al
89 jg putstrlp
90 jz putsret
91 puts:
92 movb $0x80, %ah
93 xchgw %ax, %si
94 jnc error
95 halt:
96 hlt
97 jmp halt
98 nobsmsg:
99 .asciz "No isolinux."
100
101 .org 0x0080
102 ////////////////////////////// EXE/PE header //////////////////////////////////
103
104 .org 0x01A0
105 readsectorX: // read isolinux boot sector
106 movb $0xA5, %cl // patched by installer
107 readsector1:
108 andb $0x83, %dl // disk and floppy disk
109 movw %cx, (%bx)
110 incw %cx
111 movw $0x201, %ax
112 int $0x13
113 setreg:
114 movw %bx, %si
115 movw $moved, %di
116 movw $0x0100, %cx
117 movb $nobsmsg, %al
118 ret
119 .org 0x01B8
120
121 .org 0x7F48
122 ////////////////////////////// DOS EXE code ///////////////////////////////////
123
124 exestart:
125 cld
126 movw $EXEADRS(puts), %bp
127 movw 129, %ax
128 cmpb $0x2F, %al
129 je ishelp
130 cmpw $0x2F20, %ax
131 ishelp:
132 movw $0x3000+EXESTR(help), %ax
133 cwd // clear dx
134 pushw %dx // dos exit()
135 je abort
136 int $0x21 // get DOS version
137 addb $-3, %al
138 movw $0xF000+EXESTR(noDOS3), %ax
139 movw $0x100, %di
140 jc tst386
141 abort:
142 jmp *%bp
143
144 tst386:
145 pushfw // save flags
146 // bits 15 14 13 12 11 10 9 8 7 6 5 4 3 2 1 0
147 // flags 0 NT IOPL OF DF IF TF SF ZF 0 AF 0 PF 1 CF
148 // movb $0xF0, %ah
149 pushw %ax
150 popfw // < 286 : flags[12..15] are forced 1
151 pushfw // = 286 : flags[12..15] are forced 0
152 popw %bx // > 286 : only flags[15] is forced 0
153 popfw // restore flags (IOPL)
154 addb %ah, %bh // test F0 and 00 cases
155 js is86 // NS=386+, NC=286
156 is386:
157 smsww %ax // not privileged
158 andb $1, %al
159 movw $10, %si
160 jne tstvcpi
161 movl %cr0, %eax // privileged
162 incl %eax
163 movb $EXESTR(rmPaging), %al
164 js abort
165 inc %ax
166 //movb $EXESTR(realmodemsg), %al
167 realmode:
168 call *%bp
169 is86:
170 movw comstart-end_header(%di), %si // .com address
171 pushw %di
172 movb $0x7C/2, %ch // 31K-31.5K, > com length
173 rep
174 movsw
175 ret
176
177 CallVCPI:
178 int $0x67
179 testb %ah, %ah
180 xchgw %ax, %cx
181 pushw %si
182 ScanVCPI:
183 popw %si
184 ChkVCPI:
185 NoVCPI:
186 movb $EXESTR(ERRvcpi), %al
187 jne abort
188 lodsb
189 shlw $8, %ax
190 jne CallVCPI
191 VersionVCPI:
192 xchgw %ax, %si // movb $EXESTR(vm86modemsg), %al
193 cmpb $0x40, %cl // EMM386 / VCPI 4.0 mini
194 jnc realmode // %si = 0
195 tstvcpi:
196 pushw %ds
197 movw %si, %ds // %si = 10
198 movw (0x67*4)+2-(16*10)-0x100(%di), %ds
199 lodsw
200 xorw $0x4D45, %ax // EM(MX) or EM(MQ)
201 lodsw
202 lodsw
203 popw %ds
204 jne NoVCPI
205 xorw $0x5858, %ax // XX(X0)
206 call ScanVCPI
207 CmdVCPI:
208 .byte 0x40 // status
209 .byte 0xDE // vcpi present ?
210 .byte 0x46 // version
211 .byte 0
212
213 vm86modemsg:
214 // --------------- Must be in 7F40 7FFF range ------------------------
215 .ascii "86" // 86 mode
216 .byte EXESTR(mode)
217 ERRvcpi:
218 .ascii "VCPI4" // VCPI4?
219 .byte EXESTR(need)
220 rmPaging:
221 .ascii "X" // Xreal mode
222 realmodemsg:
223 .ascii "real" // real mode
224 // --------------- Must be in 7FC0 7FFF range ------------------------
225 mode:
226 .ascii " m"
227 ode:
228 .ascii "ode"
229 .byte EXESTR(eol)
230 noDOS3:
231 .ascii "DOS3" // DOS3?
232 need:
233 .ascii "?"
234 .byte EXESTR(eol)
235 help:
236 .ascii "SliTaz iso boot." // SliTaz iso boot.
237 eol:
238 .ascii "\r\n"
239 .byte 1 // puts will return
240
241 .space 16,0 // ISO md5
242 .org 0x8000
243 ////////////////////////// ISO9660 header /////////////////////////////////////