wok view linld/stuff/src/VCPI.ASM @ rev 20295
Add python-humanize, python-pyajam, python-paho-mqtt
| author | Pascal Bellard <pascal.bellard@slitaz.org> |
|---|---|
| date | Wed Apr 25 16:08:37 2018 +0200 (2018-04-25) |
| parents | e7715725d95b |
| children | 46b511e941a7 |
line source
1 ;***************************************************************
2 ;****** This file is distributed under GPL
3 ;***************************************************************
4 ;VDPI init:
5 ;Call char* prepare_vcpi(void *pagebuf) first to
6 ;initialize paging tables needed for vm86.
7 ;pagebuf needs to be 8k+4 bytes. Returns ptr to 1st unused byte.
8 ;Then call int get_vcpi_interface(). Returns 1 if ok, 0 if bad.
9 ;
10 ;VCPI use:
11 ;u32* malloc_vcpi(u32 size) - source in HIMEM.CPP
12 ; Returns ptr to mallocated zero-terminated list of 4k page addrs
13 ; Addresses are sorted in ascending order
14 ; Never fails (will die if not enough mem)
15 ;void read2vcpi(int fd, u32* vp, u32 size,
16 ;void* xfer_buf, u16 xfer_size) - source in HIMEM.CPP
17 ; Reads opened fd data into malloc_vcpi'ed memory
18 ; Dies if file isn't exactly 'size' bytes long
19 ; Needs intermediate buffer of exactly Nx4k bytes
20 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs)
21 ; copies 4k from conventional memory to VCPI
22 ;void _vm2rm()
23 ; switches you from vm86 to plain real mode
26 ideal
27 %crefref
28 %noincl
29 %nomacs
30 p386
32 ;****** Stuff for declaring descriptors
33 struc descr
34 limit dw ?
35 base0 dw ?
36 base16 db ?
37 type db ?
38 limit16 db ?
39 base24 db ?
40 ends descr
41 macro descriptor name,typ,plevel,present,limit,gran,base
42 ;;name descr <limit and 0ffffh,base and 0ffffh,low (base shr 16),typ or plevel or present,(limit shr 16) or gran,high (base shr 16)>
43 name descr <limit and 0ffffh,base ,0 ,typ or plevel or present,(limit shr 16) or gran,0 >
44 endm
45 ; decriptor types (bit0..4 of descr.type )
46 tss386_avail = 09h
47 data_seg = 00010000b ; data segment
48 expand_down = 00000100b ; =1 limit counts down from base
49 writable = 00000010b ; =1 if write access allowed to data segment
50 code_seg = 00011000b ; code segment
51 conforming = 00000100b ; =1 code can be accesses and executed at any PL
52 readable = 00000010b ; =1 if code also can be read (cannot be ovwritten)
53 ; privilege levels (bit5..6 of descr.type )
54 priv0 = 00000000b
55 priv1 = 00100000b
56 priv2 = 01000000b
57 priv3 = 01100000b
58 ; segment present bit (bit7 of descr.type )
59 is_present = 10000000b
60 not_present = 00000000b
61 ;definition of granularity ( bits6..7 in descr.limit16 )
62 gran_byte = 00000000b
63 gran_page = 10000000b ; 4k granularity
64 use_16 = 00000000b
65 use_32 = 01000000b
67 ;****** rm32,imm16 helpers
68 macro addzx_e rm,i
69 db 66h
70 add rm,i
71 dw 0
72 endm
75 group DGROUP _TEXT,_DATA,_BSS
76 assume cs:DGROUP,ds:DGROUP
78 segment _DATA byte public use16 'DATA'
80 label gdt byte
81 gdt_null descr <?> ;0000
82 gdt_vcpi descr <?> ;0008
83 gdt_vcpi2 descr <?> ;0010
84 gdt_vcpi3 descr <?> ;0018
85 descriptor gdt_abs ,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_32),0
86 ;Note: code/data segs must be flagged use16 (i.e. use ip/sp, not eip/esp)
87 ;Note: base addrs will be fixed up in prepare_vcpi()
88 descriptor gdt_code,(code_seg+readable),priv0,is_present,0fffffh,(gran_page+use_16),0
89 descriptor gdt_data,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_16),0
90 descriptor gdt_tss ,tss386_avail ,priv0,is_present,0ffh ,gran_byte ,<offset tss>
91 SEL_VCPI = (gdt_vcpi - gdt_null)
92 SEL_TSS = (gdt_tss - gdt_null)
93 SEL_ABS = (gdt_abs - gdt_null)
94 SEL_CODE = (gdt_code - gdt_null)
95 SEL_DATA = (gdt_data - gdt_null)
97 label gdtr pword
98 gdt_lim dw 0ffffh
99 gdt_base dw offset gdt,0
101 ;Note: layout dictated by vcpi api, don't rearrange!
102 label sw2pm_params byte
103 ;Note: base addrs will be fixed up in prepare_vcpi()
104 label pagedir_laddr dword
105 sw2pm_cr3 dd 1000h
106 sw2pm_gdtr_ptr dw offset gdtr,0
107 sw2pm_idtr_ptr dw offset idtr,0
108 sw2pm_ldtr dw 0 ;we don't need it
109 sw2pm_tr dw SEL_TSS ;vcpi thinks we need it... can't set to 0
110 sw2pm_jumpaddr dd 0
111 dw SEL_CODE
113 vcpi_pm_entry dd 0
114 dw SEL_VCPI
116 label idtr pword
117 idt_lim dw 03ffh ;we won't enable ints,
118 idt_base dd 0 ; so let's leave it the same as for rm
120 ends _DATA
122 segment _BSS byte public use16 'BSS'
124 label saved_ss_sp dword
125 saved_sp dw ?
126 saved_ss dw ?
128 tss dd ?,? ;enough, we'll never use it anyway
130 ends _BSS
132 segment _TEXT byte public use16 'CODE'
134 ;***************************************************************
135 ;char* prepare_vcpi(void *pagebuf);
136 ;****** Return: AX=>first unused byte in pagebuf
137 ;****** Uses: Flags
138 ;***************************************************************
139 global _prepare_vcpi:near
140 global prepare_vcpi:near
141 proc _prepare_vcpi near
143 ;pop ax
144 ;pop bx ;pgbuf
145 ;push bx
146 ;push ax
147 prepare_vcpi:
149 ;Calculate pagedir/page0 addrs, initialize cr3 and pagedir[0]
150 xor eax,eax
151 ; heap_top = prepare_vcpi(malloc_or_die(8*1024+4));
152 mov cx,8*1024+4
153 extrn malloc_or_die:near
154 call malloc_or_die ;keep cx
156 mov edx,cs
157 shl edx,cl ;edx = linear addr of CS
158 mov si,offset gdt_vcpi
159 ; Fix up base of some gdt descriptors
160 ; Note: 'add [dword xx.base0],edx' actually updates 24 bit quantity!
161 ; Do NOT replace with mov!
162 mov ebx,10000h-28h
163 add [dword bx+si+sw2pm_idtr_ptr-gdt_vcpi+28h],edx
164 @@fixup:
165 add [dword bx+si+(gdt_code.base0)-gdt_vcpi+28h],edx
166 add bx,8
167 js @@fixup
168 mov bh,10h
169 add eax,edx
170 and ax,0f000h ;eax = 4k aligned linear addr of pagebuf
171 add eax,ebx ;eax=page0 linear addr
172 add [si+sw2pm_cr3-gdt_vcpi],eax
173 mov edi,eax
174 sub edi,edx
175 mov al,3 ;add present+writable bits
176 mov [bx+di],eax ;stuff it into pagedir[0]
177 push ds
178 pop es ;es:di->page0,es:di+1000h->pagedir
179 ;page directory will use only one entry (4 bytes):
180 ;cr3 => pagedir => page0 => ########
181 ; (1 entry) (1024 => # 4M #
182 ; entries)=> # page #
183 ; => ########
184 ; Return
185 lea ax,[bx+di+4]
186 extrn _heap_top:word
187 mov [_heap_top],ax
188 ;ret
190 endp _prepare_vcpi
193 ;***************************************************************
194 ;int get_vcpi_interface();
195 ;****** Return: Z - page mapping for low 640k is 1:1
196 ;****** NZ - otherwise (it's bad)
197 ;****** Uses: Flags
198 ;***************************************************************
199 global _get_vcpi_interface:near
200 proc _get_vcpi_interface near
202 ;push si di
204 ; Get and save VCPI pm interface
205 ;mov si,offset gdt_vcpi ;DS:DI => 3 GDT entries for VCPI
206 ;mov di,[si+page0_ofs-gdt_vcpi] ;ES:DI => page0
207 ;push ds
208 ;pop es
209 push di
210 mov ax,0DE01h ;get vcpi pm interface
211 int 67h
212 xchg [vcpi_pm_entry],ebx ;clear ebx
213 ;xor bx,bx
215 ; Check that mapping for low 640k is 1:1
216 pop si ; [page0_ofs]
217 ;cld
218 @@map_chk:
219 lodsd
220 shr eax,12
221 cmp ax,bx
222 jne @@bad
223 inc bx
224 cmp al,((640*1024) shr 12)-1
225 jne @@map_chk
226 ; Return
227 @@bad:
228 ret
229 endp _get_vcpi_interface
232 ;***************************************************************
233 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs);
234 ;***************************************************************
235 ;****** Copies PAGE_SIZE bytes
236 ;****** Uses: Flags
237 ;***************************************************************
238 global call_pm_routine:near
239 proc call_pm_routine near
241 arg dstofs :dword, \
242 srcseg :word, \
243 srcofs :dword = PARAM_SIZE
245 struc pm_regs
246 $$retaddr dw ?
247 $$f dw ?
248 $$edi dd ?
249 $$esi dd ?
250 $$ebp dd ?
251 $$esp dd ?
252 $$ebx dd ?
253 $$edx dd ?
254 $$ecx dd ?
255 $$eax dd ?
256 ends
258 ;***************************************************************
259 ;****** Helper: goes into 16bit pm and calls routine (addr on stk)
260 ;***************************************************************
261 mov bp,sp ; ss:bp => struct pm_regs
263 xor ax,ax ; IRET stack for return to vm
264 push ax gs ; (9 dwords)
265 push ax fs ;
266 push ax ds ;
267 push ax es ;
268 push ax ss ;
269 push ebp ; esp
270 pushfd ; eflags: IF saved here
271 push ax cs ;
272 push ax ;\eip
273 push offset @@vm_ret ;/
275 ;;mov [saved_xx],xx ;use if your vcpi trashes bp/etc
277 call switch_to_pm
279 ; Now we are in 16-bit protected mode
280 mov ax,SEL_DATA
281 mov ss,ax
282 ;;mov ds,ax
283 ;;mov es,ax
284 ;;mov fs,ax
285 ;;mov gs,ax
286 assume nothing
287 assume cs:DGROUP
289 ;;mov xx,[saved_xx] ;use if your vcpi trashes bp/etc
290 lea sp,[bp-9*4] ;else we can do this trick with bp
292 ; Call the routine (bp points to params on stack if any)
293 mov ax,[(pm_regs bp).$$f] ; ss:bp => struct pm_regs
294 mov bp,[word (pm_regs bp).$$ebp] ;ss:bp => params
295 call ax
297 ; Ok, let's return to vm
298 mov ax,0DE0Ch ; maybe we need whole eax?
299 cli ; to be safe
300 clts ;
301 push SEL_ABS ; vcpi wants ds=all_addrspace
302 pop ds ;
303 call [pword cs:vcpi_pm_entry]
304 @@vm_ret:
305 ; Now we are in vm86 mode. Sregs, esp, eflags (IF) restored from IRET stack
306 ret
308 ;***************************************************************
309 switch_to_pm:
310 assume cs:DGROUP,ds:DGROUP
311 pop [word sw2pm_jumpaddr]
312 ;mov [word sw2pm_jumpaddr+2],0
313 ;mov [word sw2pm_jumpaddr+4],SEL_CODE
314 mov esi,cs
315 shl esi,4
316 addzx_e si,<offset sw2pm_params>
317 mov ax,0DE0Ch ; vcpi: switch to pm
318 cli
319 int 67h
321 ;***************************************************************
322 ;****** Helper: This is where real copy is done
323 ;***************************************************************
324 global do_memcpy_vcpi:near
325 label do_memcpy_vcpi near
327 ; Note: ss:bp => params
328 ; Move data
329 mov ax,SEL_ABS
330 mov ds,ax
331 mov es,ax
332 assume nothing
333 assume cs:DGROUP
335 ; Set up target addr:
336 ; replace page mapping for page at 0 so
337 ; that it points to dstofs
338 mov eax,[dstofs]
339 mov al,03h ; writeable, present
340 call @@set_mapping
341 ;push eax ;X we'll need to restore mapping...
342 xor edi,edi ;es:edi => remapped page
344 ; Set up source addr
345 mov esi,[srcofs]
347 ; Do copying
348 xor ecx,ecx
349 mov ch,4096/256
350 ;cld
351 ;; cmp esi,edi
352 ;; jae @@do_copy
353 ;; add esi,ecx ;src<dst: we must do
354 ;; dec esi ; copy backwards to avoid
355 ;; add edi,ecx ; overwrite bug
356 ;; dec edi ;
357 ;; std ;
358 ;;@@do_copy:
359 db 67h ;address width override for esi/edi
360 rep movsb
361 ;; cld
363 ; Restore page mapping for page at 0
364 ;pop eax ;X
365 @@set_mapping:
366 mov esi,[cs:sw2pm_cr3]
367 xchg [esi-1000h],eax ; restore page0[0]
368 mov ecx,cr3 ; reload TLB cache
369 mov cr3,ecx ;
370 ; Return
371 vcpi_ret:
372 ret
374 endp call_pm_routine
375 assume cs:DGROUP,ds:DGROUP
378 ;***************************************************************
379 ;void _vm2rm();
380 ;***************************************************************
381 ;****** Uses: Flags
382 ;***************************************************************
383 global _vm2rm:near
384 proc _vm2rm near
386 p8086
387 extrn _vcpi:byte
388 test [_vcpi],-1
389 jz vcpi_ret
390 p386
391 pop ax
392 push cs ;*
393 push ax
394 push si
395 push ds
396 mov [saved_ss],ss
397 mov [saved_sp],sp
399 call switch_to_pm
401 ; Now we are in 16-bit protected mode
402 mov ax,SEL_DATA ; load data sregs with limit >=64k
403 mov ss,ax ; or you may get limit violations
404 mov ds,ax ; later in rm
405 ;mov es,ax ; (actually I prefer 4gig limits :-)
406 ;mov fs,ax ;
407 ;mov gs,ax ;
409 ; Black magic here
410 mov eax,cr0
411 and eax,7ffffffeh ; clear PG,P bits
412 mov cr0,eax ; look mommy, we're in rm now!
413 mov cr3,eax ; flush TLB cache
415 ; Now we are in rm, but not yet: have to restore sregs:
416 lss sp,[saved_ss_sp]; SS
417 pop ds ; DS
418 pop si
419 retf ; CS
421 endp _vm2rm
423 ends _TEXT
425 end
427 ;###### END OF FILE ############################################