wok annotate BootProg/stuff/boot16.asm @ rev 24942

BootProg: clear cmdline
author Pascal Bellard <pascal.bellard@slitaz.org>
date Wed Apr 20 15:10:50 2022 +0000 (2022-04-20)
parents d8c511e24c20
children 584e67527789
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - FAT12 and FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@24476 29 ;; Known Bugs: ;;
pascal@24476 30 ;; ~~~~~~~~~~~ ;;
pascal@24476 31 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 32 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 33 ;; - 360KB 5"25 ;;
pascal@24476 34 ;; - 1.2MB 5"25 ;;
pascal@24476 35 ;; - 1.44MB 3"5 ;;
pascal@24476 36 ;; on my HDD (FAT16). ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24476 57 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 58 ;; | Boot Sector | ;;
pascal@24476 59 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 60 ;; | 3KB Boot Stack | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 67 ;; dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 68 ;; cs:ip = program entry point ;;
pascal@24476 69 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 70 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 71 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 72 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24476 81 ;; ;;
pascal@24476 82 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 83
pascal@24476 84 %define bx(label) bx+label-boot
pascal@24476 85
pascal@24476 86 [BITS 16]
pascal@24476 87 [CPU 8086]
pascal@24476 88
pascal@24476 89 ImageLoadSeg equ 60h
pascal@24476 90 StackSize equ 3072 ; Stack + cluster list
pascal@24476 91
pascal@24476 92 [SECTION .text]
pascal@24476 93 [ORG 0]
pascal@24476 94
pascal@24476 95 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 96 ;; Boot sector starts here ;;
pascal@24476 97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 98
pascal@24476 99 boot:
pascal@24476 100 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 101 nop
pascal@24476 102 bsOemName DB "BootProg" ; 0x03
pascal@24476 103
pascal@24476 104 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 105 ;; BPB starts here ;;
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107
pascal@24479 108 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 109 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 110 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 111 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 112 bpbRootEntries DW 0 ; 0x11
pascal@24479 113 bpbTotalSectors DW 0 ; 0x13
pascal@24479 114 bpbMedia DB 0 ; 0x15
pascal@24479 115 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 116 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 117 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 118 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 119 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 120
pascal@24476 121 ;;;;;;;;;;;;;;;;;;;
pascal@24476 122 ;; BPB ends here ;;
pascal@24476 123 ;;;;;;;;;;;;;;;;;;;
pascal@24476 124
pascal@24479 125 bsDriveNumber DB 0 ; 0x24
pascal@24479 126 bsUnused DB 0 ; 0x25
pascal@24479 127 bsExtBootSignature DB 0 ; 0x26
pascal@24479 128 bsSerialNumber DD 0 ; 0x27
pascal@24476 129 bsVolumeLabel DB "NO NAME " ; 0x2B
pascal@24476 130 bsFileSystem DB "FAT12 " ; 0x36
pascal@24476 131
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133 ;; Boot sector code starts here ;;
pascal@24476 134 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 135
pascal@24476 136 start:
pascal@24476 137 cld
pascal@24476 138
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 140 ;; How much RAM is there? ;;
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 142
pascal@24476 143 int 12h ; get conventional memory size (in KBs)
pascal@24476 144 mov cx, 106h
pascal@24476 145 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 152 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 153 mov ss, ax
pascal@24476 154 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 155
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157 ;; Copy ourselves to top of memory ;;
pascal@24476 158 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 159
pascal@24476 160 mov si, 7C00h
pascal@24476 161 xor di, di
pascal@24476 162 mov ds, di
pascal@24476 163 mov [si], dx ; store BIOS boot drive number
pascal@24476 164 rep movsw ; move 512 bytes (+ 12)
pascal@24476 165
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167 ;; Jump to the copy ;;
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169
pascal@24476 170 push es
pascal@24476 171 mov cl, byte main
pascal@24476 172 push cx
pascal@24476 173 retf
pascal@24476 174
pascal@24476 175 main:
pascal@24476 176 %if ImageLoadSeg != main-boot
pascal@24476 177 %if ImageLoadSeg >= 100h
pascal@24476 178 mov cx, ImageLoadSeg
pascal@24476 179 %else
pascal@24476 180 mov cl, ImageLoadSeg
pascal@24476 181 %endif
pascal@24476 182 %endif
pascal@24476 183 push cx
pascal@24476 184
pascal@24476 185 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 186 ;; Get drive parameters ;;
pascal@24476 187 ;; Update heads count ;;
pascal@24476 188 ;; for current BIOS ;;
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190
pascal@24476 191 mov ah, 8
pascal@24476 192 int 13h ; may destroy SI,BP, and DS registers
pascal@24476 193 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 194 push cs
pascal@24476 195 pop ds
pascal@24476 196 xor bx, bx
pascal@24476 197
pascal@24479 198 and cx, byte 3Fh
pascal@24476 199 cmp [bx(bpbSectorsPerTrack)], cx
pascal@24476 200 jne BadParams ; verify updated and validity
pascal@24476 201 mov al, dh
pascal@24476 202 inc ax
pascal@24476 203 mov [bpbHeadsPerCylinder], ax
pascal@24476 204 BadParams:
pascal@24476 205
pascal@24476 206 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 207 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 208 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 209
pascal@24476 210 pop es ; ImageLoadSeg
pascal@24476 211 push es
pascal@24476 212
pascal@24476 213 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@24476 214 mov cx, word [bx(bpbSectorsPerFAT)]
pascal@24476 215
pascal@24942 216 call ReadCXSectors ; read fat and clear ax & cx
pascal@24476 217
pascal@24476 218 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 219 ;; load the root directory in ;;
pascal@24476 220 ;; its entirety (16KB max) ;;
pascal@24476 221 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 222
pascal@24942 223 mov al, 32
pascal@24476 224
pascal@24476 225 mul word [bx(bpbRootEntries)]
pascal@24476 226 div word [bx(bpbBytesPerSector)]
pascal@24476 227 xchg ax, cx ; cx = root directory size in sectors, clear ax
pascal@24476 228
pascal@24476 229 mov al, [bpbNumberOfFATs]
pascal@24476 230 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadCXSectors
pascal@24476 231
pascal@24476 232 push es
pascal@24942 233 call ReadCXSectors ; read root directory; clear ax, cx and di
pascal@24476 234 pop es
pascal@24476 235
pascal@24476 236 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 237 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 238 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 239
pascal@24476 240 ; es:di -> root entries array
pascal@24476 241
pascal@24476 242 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 243 ;; Looks for the file/dir ProgramName ;;
pascal@24476 244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 245 ;; Input: ES:DI -> root directory array ;;
pascal@24476 246 ;; Output: SI = cluster number ;;
pascal@24476 247 ;; AX = file sector count ;;
pascal@24476 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 249
pascal@24476 250 FindNameCycle:
pascal@24476 251 push di
pascal@24476 252 mov cl, 11
pascal@24476 253 mov si, ProgramName ; ds:si -> program name
pascal@24476 254 repe cmpsb
pascal@24476 255 pop di
pascal@24476 256 je FindNameFound
pascal@24942 257 scasb
pascal@24942 258 je FindNameFailed ; end of root directory (NULL entry found)
pascal@24942 259 add di, byte 31
pascal@24476 260 dec word [bx(bpbRootEntries)]
pascal@24476 261 jnz FindNameCycle ; next root entry
pascal@24476 262
pascal@24476 263 FindNameFailed:
pascal@24476 264 call Error
pascal@24476 265 db "File not found."
pascal@24476 266
pascal@24476 267 FindNameFound:
pascal@24476 268 push si
pascal@24476 269 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 270 les ax, [es:di+1Ch] ; file size
pascal@24476 271 mov dx, es
pascal@24476 272 div word [bx(bpbBytesPerSector)]
pascal@24476 273 cmp bx, dx ; sector aligned ?
pascal@24476 274 adc ax, bx ; file last sector
pascal@24476 275 pop di ; di = ClusterList
pascal@24476 276
pascal@24476 277 pop es ; ImageLoadSeg
pascal@24476 278 push ax
pascal@24476 279
pascal@24476 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 281 ;; build cluster list ;;
pascal@24476 282 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 283 ;; Input: ES:0 -> FAT ;;
pascal@24476 284 ;; SI = first cluster ;;
pascal@24476 285 ;; DI = cluster list :;
pascal@24476 286 ;; CH = 0 ;;
pascal@24476 287 ;; Output: SI = cluster list ;;
pascal@24476 288 ;; CH = 0 ;;
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290
pascal@24476 291 push di ; up to 2 * 635K / BytesPerCluster bytes
pascal@24476 292 mov cl, 12
pascal@24476 293 ClusterLoop:
pascal@24476 294 mov [di], si
pascal@24476 295
pascal@24476 296 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@24476 297 add si, si ; si = cluster * 2
pascal@24476 298 jnc First64
pascal@24476 299 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@24476 300 First64:
pascal@24942 301 mov dx, 0FFF8h
pascal@24942 302
pascal@24476 303 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@24476 304 mov ds, ax
pascal@24942 305 ja ReadClusterFat16
pascal@24476 306
pascal@24942 307 mov dh, 0Fh
pascal@24476 308 add si, [cs:di]
pascal@24476 309 shr si, 1 ; si = cluster * 3 / 2
pascal@24476 310
pascal@24942 311 ReadClusterFat16:
pascal@24476 312 lodsw ; ax = next cluster
pascal@24476 313 jnc ReadClusterEven
pascal@24476 314
pascal@24476 315 rol ax, cl
pascal@24476 316
pascal@24476 317 ReadClusterEven:
pascal@24942 318 and ah, dh ; mask cluster value
pascal@24942 319 cmp ax, dx
pascal@24476 320
pascal@24476 321 push cs
pascal@24476 322 pop ds
pascal@24476 323 inc di
pascal@24476 324 inc di
pascal@24476 325 xchg ax, si
pascal@24476 326 jc ClusterLoop
pascal@24476 327 pop si
pascal@24476 328 pop di ; file size in sectors
pascal@24476 329
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 ;; Load the entire file ;;
pascal@24476 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 333 ;; Input: ES:0 -> buffer ;;
pascal@24476 334 ;; SI = cluster list ;;
pascal@24476 335 ;; DI = file sectors ;;
pascal@24476 336 ;; CH = 0 ;;
pascal@24476 337 ;; Output: BP:0 -> buffer ;;
pascal@24476 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 339
pascal@24476 340 push es
pascal@24476 341
pascal@24476 342 ReadClusters:
pascal@24476 343 lodsw
pascal@24476 344 dec ax
pascal@24476 345 dec ax
pascal@24476 346
pascal@24476 347 mov cl, [bx(bpbSectorsPerCluster)]
pascal@24476 348 mul cx ; cx = sector count (ch = 0)
pascal@24476 349
pascal@24476 350 add ax, bp ; LBA for cluster data
pascal@24476 351 adc dx, bx ; dx:ax = LBA
pascal@24476 352
pascal@24942 353 call ReadSector ; clear ax & cx, restore dx
pascal@24476 354
pascal@24476 355 jne ReadClusters
pascal@24476 356
pascal@24476 357 pop bp ; ImageLoadSeg
pascal@24476 358
pascal@24476 359 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 360 ;; Type detection, .COM or .EXE? ;;
pascal@24476 361 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 362
pascal@24476 363 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 364
pascal@24476 365 add bp, [bx+08h] ; bp = image base
pascal@24476 366 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 367
pascal@24476 368 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 369 je RelocateEXE ; yes, it's an EXE program
pascal@24476 370
pascal@24476 371 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 372 ;; Setup and run a .COM program ;;
pascal@24476 373 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24942 374 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24942 375 ;; and cmdline=void ;;
pascal@24476 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 377
pascal@24942 378 mov di, 100h ; ip
pascal@24476 379 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 380 mov ss, bp
pascal@24476 381 xor sp, sp
pascal@24476 382 push bp ; cs, ds and es
pascal@24476 383 jmp short Run
pascal@24476 384
pascal@24476 385 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 386 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 387 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 388 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24942 389 ;; AX=0ffffh BX=0 CX=0 DX=drive cmdline=void ;;
pascal@24476 390 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 391
pascal@24476 392 ReloCycle:
pascal@24476 393 add [di+2], bp ; item seg (abs)
pascal@24476 394 les si, [di] ; si = item ofs, es = item seg
pascal@24476 395 add [es:si], bp ; fixup
pascal@24476 396 scasw ; di += 2
pascal@24476 397 scasw ; point to next entry
pascal@24476 398
pascal@24476 399 RelocateEXE:
pascal@24942 400 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 401 jns ReloCycle
pascal@24476 402 ; PSP don't have a valid drive identifier
pascal@24476 403 les si, [bx+0Eh]
pascal@24476 404 add si, bp
pascal@24476 405 mov ss, si ; ss for EXE
pascal@24476 406 mov sp, es ; sp for EXE
pascal@24476 407
pascal@24476 408 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 409 push si ; containing the PSP structure
pascal@24476 410
pascal@24476 411 add bp, [bx+16h] ; cs for EXE
pascal@24942 412 mov di, [bx+14h] ; ip for EXE
pascal@24476 413 Run:
pascal@24476 414 pop ds
pascal@24476 415 push bp
pascal@24942 416 push di
pascal@24476 417 push ds
pascal@24476 418 pop es
pascal@24942 419 mov [80h], ax ; clear cmdline
pascal@24942 420 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 421
pascal@24476 422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 423 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 424 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 425 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 426 mov si, 16381 ; prime number 2**14-3
pascal@24476 427 mov di, 32749 ; prime number 2**15-19
pascal@24476 428 mov bp, 65521 ; prime number 2**16-15
pascal@24476 429
pascal@24476 430 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 431 ;; All done, transfer control to the program now ;;
pascal@24476 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 433 retf
pascal@24476 434
pascal@24476 435 ReadCXSectors:
pascal@24476 436 mov bp, cx
pascal@24476 437 add bp, ax ; adjust LBA for cluster data
pascal@24476 438
pascal@24476 439 mov di, cx ; no file size limit
pascal@24476 440
pascal@24476 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 442 ;; Reads sectors using BIOS Int 13h ;;
pascal@24476 443 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 444 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 445 ;; BX = 0 ;;
pascal@24476 446 ;; CX = sector count ;;
pascal@24476 447 ;; DI = file sectors ;;
pascal@24476 448 ;; ES:BX -> buffer address ;;
pascal@24476 449 ;; Output: ES:BX -> next address ;;
pascal@24476 450 ;; BX = 0 ;;
pascal@24476 451 ;; CX or DI = 0 ;;
pascal@24476 452 ;; DL = drive number ;;
pascal@24476 453 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 454
pascal@24476 455 ReadSector:
pascal@24476 456 add ax, [bx(bpbHiddenSectors)]
pascal@24476 457 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 458 add ax, [bx(bpbReservedSectors)]
pascal@24476 459
pascal@24476 460 push si
pascal@24476 461 ReadSectorNext:
pascal@24476 462 adc dx, bx
pascal@24476 463 push di
pascal@24476 464 push cx
pascal@24476 465
pascal@24476 466 push bx
pascal@24476 467 push bx
pascal@24476 468 push dx ; 32-bit LBA: up to 2TB
pascal@24476 469 push ax
pascal@24476 470 push es
pascal@24476 471 push bx
pascal@24476 472 inc bx ; sector count word = 1
pascal@24476 473 push bx
pascal@24476 474 dec bx
pascal@24476 475 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 476 push di
pascal@24476 477
pascal@24476 478 xchg ax, cx ; save low LBA
pascal@24476 479 xchg ax, dx ; get high LBA
pascal@24476 480 cwd ; clear dx (LBA offset <2TB)
pascal@24476 481 div word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 482
pascal@24476 483 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@24476 484 div word [bx(bpbSectorsPerTrack)]
pascal@24476 485 ; ax = LBA / SPT
pascal@24476 486 ; dx = LBA % SPT = sector - 1
pascal@24476 487 inc dx
pascal@24476 488
pascal@24476 489 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@24476 490 div word [bx(bpbHeadsPerCylinder)]
pascal@24476 491 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 492 ; dx = (LBA / SPT) % HPC = head
pascal@24476 493 mov ch, al
pascal@24476 494 ; ch = LSB 0...7 of cylinder no.
pascal@24476 495 mov al, 64
pascal@24476 496 mul ah
pascal@24476 497 or cl, al
pascal@24476 498 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 499 mov dh, dl
pascal@24476 500 ; dh = head no.
pascal@24476 501
pascal@24476 502 ReadSectorRetry:
pascal@24476 503 mov dl, [bx]
pascal@24476 504 ; dl = drive no.
pascal@24476 505 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 506 mov si, sp
pascal@24476 507 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 508 jnc ReadSectorNextSegment
pascal@24476 509
pascal@24476 510 mov ax, 201h ; al = sector count = 1
pascal@24476 511 ; ah = 2 = read function no.
pascal@24476 512 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 513
pascal@24476 514 jnc ReadSectorNextSegment
pascal@24476 515 cbw ; ah = 0 = reset function
pascal@24476 516 int 13h ; reset drive (DL)
pascal@24476 517
pascal@24476 518 dec di
pascal@24476 519 jnz ReadSectorRetry ; extra attempt
pascal@24476 520
pascal@24476 521 call Error
pascal@24476 522 db "Read error."
pascal@24476 523
pascal@24476 524 ReadSectorNextSegment:
pascal@24476 525
pascal@24476 526 pop ax ; al = 16
pascal@24476 527 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@24476 528 pop cx ; sector count = 1
pascal@24476 529 pop bx
pascal@24476 530 add [si+6], ax ; adjust segment for next sector
pascal@24476 531 pop es ; es:0 updated
pascal@24476 532 pop ax
pascal@24476 533 pop dx
pascal@24476 534 pop di
pascal@24476 535 pop di
pascal@24476 536
pascal@24476 537 add ax, cx ; adjust LBA for next sector
pascal@24476 538
pascal@24476 539 pop cx ; cluster sectors to read
pascal@24476 540 pop di ; file sectors to read
pascal@24476 541 dec di ; keep C
pascal@24476 542 loopne ReadSectorNext ; until cluster sector count or file sector count is reached
pascal@24476 543 pop si
pascal@24942 544 mov ax, bx ; clear ax
pascal@24476 545 mov dx, [bx] ; pass the BIOS boot drive to Run or Error
pascal@24476 546
pascal@24476 547 ret
pascal@24476 548
pascal@24942 549 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 550 ;; Fill free space with zeroes ;;
pascal@24942 551 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 552
pascal@24942 553 times (512-13-20-($-$$)) db 0
pascal@24942 554
pascal@24476 555 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 556 ;; Error Messaging Code ;;
pascal@24476 557 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 558
pascal@24476 559 Error:
pascal@24476 560 pop si
pascal@24478 561
pascal@24478 562 PutStr:
pascal@24476 563 mov ah, 0Eh
pascal@24476 564 mov bl, 7
pascal@24476 565 lodsb
pascal@24476 566 int 10h
pascal@24476 567 cmp al, "."
pascal@24476 568 jne PutStr
pascal@24476 569
pascal@24476 570 cbw
pascal@24476 571 int 16h ; wait for a key...
pascal@24476 572 int 19h ; bootstrap
pascal@24476 573
pascal@24476 574 Stop:
pascal@24476 575 hlt
pascal@24476 576 jmp short Stop
pascal@24476 577
pascal@24476 578 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 579 ;; Name of the file to load and run ;;
pascal@24476 580 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 581
pascal@24476 582 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 583 ; padded with spaces (11 bytes total)
pascal@24476 584
pascal@24476 585 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 586 ;; End of the sector ID ;;
pascal@24476 587 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 588
pascal@24476 589 ClusterList dw 0AA55h ; BIOS checks for this ID
pascal@24479 590