# HG changeset patch
# User Pascal Bellard <pascal.bellard@slitaz.org>
# Date 1345356396 -7200
# Node ID 18d1dc85701e12d509eb460bb9be597ccdb5cbf4
# Parent  4cba4433d0b782aa377ec43440c6fc9c8a45bb45
memtest: compression (-76K)

diff -r 4cba4433d0b7 -r 18d1dc85701e memtest/receipt
--- a/memtest/receipt	Fri Aug 17 15:30:50 2012 +0000
+++ b/memtest/receipt	Sun Aug 19 08:06:36 2012 +0200
@@ -10,17 +10,24 @@
 WEB_SITE="http://www.memtest.org/"
 WGET_URL="${WEB_SITE}download/$VERSION/$TARBALL"
 
+BUILD_DEPENDS="lz4"
+
 # Rules to configure and make the package.
 compile_rules()
 {
 	cd $src
 	make
+	cp $stuff/*.S $stuff/pack .
+	cc -o unpack.o -Wa,-a=unpack.lst -c unpack.S
+	objcopy -O binary unpack.o unpack.bin
+	./pack --build unpack.bin
+	./pack memtest.bin memtest.packed
 } 
 
 
 # Rules to gen a SliTaz package suitable for Tazpkg.
 genpkg_rules()
 {
-	mkdir -p  $fs/boot
-	cp $src/memtest.bin $fs/boot/memtest
+	mkdir -p $fs/boot
+	cp $src/memtest.packed $fs/boot/memtest
 }
diff -r 4cba4433d0b7 -r 18d1dc85701e memtest/stuff/pack
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/memtest/stuff/pack	Sun Aug 19 08:06:36 2012 +0200
@@ -0,0 +1,41 @@
+#!/bin/sh
+if [ "$1" == "--build" ]; then
+	cat >> $0 <<EOM
+$(gzip -9 < ${2:-unpack.bin} | uuencode -m -)
+EOT
+EOM
+	sed -i '/--build/,/^fi/d' $0
+	exit
+fi
+
+store()
+{
+	n=$1
+	for i in $(seq 1 $4); do
+		printf '\\\\x%02X' $(($n & 255))
+		n=$(($n >> 8))
+	done | xargs echo -en | dd conv=notrunc bs=1 of=$2 seek=$3
+}
+
+setup="$(dd bs=1 count=1 if=$1 skip=497 | hexdump -e '"" 1/1 "%d" "\n"')"
+syssize="$(dd bs=1 count=2 if=$1 skip=500 | hexdump -e '"" 1/2 "%d" "\n"')"
+
+compress()
+{
+	lz4demo -c1 stdin stdout
+	echo -en "\x00\x00\x00\x00"
+}
+
+main()
+{
+	dd if=$1 bs=512 count=1 >$2
+	uudecode | gunzip >>$2
+	dd if=$1 bs=512 count=$setup skip=1 | compress >>$2
+	dd if=$1 bs=16 count=$syssize skip=$((32*(1+$setup))) | compress >>$2
+	size=$(stat -c %s $2)
+	store $((($size-512)/16)) $2 520 2
+	store $((($size-2560)/16)) $2 500 2
+	store 4 $2 497 1
+}
+
+main $1 $2 2>/dev/null <<EOT
diff -r 4cba4433d0b7 -r 18d1dc85701e memtest/stuff/unlz4.S
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/memtest/stuff/unlz4.S	Sun Aug 19 08:06:36 2012 +0200
@@ -0,0 +1,105 @@
+/*
+ * Lz4Decode:
+#ifndef FLAT32
+ *   input   ds:si=inStream, es:di=outStream
+ *   output  outStream[], ds:si, es:di
+	.code16
+#else
+ *   input   esi=inStream, edi=outStream
+ *   output  outStream[], esi, edi
+	.code32
+#endif
+ */
+ 
+#define ARCHIVE_MAGICNUMBER 0x184C2102
+
+lz4main:
+	cld
+	lodsl			// get chunkSize
+	cmpl	$ARCHIVE_MAGICNUMBER, %eax
+	je	lz4main
+	orl	%eax, %eax	// end of file ?
+	je	lz4quit
+	xchgl	%eax, %edx
+lz4chunk:			// uncompress chunk
+	lodsb			// get token
+	decl	%edx
+	movzbl	%al, %ebx
+	shrb	$4, %al
+	call	lz4len		// get literal length, %eax < 255
+	incl	%ecx
+	stc
+	sbbl	%ecx, %edx
+	pushf	
+	call	lz4mov		// copy literals
+	popf
+	js	lz4main
+	lodsw			// get string address
+#ifndef FLAT32
+	pushw	%bx
+	movw	%di, %bx
+	subl	%eax, %ebx
+	popw	%ax
+	call	lz4len		// get string length
+	pushw	%ds
+	pushw	%si
+	pushw	%es
+	popw	%ds
+	movw	$0xF, %si
+	andw	%bx, %si
+	shrl	$4, %ebx
+	addl	$4+1, %ecx
+	movw	%bx, %bp
+	call	lz4mov2		// copy string
+	popw	%si
+	popw	%ds
+#else
+	negl	%eax
+	xchgl	%eax, %ebx
+	addl	%edi, %ebx
+	call	lz4len		// get string length
+	pushl	%esi
+	xchgl	%ebx, %esi
+	call	lz4mov		// copy string
+	popl	%esi
+#endif
+	jmp	lz4chunk
+
+lz4len:				// get length in %ecx
+	andl	$0xF, %eax
+	movl	%eax, %ecx
+	cmpb	$0xF, %al
+	jne	lz4quit
+lz4len2:
+	lodsb
+	decl	%edx		// remaining chunk size
+	addl	%eax, %ecx
+	cmpb	$0xFF, %al
+	je	lz4len2
+lz4quit:
+	ret
+
+lz4movlp:
+	movsb
+#ifndef FLAT32
+	movw	$0x800, %bp
+	orw	%di, %di
+	jns	lz4di
+	subw	$0x8000, %di
+	movw	%es, %ax
+	addw	%bp, %ax
+	movw	%ax, %es
+lz4di:
+	orw	%si, %si
+	jns	lz4si
+	subw	$0x8000, %si
+lz4mov2:
+	movw	%ds, %ax
+	addw	%bp, %ax
+	movw	%ax, %ds
+lz4si:
+#endif
+lz4mov:
+	decl	%ecx
+	jnz	lz4movlp
+	ret
diff -r 4cba4433d0b7 -r 18d1dc85701e memtest/stuff/unpack.S
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/memtest/stuff/unpack.S	Sun Aug 19 08:06:36 2012 +0200
@@ -0,0 +1,83 @@
+#define TOP	0x8FF00
+#define SYSTEM	0x10000
+#define SETUP	4
+
+	.text
+	.code16
+	.org	0
+
+	.globl	_start
+_start:
+	pushf
+	pushw	%cs
+	call	getip
+getip:
+	pushal
+	movw	$0, %bx		// packed sizes
+	movw	%sp, %bp
+#define START_IP	32(%bp)
+	pushw	%ds
+	pushw	%es
+	subw	$getip-_start, START_IP
+
+	cld
+	pushw	%cs
+	popw	%ds	
+	movw	$TOP/16, %ax
+	movw	%ax, %es
+	subw	%bx, %ax	// moved packed data
+	movw	START_IP, %si
+	movw	$moved-_start, %di
+	addw	%si, %di
+	pushw	%ds		// save setup seg
+	pushw	%es		// moved
+	pushw	%di		//   unpack code
+	movw	%si, %di
+	movw	$end-_start, %cx
+	rep
+	movsb			// move upack code to $TOP
+	pushw	%si		// data offset
+	movw	%ax, %es
+	movw	$SETUP*512, %cx
+	subw	$SETUP*32, %bx
+	xorw	%si, %si
+	xorw	%di, %di
+	rep
+	movsb			// move header part
+	pushw	$SYSTEM/16
+	popw	%ds
+movlp:
+	xorw	%si, %si
+	movw	$8, %cx
+	rep
+	movsw			// move system part
+	subw	$16, %di
+	movw	%ds, %cx
+	incw	%cx
+	movw	%cx, %ds
+	movw	%es, %cx
+	incw	%cx
+	movw	%cx, %es
+	decw	%bx
+	jns	movlp
+	popw	%si		// data offset
+	movw	%ax, %ds
+	retf
+
+moved:
+	popw	%es		// restore setup seg
+	movw	START_IP, %di
+	call	unpack		// unpack setup
+	pushw	$SYSTEM/16
+	popw	%es
+	xorw	%di,%di
+	call	unpack		// unpack system
+	popw	%es
+	popw	%ds
+	popal
+	iret
+
+unpack:
+#include "unlz4.S"
+
+end:
diff -r 4cba4433d0b7 -r 18d1dc85701e qemacs-tiny/receipt
--- a/qemacs-tiny/receipt	Fri Aug 17 15:30:50 2012 +0000
+++ b/qemacs-tiny/receipt	Sun Aug 19 08:06:36 2012 +0200
@@ -18,7 +18,7 @@
 compile_rules()
 {
 	cd $src
-	export CFLAGS="-Wno-error=unused-but-set-variable"
+	export CFLAGS="-Wno-error=unused-but-set-variable -O2"
 	sed -i 's/\(define SAVED_DATA_SIZE \).*/\1 __builtin_offsetof(EditState,end_of_saved_data)/' qe.h
 	./configure --prefix=/usr --enable-tiny && make qe
 }