wok-6.x annotate BootProg/stuff/boot32.asm @ rev 24525

Up libav (0.6.6 -> 12.3)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Tue Feb 22 16:15:28 2022 +0000 (2022-02-22)
parents d8c511e24c20
children 7c0170dd3ecc
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24525 14 ;; - FAT32 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24525 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@24525 51 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@24525 53 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24525 54 ;; | 1.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 61 ;; dl = BIOS boot drive number (e.g. 80H) ;;
pascal@24476 62 ;; cs:ip = program entry point ;;
pascal@24476 63 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 64 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 65 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 66 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24476 75 ;; ;;
pascal@24476 76 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 77
pascal@24491 78 %define bx(label) bx+label-boot
pascal@24491 79
pascal@24476 80 [BITS 16]
pascal@24476 81
pascal@24478 82 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@24525 83 StackSize equ 1536
pascal@24476 84
pascal@24476 85 [SECTION .text]
pascal@24476 86 [ORG 0]
pascal@24476 87
pascal@24476 88 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 89 ;; Boot sector starts here ;;
pascal@24476 90 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 91
pascal@24491 92 boot:
pascal@24491 93 HiLBA equ boot+0
pascal@24476 94 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 95 nop
pascal@24476 96 bsOemName DB "BootProg" ; 0x03
pascal@24476 97
pascal@24476 98 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 99 ;; BPB1 starts here ;;
pascal@24476 100 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 101
pascal@24479 102 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 103 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 104 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 105 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 106 bpbRootEntries DW 0 ; 0x11
pascal@24479 107 bpbTotalSectors DW 0 ; 0x13
pascal@24479 108 bpbMedia DB 0 ; 0x15
pascal@24479 109 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 110 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 111 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 112 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 113 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 114
pascal@24476 115 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 116 ;; BPB1 ends here ;;
pascal@24476 117 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 118
pascal@24476 119 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 120 ;; BPB2 starts here ;;
pascal@24476 121 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 122
pascal@24479 123 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 124 bsExtendedFlags DW 0 ; 0x28
pascal@24479 125 bsFSVersion DW 0 ; 0x2A
pascal@24479 126 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 127 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 128 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 129 bsreserved times 12 DB 0 ; 0x34
pascal@24479 130 bsDriveNumber DB 0 ; 0x40
pascal@24479 131 bsreserved1 DB 0 ; 0x41
pascal@24479 132 bsExtendedBootSignature DB 0 ; 0x42
pascal@24479 133 bsVolumeSerialNumber DD 0 ; 0x43
pascal@24476 134 bsVolumeLabel DB "NO NAME " ; 0x47
pascal@24476 135 bsFileSystemName DB "FAT32 " ; 0x52
pascal@24476 136
pascal@24476 137 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 138 ;; BPB2 ends here ;;
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 140
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 142 ;; Boot sector code starts here ;;
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 144
pascal@24476 145 start:
pascal@24476 146 cld
pascal@24476 147
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149 ;; How much RAM is there? ;;
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 151
pascal@24476 152 int 12h ; get conventional memory size (in KBs)
pascal@24525 153 dec ax
pascal@24525 154 dec ax ; reserve 2K bytes for the code and the stack
pascal@24525 155 mov cx, 106h
pascal@24525 156 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 157
pascal@24476 158 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 159 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 160 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 161
pascal@24525 162 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24525 163 mov ss, ax
pascal@24525 164 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 165
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167 ;; Copy ourselves to top of memory ;;
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169
pascal@24476 170 mov si, 7C00h
pascal@24476 171 xor di, di
pascal@24476 172 mov ds, di
pascal@24478 173 rep movsw
pascal@24476 174
pascal@24476 175 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 176 ;; Jump to the copy ;;
pascal@24476 177 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 178
pascal@24476 179 push es
pascal@24478 180 push byte main
pascal@24476 181 retf
pascal@24476 182
pascal@24476 183 main:
pascal@24476 184 push cs
pascal@24476 185 pop ds
pascal@24476 186
pascal@24491 187 xor bx, bx
pascal@24491 188 mov [bx(bsDriveNumber)], dx ; store BIOS boot drive number
pascal@24476 189
pascal@24491 190 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@24491 191 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 192
pascal@24476 193 RootDirReadContinue:
pascal@24478 194 push byte ImageLoadSeg
pascal@24478 195 pop es
pascal@24478 196 call ReadCluster ; read one cluster of root dir
pascal@24478 197 pushf ; save carry="not last cluster" flag
pascal@24476 198
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 202
pascal@24476 203 xor di, di ; es:di -> root entries array
pascal@24476 204
pascal@24476 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 206 ;; Looks for a file/dir by its name ;;
pascal@24476 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 208 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 209 ;; ES:DI -> root directory array ;;
pascal@24478 210 ;; DX = number of root entries ;;
pascal@24525 211 ;; BP = paragraphs in sector ;;
pascal@24476 212 ;; Output: ESI = cluster number ;;
pascal@24476 213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 214
pascal@24478 215 FindName:
pascal@24476 216 FindNameCycle:
pascal@24525 217 cmp byte [es:di], bh
pascal@24478 218 je ErrFind ; end of root directory (NULL entry found)
pascal@24478 219 FindNameNotEnd:
pascal@24478 220 pusha
pascal@24525 221 mov cl, 11
pascal@24525 222 mov si, ProgramName ; ds:si -> program name
pascal@24476 223 repe cmpsb
pascal@24525 224 je FindNameFound
pascal@24478 225 popa
pascal@24525 226 add di, byte 32
pascal@24476 227 dec bp
pascal@24476 228 dec bp
pascal@24476 229 jnz FindNameCycle ; next root entry
pascal@24478 230 popf ; restore carry="not last cluster" flag
pascal@24476 231 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 232 ErrFind:
pascal@24478 233 call Error ; end of root directory (dir end reached)
pascal@24476 234 db "File not found."
pascal@24476 235 FindNameFound:
pascal@24525 236 push word [es:di+14h-11]
pascal@24525 237 push word [es:di+1Ah-11]
pascal@24478 238 pop esi ; esi = cluster no. cx = 0
pascal@24476 239
pascal@24525 240 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 241 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 242
pascal@24476 243 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 244 ;; Load the entire file ;;
pascal@24476 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 246
pascal@24476 247 push es
pascal@24476 248 FileReadContinue:
pascal@24476 249 push di
pascal@24478 250 call ReadCluster ; read one cluster of root dir
pascal@24476 251 mov di, es
pascal@24478 252 add di, bp
pascal@24478 253 mov es, di ; es:bx updated
pascal@24476 254 pop di
pascal@24478 255
pascal@24476 256 sub di, bp
pascal@24476 257 jae FileReadContinue
pascal@24476 258 pop bp
pascal@24476 259
pascal@24476 260 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 261 ;; Type detection, .COM or .EXE? ;;
pascal@24476 262 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 263
pascal@24476 264 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 265 add bp, [bx+08h] ; bp = image base
pascal@24476 266 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 267 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 268
pascal@24476 269 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24478 270
pascal@24476 271 je RelocateEXE ; yes, it's an EXE program
pascal@24476 272
pascal@24476 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 274 ;; Setup and run a .COM program ;;
pascal@24478 275 ;; Set CS=DS=ES=SP SP=0 IP=100h ;;
pascal@24476 276 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 277
pascal@24476 278 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 279 mov ss, bp
pascal@24476 280 xor sp, sp
pascal@24476 281 push bp ; cs, ds and es
pascal@24476 282 mov bh, 1 ; ip
pascal@24476 283 jmp short Run
pascal@24476 284
pascal@24476 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 286 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 287 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 288 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290
pascal@24476 291 ReloCycle:
pascal@24476 292 add [di+2], bp ; item seg (abs)
pascal@24476 293 les si, [di] ; si = item ofs, es = item seg
pascal@24476 294 add [es:si], bp ; fixup
pascal@24525 295 scasw ; di += 2
pascal@24525 296 scasw ; point to next entry
pascal@24476 297
pascal@24476 298 RelocateEXE:
pascal@24476 299 dec ax ; 32768 max (128KB table)
pascal@24476 300 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 301 ; PSP don't have a valid drive identifier
pascal@24476 302 les si, [bx+0Eh]
pascal@24476 303 add si, bp
pascal@24476 304 mov ss, si ; ss for EXE
pascal@24476 305 mov sp, es ; sp for EXE
pascal@24476 306
pascal@24476 307 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 308 push si ; containing the PSP structure
pascal@24476 309
pascal@24476 310 add bp, [bx+16h] ; cs for EXE
pascal@24476 311 mov bx, [bx+14h] ; ip for EXE
pascal@24476 312 Run:
pascal@24476 313 pop ds
pascal@24476 314 push bp
pascal@24476 315 push bx
pascal@24476 316 push ds
pascal@24476 317 pop es
pascal@24476 318
pascal@24476 319 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 320 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 321 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 322 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 323 mov si, 16381 ; prime number 2**14-3
pascal@24476 324 mov di, 32749 ; prime number 2**15-19
pascal@24476 325 mov bp, 65521 ; prime number 2**16-15
pascal@24476 326
pascal@24476 327 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 328 ;; All done, transfer control to the program now ;;
pascal@24476 329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 330 retf
pascal@24476 331
pascal@24525 332 ReadCluster:
pascal@24525 333 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 334 shr bp, 4 ; bp = paragraphs per sector
pascal@24525 335 inc cx
pascal@24525 336 loop ReadSectorLBA
pascal@24525 337
pascal@24478 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 339 ;; Reads a FAT32 cluster ;;
pascal@24478 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 341 ;; Inout: ES:BX -> buffer ;;
pascal@24478 342 ;; ESI = cluster no ;;
pascal@24478 343 ;; Output: ESI = next cluster ;;
pascal@24525 344 ;; BP -> para / sector ;;
pascal@24478 345 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 346
pascal@24525 347 imul ax, bp, byte 2 ; ax=# of FAT32 entries per sector
pascal@24478 348 cwde
pascal@24525 349 lea edi, [esi-2] ; esi=cluster #
pascal@24476 350 xchg eax, esi
pascal@24476 351 cdq
pascal@24478 352 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 353
pascal@24525 354 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@24491 355 mov word [bx(HiLBA)], bx
pascal@24478 356 call ReadSectorLBAabsolute ; read 1 FAT32 sector
pascal@24476 357
pascal@24478 358 and byte [es:si+3], 0Fh ; mask cluster value
pascal@24478 359 mov esi, [es:si] ; esi=next cluster #
pascal@24476 360
pascal@24525 361 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 362 mul dword [bx(bsSectorsPerFAT32)]
pascal@24525 363 mov word [bx(HiLBA)], dx
pascal@24525 364
pascal@24525 365 xchg eax, edi
pascal@24491 366 movzx ecx, byte [bx(bpbSectorsPerCluster)]
pascal@24491 367 mul ecx ; edx:eax=sector number in data area
pascal@24476 368
pascal@24525 369 add eax, edi
pascal@24491 370 adc word [bx(HiLBA)], dx
pascal@24476 371
pascal@24478 372 ReadSectorLBAabsolute:
pascal@24525 373 mov dx, word [bx(bpbReservedSectors)]
pascal@24478 374 add eax, edx
pascal@24491 375 adc word [bx(HiLBA)], bx
pascal@24491 376 add eax, [bx(bpbHiddenSectors)]
pascal@24491 377 adc word [bx(HiLBA)], bx
pascal@24476 378
pascal@24478 379 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 380 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 381 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 382 ;; Input: EAX = LBA ;;
pascal@24478 383 ;; CX = sector count ;;
pascal@24478 384 ;; ES:BX -> buffer address ;;
pascal@24478 385 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 387
pascal@24476 388 ReadSectorLBA:
pascal@24476 389 pusha
pascal@24476 390
pascal@24478 391 push bx
pascal@24491 392 push word [bx(HiLBA)] ; 48-bit LBA
pascal@24478 393 push eax
pascal@24476 394 push es
pascal@24476 395 push bx
pascal@24478 396 push byte 1 ; sector count word = 1
pascal@24525 397 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 398 push eax
pascal@24525 399 pop cx ; low LBA
pascal@24525 400 pop ax ; high LBA
pascal@24525 401 cwd ; clear dx (CHS disk <2TB)
pascal@24525 402 div word [bx(bpbSectorsPerTrack)] ; up to 8GB CHS disks
pascal@24476 403
pascal@24525 404 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@24525 405 div word [bx(bpbSectorsPerTrack)]
pascal@24525 406 ; ax = LBA / SPT
pascal@24525 407 ; dx = LBA % SPT = sector - 1
pascal@24525 408 inc dx
pascal@24525 409
pascal@24525 410 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@24525 411 div word [bx(bpbHeadsPerCylinder)]
pascal@24525 412 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24525 413 ; dx = (LBA / SPT) % HPC = head
pascal@24525 414 shl ah, 6
pascal@24525 415 mov ch, al
pascal@24525 416 ; ch = LSB 0...7 of cylinder no.
pascal@24525 417 or cl, ah
pascal@24525 418 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24525 419 mov dh, dl
pascal@24525 420 ; dh = head no.
pascal@24525 421
pascal@24525 422 ReadSectorLBARetry:
pascal@24525 423 mov dl, [bx(bsDriveNumber)] ; restore BIOS boot drive number
pascal@24525 424 mov si, sp
pascal@24478 425 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 426 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 427 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 428
pascal@24525 429 ReadSectorCHSRetry:
pascal@24525 430 mov ax, 201h ; al = sector count = 1
pascal@24525 431 ; ah = 2 = read function no.
pascal@24525 432 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24525 433 jnc ReadSuccess ; CF = 0 if no error
pascal@24525 434
pascal@24525 435 cbw ; ah = 0 = reset function
pascal@24476 436 int 13h ; reset drive (DL)
pascal@24476 437
pascal@24525 438 dec bp
pascal@24525 439 jnz ReadSectorLBARetry
pascal@24525 440
pascal@24476 441 call Error
pascal@24476 442 db "Read error."
pascal@24476 443
pascal@24478 444 ReadSuccess:
pascal@24476 445
pascal@24476 446 popa ; sp += 16
pascal@24478 447
pascal@24478 448 popa
pascal@24478 449
pascal@24491 450 add eax, byte 1 ; adjust LBA for next sector
pascal@24491 451 adc word [bx(HiLBA)], bx
pascal@24478 452
pascal@24476 453 stc
pascal@24478 454 loop ReadSectorNext
pascal@24476 455
pascal@24478 456 cmp esi, 0FFFFFF8h ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 457
pascal@24478 458 ReadSectorNext:
pascal@24525 459 mov dx, [bx(bsDriveNumber)] ; restore BIOS boot drive number
pascal@24476 460 ret
pascal@24476 461
pascal@24476 462 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 463 ;; Error Messaging Code ;;
pascal@24476 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 465
pascal@24476 466 Error:
pascal@24476 467 pop si
pascal@24478 468 puts:
pascal@24476 469 mov ah, 0Eh
pascal@24476 470 mov bl, 7
pascal@24476 471 lodsb
pascal@24476 472 int 10h
pascal@24478 473 cmp al, '.'
pascal@24478 474 jne puts
pascal@24476 475 cbw
pascal@24525 476 ; int 16h ; wait for a key...
pascal@24525 477 ; int 19h ; bootstrap
pascal@24525 478
pascal@24525 479 Stop:
pascal@24525 480 hlt
pascal@24525 481 jmp short Stop
pascal@24476 482
pascal@24476 483 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 484 ;; Fill free space with zeroes ;;
pascal@24476 485 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 486
pascal@24476 487 times (512-13-($-$$)) db 0
pascal@24476 488
pascal@24476 489 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 490 ;; Name of the file to load and run ;;
pascal@24476 491 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 492
pascal@24476 493 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 494 ; padded with spaces (11 bytes total)
pascal@24476 495
pascal@24476 496 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 497 ;; End of the sector ID ;;
pascal@24476 498 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 499
pascal@24476 500 dw 0AA55h ; BIOS checks for this ID