wok-current view linld/stuff/src/VCPI.ASM @ rev 21984
linld: x86 support
author | Pascal Bellard <pascal.bellard@slitaz.org> |
---|---|
date | Mon Oct 14 11:20:06 2019 +0200 (2019-10-14) |
parents | de6c5f0bf7ea |
children | fcb1de9af8f7 |
line source
1 ;***************************************************************
2 ;****** This file is distributed under GPL
3 ;***************************************************************
4 ;VDPI init:
5 ;Call char* prepare_vcpi(void *pagebuf) first to
6 ;initialize paging tables needed for vm86.
7 ;pagebuf needs to be 8k+4 bytes. Returns ptr to 1st unused byte.
8 ;Then call int get_vcpi_interface(). Returns 1 if ok, 0 if bad.
9 ;
10 ;VCPI use:
11 ;u32* malloc_vcpi(u32 size) - source in HIMEM.CPP
12 ; Returns ptr to mallocated zero-terminated list of 4k page addrs
13 ; Addresses are sorted in ascending order
14 ; Never fails (will die if not enough mem)
15 ;void read2vcpi(int fd, u32* vp, u32 size,
16 ;void* xfer_buf, u16 xfer_size) - source in HIMEM.CPP
17 ; Reads opened fd data into malloc_vcpi'ed memory
18 ; Dies if file isn't exactly 'size' bytes long
19 ; Needs intermediate buffer of exactly Nx4k bytes
20 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs)
21 ; copies 4k from conventional memory to VCPI
22 ;void _vm2rm()
23 ; switches you from vm86 to plain real mode
26 ideal
27 %PAGESIZE 1000
28 %crefref
29 %noincl
30 %nomacs
31 p386
33 ;****** Stuff for declaring descriptors
34 struc descr
35 limit dw ?
36 base0 dw ?
37 base16 db ?
38 type db ?
39 limit16 db ?
40 base24 db ?
41 ends descr
42 macro descriptor name,typ,plevel,present,limit,gran,base
43 ;;name descr <limit and 0ffffh,base and 0ffffh,low (base shr 16),typ or plevel or present,(limit shr 16) or gran,high (base shr 16)>
44 name descr <limit and 0ffffh,base ,0 ,typ or plevel or present,(limit shr 16) or gran,0 >
45 endm
46 ; decriptor types (bit0..4 of descr.type )
47 tss386_avail = 09h
48 data_seg = 00010000b ; data segment
49 expand_down = 00000100b ; =1 limit counts down from base
50 writable = 00000010b ; =1 if write access allowed to data segment
51 code_seg = 00011000b ; code segment
52 conforming = 00000100b ; =1 code can be accesses and executed at any PL
53 readable = 00000010b ; =1 if code also can be read (cannot be ovwritten)
54 ; privilege levels (bit5..6 of descr.type )
55 priv0 = 00000000b
56 priv1 = 00100000b
57 priv2 = 01000000b
58 priv3 = 01100000b
59 ; segment present bit (bit7 of descr.type )
60 is_present = 10000000b
61 not_present = 00000000b
62 ;definition of granularity ( bits6..7 in descr.limit16 )
63 gran_byte = 00000000b
64 gran_page = 10000000b ; 4k granularity
65 use_16 = 00000000b
66 use_32 = 01000000b
68 ;****** rm32,imm16 helpers
69 macro addzx_e rm,i
70 db 66h
71 add rm,i
72 dw 0
73 endm
76 group DGROUP _TEXT,_BSS
77 assume cs:DGROUP,ds:DGROUP
79 segment _BSS byte public use16 'BSS'
81 tss dd ?,? ;enough, we'll never use it anyway
83 ends _BSS
85 segment _TEXT byte public use16 'CODE'
87 label gdt byte
88 gdt_null descr <?> ;0000
89 gdt_vcpi descr <?> ;0008
90 gdt_vcpi2 descr <?> ;0010
91 gdt_vcpi3 descr <?> ;0018
92 descriptor gdt_abs ,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_32),0
93 ;Note: code/data segs must be flagged use16 (i.e. use ip/sp, not eip/esp)
94 ;Note: base addrs will be fixed up in prepare_vcpi()
95 descriptor gdt_code,(code_seg+readable),priv0,is_present,0fffffh,(gran_page+use_16),0
96 global gdt_data:descr
97 descriptor gdt_data,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_16),0
98 descriptor gdt_tss ,tss386_avail ,priv0,is_present,0ffh ,gran_byte ,<offset tss>
99 SEL_VCPI = (gdt_vcpi - gdt_null)
100 SEL_TSS = (gdt_tss - gdt_null)
101 SEL_ABS = (gdt_abs - gdt_null)
102 SEL_CODE = (gdt_code - gdt_null)
103 SEL_DATA = (gdt_data - gdt_null)
105 label gdtr pword
106 gdt_lim dw 0ffffh
107 gdt_base dw offset gdt,0
109 ;Note: layout dictated by vcpi api, don't rearrange!
110 label sw2pm_params byte
111 ;Note: base addrs will be fixed up in prepare_vcpi()
112 label pagedir_laddr dword
113 sw2pm_cr3 dd 1000h
114 sw2pm_gdtr_ptr dw offset gdtr,0
115 sw2pm_idtr_ptr dw offset idtr,0
116 sw2pm_ldtr dw 0 ;we don't need it
117 sw2pm_tr dw SEL_TSS ;vcpi thinks we need it... can't set to 0
118 sw2pm_jumpaddr dd 0
119 dw SEL_CODE
121 vcpi_pm_entry dd 0
122 dw SEL_VCPI
124 label idtr pword
125 idt_lim dw 03ffh ;we won't enable ints,
126 idt_base dd 0 ; so let's leave it the same as for rm
129 ;***************************************************************
130 ;char* prepare_vcpi(void *pagebuf);
131 ;****** Return: AX=>first unused byte in pagebuf
132 ;****** Uses: Flags
133 ;***************************************************************
134 global prepare_vcpi:near
135 proc prepare_vcpi near
137 ;pop ax
138 ;pop bx ;pgbuf
139 ;push bx
140 ;push ax
142 ;Calculate pagedir/page0 addrs, initialize cr3 and pagedir[0]
143 xor eax,eax
144 ; heap_top = prepare_vcpi(malloc_or_die(8*1024+4));
145 mov ah,8*1024/256
146 extrn malloc_or_die:near
147 call malloc_or_die
149 mov edx,cs
150 shl edx,4 ;edx = linear addr of CS
151 mov si,offset gdt_vcpi
152 ; Fix up base of some gdt descriptors
153 ; Note: 'add [dword xx.base0],edx' actually updates 24 bit quantity!
154 ; Do NOT replace with mov!
155 mov ebx,10000h-28h
156 add [dword bx+si+sw2pm_idtr_ptr-gdt_vcpi+28h],edx
157 @@fixup:
158 add [dword bx+si+(gdt_code.base0)-gdt_vcpi+28h],edx
159 add bx,8
160 js @@fixup
161 mov bh,10h
162 add eax,edx
163 and ax,0f000h ;eax = 4k aligned linear addr of pagebuf
164 add eax,ebx ;eax=page0 linear addr
165 add [si+sw2pm_cr3-gdt_vcpi],eax
166 mov edi,eax
167 sub edi,edx
168 mov al,3 ;add present+writable bits
169 mov [bx+di],eax ;stuff it into pagedir[0]
170 push ds
171 pop es ;es:di->page0,es:di+1000h->pagedir
172 ;page directory will use only one entry (4 bytes):
173 ;cr3 => pagedir => page0 => ########
174 ; (1 entry) (1024 => # 4M #
175 ; entries)=> # page #
176 ; => ########
177 ; Return
178 lea ax,[bx+di+4]
179 extrn _heap_top:word
180 mov [_heap_top],ax
181 ;ret
183 endp prepare_vcpi
186 ;***************************************************************
187 ;int get_vcpi_interface();
188 ;****** Return: Z - page mapping for low 640k is 1:1
189 ;****** NZ - otherwise (it's bad)
190 ;****** Uses: Flags
191 ;***************************************************************
192 ;global _get_vcpi_interface:near
193 proc _get_vcpi_interface near
195 ;push si di
197 ; Get and save VCPI pm interface
198 ;mov si,offset gdt_vcpi ;DS:DI => 3 GDT entries for VCPI
199 ;mov di,[si+page0_ofs-gdt_vcpi] ;ES:DI => page0
200 ;push ds
201 ;pop es
202 push di
203 mov ax,0DE01h ;get vcpi pm interface
204 int 67h
205 xchg [vcpi_pm_entry],ebx ;clear ebx
206 ;xor bx,bx
208 ; Check that mapping for low 640k is 1:1
209 pop si ; [page0_ofs]
210 ;cld
211 @@map_chk:
212 lodsd
213 shr eax,12
214 cmp ax,bx
215 jne @@bad
216 inc bx
217 cmp al,((640*1024) shr 12)-1
218 jne @@map_chk
219 ; Return
220 @@bad:
221 ret
222 endp _get_vcpi_interface
225 ;***************************************************************
226 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs);
227 ;***************************************************************
228 ;****** Copies PAGE_SIZE bytes
229 ;****** Uses: Flags
230 ;***************************************************************
231 global vcpi_pm_copy_routine:near
232 proc vcpi_pm_copy_routine near
234 arg dstofs :dword, \
235 srcseg :word, \
236 srcofs :dword = PARAM_SIZE
238 struc pm_regs
239 $$retaddr dw ?
240 $$edi dd ?
241 $$esi dd ?
242 $$ebp dd ?
243 $$esp dd ?
244 $$ebx dd ?
245 $$edx dd ?
246 $$ecx dd ?
247 $$eax dd ?
248 ends
250 ;***************************************************************
251 ;****** Helper: goes into 16bit pm and calls routine (addr on stk)
252 ;***************************************************************
253 mov bp,sp ; ss:bp => struct pm_regs
255 xor ax,ax ; IRET stack for return to vm
256 push ax gs ; (9 dwords)
257 push ax fs ;
258 push ax ds ;
259 push ax es ;
260 push ax ss ;
261 push ebp ; esp
262 pushfd ; eflags: IF saved here
263 push ax cs ;
264 push ax ;\eip
265 push offset @@vm_ret ;/
267 ;;mov [saved_xx],xx ;use if your vcpi trashes bp/etc
269 call switch_to_pm
271 ; Now we are in 16-bit protected mode
272 mov ax,SEL_DATA
273 mov ss,ax
274 ;;mov ds,ax
275 ;;mov es,ax
276 ;;mov fs,ax
277 ;;mov gs,ax
278 assume nothing
279 assume cs:DGROUP
281 ;;mov xx,[saved_xx] ;use if your vcpi trashes bp/etc
282 lea sp,[bp-9*4] ;else we can do this trick with bp
284 ; Call the routine (bp points to params on stack if any)
285 mov bp,[word (pm_regs bp).$$ebp] ;ss:bp => params
286 call do_memcpy_vcpi
288 ; Ok, let's return to vm
289 mov ax,0DE0Ch ; maybe we need whole eax?
290 cli ; to be safe
291 clts ;
292 ;;push SEL_ABS ; vcpi wants ds=all_addrspace
293 ;;pop ds ;
294 call [pword cs:vcpi_pm_entry]
295 @@vm_ret:
296 ; Now we are in vm86 mode. Sregs, esp, eflags (IF) restored from IRET stack
297 ret
299 ;***************************************************************
300 switch_to_pm:
301 assume cs:DGROUP,ds:DGROUP
302 pop [word sw2pm_jumpaddr]
303 ;mov [word sw2pm_jumpaddr+2],0
304 ;mov [word sw2pm_jumpaddr+4],SEL_CODE
305 mov esi,cs
306 shl esi,4
307 addzx_e si,<offset sw2pm_params>
308 mov ax,0DE0Ch ; vcpi: switch to pm
309 cli
310 int 67h
312 ;***************************************************************
313 ;****** Helper: This is where real copy is done
314 ;***************************************************************
315 global do_memcpy_vcpi:near
316 label do_memcpy_vcpi near
318 ; Note: ss:bp => params
319 ; Move data
320 mov al,SEL_ABS
321 mov ds,ax
322 mov es,ax
323 assume nothing
324 assume cs:DGROUP
326 ; Set up target addr:
327 ; replace page mapping for page at 0 so
328 ; that it points to dstofs
329 mov eax,[dstofs]
330 mov al,03h ; writeable, present
331 call @@set_mapping
332 ;push eax ;X we'll need to restore mapping...
333 xor edi,edi ;es:edi => remapped page
335 ; Set up source addr
336 mov esi,[srcofs]
338 ; Do copying
339 xor ecx,ecx
340 mov ch,4096/256
341 ;cld
342 ;; cmp esi,edi
343 ;; jae @@do_copy
344 ;; add esi,ecx ;src<dst: we must do
345 ;; dec esi ; copy backwards to avoid
346 ;; add edi,ecx ; overwrite bug
347 ;; dec edi ;
348 ;; std ;
349 ;;@@do_copy:
350 db 67h ;address width override for esi/edi
351 rep movsb
352 ;; cld
354 ; Restore page mapping for page at 0
355 ;pop eax ;X
356 @@set_mapping:
357 mov esi,[cs:sw2pm_cr3]
358 xchg [esi-1000h],eax ; restore page0[0]
359 mov ecx,cr3 ; reload TLB cache
360 mov cr3,ecx ;
361 ; Return
362 vcpi_ret:
363 ret
365 endp vcpi_pm_copy_routine
366 assume cs:DGROUP,ds:DGROUP
369 ;***************************************************************
370 ;void _vm2rm();
371 ;***************************************************************
372 ;****** Uses: Flags
373 ;***************************************************************
374 global _vm2rm:near
375 proc _vm2rm near
377 ifdef NO386
378 p8086
379 extrn _vcpi:byte
380 test [_vcpi],-1
381 else
382 p386
383 smsw ax ;SMSW cannot be trapped! :-)
384 and al,1 ;MSW_PE
385 endif
386 jz vcpi_ret
387 p386
388 pop ax
389 push cs ;*
390 push ax
391 push si
392 push ds
393 extrn sssp:word
394 mov [sssp],sp
395 ;mov [sssp+2],ss
397 call switch_to_pm
399 ; Now we are in 16-bit protected mode
400 mov ax,SEL_DATA ; load data sregs with limit >=64k
401 mov ss,ax ; or you may get limit violations
402 mov ds,ax ; later in rm
403 ;mov es,ax ; (actually I prefer 4gig limits :-)
404 ;mov fs,ax ;
405 ;mov gs,ax ;
407 ; Black magic here
408 mov eax,cr0
409 and eax,7ffffffeh ; clear PG,P bits
410 mov cr0,eax ; look mommy, we're in rm now!
411 mov cr3,eax ; flush TLB cache
413 ; Now we are in rm, but not yet: have to restore sregs:
414 lss sp,[dword sssp]; SS
415 pop ds ; DS
416 pop si
417 retf ; CS
419 endp _vm2rm
421 ends _TEXT
423 end
425 ;###### END OF FILE ############################################