wok-current annotate BootProg/stuff/boot16.asm @ rev 25454

oldrunner: add apple2 keys mapping
author Pascal Bellard <pascal.bellard@slitaz.org>
date Thu Sep 22 07:58:57 2022 +0000 (22 months ago)
parents ec9531d04de1
children d4a851cd7f09
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - FAT12 and FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@24476 29 ;; Known Bugs: ;;
pascal@24476 30 ;; ~~~~~~~~~~~ ;;
pascal@24476 31 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 32 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 33 ;; - 360KB 5"25 ;;
pascal@24476 34 ;; - 1.2MB 5"25 ;;
pascal@24476 35 ;; - 1.44MB 3"5 ;;
pascal@24476 36 ;; on my HDD (FAT16). ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24476 57 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 58 ;; | Boot Sector | ;;
pascal@24476 59 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 60 ;; | 3KB Boot Stack | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 67 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 68 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 69 ;; cs:ip = program entry point ;;
pascal@24476 70 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 71 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 72 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24945 81 ;; The command line contains no arguments. ;;
pascal@24476 82 ;; ;;
pascal@24476 83 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 84
pascal@24476 85 %define bx(label) bx+label-boot
pascal@25450 86 %define si(label) si+label-boot
pascal@25450 87 NullEntryCheck equ 1 ; +3 bytes
pascal@25450 88 ReadRetry equ 1 ; +9 bytes
pascal@25450 89 LBAsupport equ 1 ; +16 bytes
pascal@25450 90 Over2GB equ 1 ; +5 bytes
pascal@25450 91 GeometryCheck equ 1 ; +18 bytes
pascal@24476 92
pascal@24476 93 [BITS 16]
pascal@24476 94 [CPU 8086]
pascal@24476 95
pascal@24476 96 ImageLoadSeg equ 60h
pascal@24476 97 StackSize equ 3072 ; Stack + cluster list
pascal@24476 98
pascal@24476 99 [SECTION .text]
pascal@24476 100 [ORG 0]
pascal@24476 101
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103 ;; Boot sector starts here ;;
pascal@24476 104 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 105
pascal@24476 106 boot:
pascal@25450 107 DriveNumber:
pascal@24476 108 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 109 nop
pascal@24476 110 bsOemName DB "BootProg" ; 0x03
pascal@24476 111
pascal@24476 112 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 113 ;; BPB starts here ;;
pascal@24476 114 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 115
pascal@24479 116 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 117 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 118 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 119 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 120 bpbRootEntries DW 0 ; 0x11
pascal@24479 121 bpbTotalSectors DW 0 ; 0x13
pascal@24479 122 bpbMedia DB 0 ; 0x15
pascal@24479 123 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 124 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 125 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 126 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 127 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 128
pascal@24476 129 ;;;;;;;;;;;;;;;;;;;
pascal@24476 130 ;; BPB ends here ;;
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;
pascal@24476 132
pascal@24479 133 bsDriveNumber DB 0 ; 0x24
pascal@24479 134 bsUnused DB 0 ; 0x25
pascal@24479 135 bsExtBootSignature DB 0 ; 0x26
pascal@24479 136 bsSerialNumber DD 0 ; 0x27
pascal@24476 137 bsVolumeLabel DB "NO NAME " ; 0x2B
pascal@24476 138 bsFileSystem DB "FAT12 " ; 0x36
pascal@24476 139
pascal@24476 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 141 ;; Boot sector code starts here ;;
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 143
pascal@24476 144 start:
pascal@24476 145 cld
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; How much RAM is there? ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 int 12h ; get conventional memory size (in KBs)
pascal@24476 152 mov cx, 106h
pascal@24476 153 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 154
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158
pascal@24476 159 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 160 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 161 mov ss, ax
pascal@24476 162 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 163
pascal@24476 164 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 165 ;; Copy ourselves to top of memory ;;
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167
pascal@24476 168 mov si, 7C00h
pascal@24476 169 xor di, di
pascal@24476 170 mov ds, di
pascal@25450 171 push es
pascal@25450 172 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 173 rep movsw ; move 512 bytes (+ 12)
pascal@24476 174
pascal@24476 175 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 176 ;; Jump to the copy ;;
pascal@24476 177 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 178
pascal@24476 179 mov cl, byte main
pascal@24476 180 push cx
pascal@24476 181 retf
pascal@24476 182
pascal@24476 183 main:
pascal@24476 184 %if ImageLoadSeg != main-boot
pascal@24476 185 %if ImageLoadSeg >= 100h
pascal@24476 186 mov cx, ImageLoadSeg
pascal@24476 187 %else
pascal@24476 188 mov cl, ImageLoadSeg
pascal@24476 189 %endif
pascal@24476 190 %endif
pascal@24476 191 push cx
pascal@24476 192
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194 ;; Get drive parameters ;;
pascal@24476 195 ;; Update heads count ;;
pascal@24476 196 ;; for current BIOS ;;
pascal@24476 197 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 198
pascal@25450 199 %if GeometryCheck != 0
pascal@24476 200 mov ah, 8
pascal@24476 201 int 13h ; may destroy SI,BP, and DS registers
pascal@25450 202 %endif
pascal@24476 203 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 204 push cs
pascal@24476 205 pop ds
pascal@24476 206 xor bx, bx
pascal@24476 207
pascal@25450 208 %if GeometryCheck != 0
pascal@24479 209 and cx, byte 3Fh
pascal@24476 210 cmp [bx(bpbSectorsPerTrack)], cx
pascal@24476 211 jne BadParams ; verify updated and validity
pascal@24476 212 mov al, dh
pascal@24476 213 inc ax
pascal@24476 214 mov [bpbHeadsPerCylinder], ax
pascal@24476 215 BadParams:
pascal@25450 216 %endif
pascal@24476 217
pascal@24476 218 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 219 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 221
pascal@24476 222 pop es ; ImageLoadSeg
pascal@24476 223 push es
pascal@24476 224
pascal@24476 225 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@24476 226 mov cx, word [bx(bpbSectorsPerFAT)]
pascal@24476 227
pascal@24945 228 call ReadCXSectors ; read fat and clear ax & cx; bp = SectorsPerFAT
pascal@24476 229
pascal@24476 230 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 231 ;; load the root directory in ;;
pascal@24476 232 ;; its entirety (16KB max) ;;
pascal@24476 233 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 234
pascal@24942 235 mov al, 32
pascal@24476 236
pascal@24476 237 mul word [bx(bpbRootEntries)]
pascal@24476 238 div word [bx(bpbBytesPerSector)]
pascal@24476 239 xchg ax, cx ; cx = root directory size in sectors, clear ax
pascal@24476 240
pascal@24476 241 mov al, [bpbNumberOfFATs]
pascal@24476 242 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadCXSectors
pascal@24476 243
pascal@24476 244 push es
pascal@24945 245 call ReadCXSectors ; read root directory; clear ax, cx & di; bp = first data sector
pascal@24476 246 pop es
pascal@24476 247
pascal@24476 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 249 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 251
pascal@24476 252 ; es:di -> root entries array
pascal@24476 253
pascal@24476 254 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 255 ;; Looks for the file/dir ProgramName ;;
pascal@24476 256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 257 ;; Input: ES:DI -> root directory array ;;
pascal@24476 258 ;; Output: SI = cluster number ;;
pascal@24476 259 ;; AX = file sector count ;;
pascal@24476 260 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 261
pascal@24476 262 FindNameCycle:
pascal@24476 263 push di
pascal@25454 264 mov cl, NameLength
pascal@24476 265 mov si, ProgramName ; ds:si -> program name
pascal@24476 266 repe cmpsb
pascal@24476 267 pop di
pascal@24476 268 je FindNameFound
pascal@25450 269 %if NullEntryCheck != 0
pascal@24942 270 scasb
pascal@24942 271 je FindNameFailed ; end of root directory (NULL entry found)
pascal@24942 272 add di, byte 31
pascal@25450 273 %else
pascal@25450 274 add di, byte 32
pascal@25450 275 %endif
pascal@24476 276 dec word [bx(bpbRootEntries)]
pascal@24476 277 jnz FindNameCycle ; next root entry
pascal@24476 278
pascal@24476 279 FindNameFailed:
pascal@24476 280 call Error
pascal@24476 281 db "File not found."
pascal@24476 282
pascal@24476 283 FindNameFound:
pascal@24476 284 push si
pascal@24476 285 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 286 les ax, [es:di+1Ch] ; file size
pascal@24476 287 mov dx, es
pascal@24476 288 div word [bx(bpbBytesPerSector)]
pascal@24476 289 cmp bx, dx ; sector aligned ?
pascal@24476 290 adc ax, bx ; file last sector
pascal@24476 291 pop di ; di = ClusterList
pascal@24476 292
pascal@24476 293 pop es ; ImageLoadSeg
pascal@24476 294 push ax
pascal@24476 295
pascal@24476 296 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 297 ;; build cluster list ;;
pascal@24476 298 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 299 ;; Input: ES:0 -> FAT ;;
pascal@24476 300 ;; SI = first cluster ;;
pascal@24476 301 ;; DI = cluster list :;
pascal@24476 302 ;; CH = 0 ;;
pascal@24476 303 ;; Output: SI = cluster list ;;
pascal@24476 304 ;; CH = 0 ;;
pascal@24476 305 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 306
pascal@25450 307 FAT12 equ 1
pascal@25450 308 FAT16 equ 1
pascal@25454 309 TINYFAT16 equ 1
pascal@25453 310 push di ; up to 2 * 635K / BytesPerCluster = 2540 bytes
pascal@25450 311 %if FAT12 == 1
pascal@25454 312 %if TINYFAT16 == 0 && FAT16 == 1
pascal@25454 313 mov cl, 12
pascal@25454 314 %else
pascal@25453 315 mov cl, 4
pascal@25454 316 %endif
pascal@25450 317 %endif
pascal@24476 318 ClusterLoop:
pascal@24476 319 mov [di], si
pascal@25450 320 add si, si ; si = cluster * 2
pascal@25450 321 %if FAT16 == 1
pascal@24476 322 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@25094 323 jnc First64k
pascal@24476 324 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 325 First64k:
pascal@25453 326 %if FAT12 == 1
pascal@24942 327 mov dx, 0FFF8h
pascal@25454 328 %if TINYFAT16 == 1
pascal@25453 329 test [bx(bsFileSystem+4)], cl ; FAT12 or FAT16 ? clear C
pascal@25454 330 %else
pascal@25454 331 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@25454 332 %endif
pascal@25453 333 jne ReadClusterFat16
pascal@24942 334 mov dh, 0Fh
pascal@25453 335 %endif
pascal@25450 336 %endif
pascal@25450 337 %if FAT12 == 1
pascal@25087 338 add si, [di]
pascal@24476 339 shr si, 1 ; si = cluster * 3 / 2
pascal@25450 340 %endif
pascal@25450 341 %if FAT16 == 1
pascal@24942 342 ReadClusterFat16:
pascal@25094 343 push ds
pascal@25087 344 mov ds, ax
pascal@24476 345 lodsw ; ax = next cluster
pascal@25094 346 pop ds
pascal@25450 347 %else
pascal@25453 348 es lodsw
pascal@25450 349 %endif
pascal@25450 350 %if FAT12 == 1
pascal@24476 351 jnc ReadClusterEven
pascal@25454 352 %if TINYFAT16 == 0 && FAT16 == 1
pascal@25454 353 rol ax, cl
pascal@25454 354 %else
pascal@25453 355 shr ax, cl
pascal@25454 356 %endif
pascal@24476 357 ReadClusterEven:
pascal@25094 358 scasw ; di += 2
pascal@25454 359 %if FAT16 == 1
pascal@24942 360 and ah, dh ; mask cluster value
pascal@24942 361 cmp ax, dx
pascal@25454 362 %else
pascal@25453 363 and ah, 0Fh ; mask cluster value
pascal@25453 364 cmp ax, 0FF8h
pascal@25454 365 %endif
pascal@25454 366 %else
pascal@25454 367 scasw ; di += 2
pascal@25453 368 cmp ax, 0FFF8h
pascal@25453 369 %endif
pascal@24476 370 xchg ax, si
pascal@24476 371 jc ClusterLoop
pascal@24476 372 pop si
pascal@24476 373 pop di ; file size in sectors
pascal@24476 374
pascal@24476 375 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 376 ;; Load the entire file ;;
pascal@24476 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 378 ;; Input: ES:0 -> buffer ;;
pascal@24476 379 ;; SI = cluster list ;;
pascal@24476 380 ;; DI = file sectors ;;
pascal@24476 381 ;; CH = 0 ;;
pascal@24945 382 ;; BP = 1st data sec ;;
pascal@24476 383 ;; Output: BP:0 -> buffer ;;
pascal@24476 384 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 385
pascal@24476 386 push es
pascal@24476 387
pascal@24476 388 ReadClusters:
pascal@24476 389 lodsw
pascal@24476 390 dec ax
pascal@24476 391 dec ax
pascal@24476 392
pascal@25454 393 mov cl, [bx(bpbSectorsPerCluster)] ; 1..128
pascal@24476 394 mul cx ; cx = sector count (ch = 0)
pascal@24476 395
pascal@24476 396 add ax, bp ; LBA for cluster data
pascal@24476 397 adc dx, bx ; dx:ax = LBA
pascal@24476 398
pascal@25454 399 call ReadSector ; clear ax, restore dx
pascal@24476 400
pascal@24476 401 jne ReadClusters
pascal@24476 402
pascal@24476 403 pop bp ; ImageLoadSeg
pascal@24476 404
pascal@24476 405 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 406 ;; Type detection, .COM or .EXE? ;;
pascal@24476 407 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 408
pascal@24476 409 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 410
pascal@24476 411 add bp, [bx+08h] ; bp = image base
pascal@24476 412 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 413
pascal@24476 414 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 415 je RelocateEXE ; yes, it's an EXE program
pascal@24476 416
pascal@24476 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 418 ;; Setup and run a .COM program ;;
pascal@24476 419 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 420 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 421 ;; cmdline=void ;;
pascal@24476 422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 423
pascal@24942 424 mov di, 100h ; ip
pascal@24476 425 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 426 mov ss, bp
pascal@24476 427 xor sp, sp
pascal@24476 428 push bp ; cs, ds and es
pascal@24476 429 jmp short Run
pascal@24476 430
pascal@24476 431 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 432 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 433 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 434 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 435 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 436 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 437
pascal@24476 438 ReloCycle:
pascal@24476 439 add [di+2], bp ; item seg (abs)
pascal@24476 440 les si, [di] ; si = item ofs, es = item seg
pascal@24476 441 add [es:si], bp ; fixup
pascal@24476 442 scasw ; di += 2
pascal@24476 443 scasw ; point to next entry
pascal@24476 444
pascal@24476 445 RelocateEXE:
pascal@24942 446 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 447 jns ReloCycle
pascal@24476 448 ; PSP don't have a valid drive identifier
pascal@24476 449 les si, [bx+0Eh]
pascal@24476 450 add si, bp
pascal@24476 451 mov ss, si ; ss for EXE
pascal@24476 452 mov sp, es ; sp for EXE
pascal@24476 453
pascal@24476 454 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 455 push si ; containing the PSP structure
pascal@24476 456
pascal@24476 457 add bp, [bx+16h] ; cs for EXE
pascal@24942 458 mov di, [bx+14h] ; ip for EXE
pascal@24476 459 Run:
pascal@24476 460 pop ds
pascal@24476 461 push bp
pascal@24942 462 push di
pascal@24476 463 push ds
pascal@24476 464 pop es
pascal@24942 465 mov [80h], ax ; clear cmdline
pascal@24942 466 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 467
pascal@24476 468 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 469 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 470 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 471 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 472 mov si, 16381 ; prime number 2**14-3
pascal@24476 473 mov di, 32749 ; prime number 2**15-19
pascal@24476 474 mov bp, 65521 ; prime number 2**16-15
pascal@24476 475
pascal@24476 476 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 477 ;; All done, transfer control to the program now ;;
pascal@24476 478 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 479 retf
pascal@24476 480
pascal@24476 481 ReadCXSectors:
pascal@24476 482 mov bp, cx
pascal@24476 483 add bp, ax ; adjust LBA for cluster data
pascal@24476 484
pascal@24476 485 mov di, cx ; no file size limit
pascal@24476 486
pascal@24476 487 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 488 ;; Reads sectors using BIOS Int 13h ;;
pascal@24476 489 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 490 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 491 ;; BX = 0 ;;
pascal@24476 492 ;; CX = sector count ;;
pascal@24476 493 ;; DI = file sectors ;;
pascal@24476 494 ;; ES:BX -> buffer address ;;
pascal@24476 495 ;; Output: ES:BX -> next address ;;
pascal@24476 496 ;; BX = 0 ;;
pascal@24476 497 ;; CX or DI = 0 ;;
pascal@24476 498 ;; DL = drive number ;;
pascal@24476 499 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 500
pascal@24476 501 ReadSector:
pascal@24476 502 add ax, [bx(bpbHiddenSectors)]
pascal@24476 503 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 504 add ax, [bx(bpbReservedSectors)]
pascal@24476 505
pascal@24476 506 push si
pascal@24476 507 ReadSectorNext:
pascal@24476 508 adc dx, bx
pascal@24476 509 push di
pascal@24476 510 push cx
pascal@24476 511
pascal@25450 512 %if LBAsupport != 0
pascal@24476 513 push bx
pascal@24476 514 push bx
pascal@25450 515 %endif
pascal@24476 516 push dx ; 32-bit LBA: up to 2TB
pascal@24476 517 push ax
pascal@24476 518 push es
pascal@25450 519 %if ReadRetry != 0 || LBAsupport != 0
pascal@25450 520 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 521 %endif
pascal@25450 522 %if LBAsupport != 0
pascal@24476 523 push bx
pascal@24476 524 inc bx ; sector count word = 1
pascal@24476 525 push bx
pascal@24476 526 dec bx
pascal@24476 527 push di
pascal@25450 528 %endif
pascal@24476 529
pascal@25450 530 %if Over2GB != 0
pascal@24476 531 xchg ax, cx ; save low LBA
pascal@24476 532 xchg ax, dx ; get high LBA
pascal@25452 533 cwd ; clear dx (LBA offset <1TB)
pascal@25450 534 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 535
pascal@24476 536 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25450 537 %else
pascal@25450 538 xor cx, cx ; up to 2GB disks otherwise divide error interrupt !
pascal@25450 539 %endif
pascal@25450 540 idiv word [bx(bpbSectorsPerTrack)]
pascal@24476 541 ; ax = LBA / SPT
pascal@24476 542 ; dx = LBA % SPT = sector - 1
pascal@24476 543 inc dx
pascal@24476 544
pascal@24476 545 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25450 546 idiv word [bx(bpbHeadsPerCylinder)]
pascal@24476 547 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 548 ; dx = (LBA / SPT) % HPC = head
pascal@24476 549 mov ch, al
pascal@24476 550 ; ch = LSB 0...7 of cylinder no.
pascal@24476 551 mov al, 64
pascal@24476 552 mul ah
pascal@24476 553 or cl, al
pascal@24476 554 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 555 mov dh, dl
pascal@24476 556 ; dh = head no.
pascal@24476 557
pascal@24476 558 ReadSectorRetry:
pascal@25450 559 mov dl, [bx(DriveNumber)]
pascal@24476 560 ; dl = drive no.
pascal@25450 561 mov si, sp
pascal@25450 562 %if LBAsupport != 0
pascal@24476 563 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 564 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 565 jnc ReadSectorNextSegment
pascal@25450 566 %endif
pascal@24476 567
pascal@24476 568 mov ax, 201h ; al = sector count = 1
pascal@24476 569 ; ah = 2 = read function no.
pascal@24476 570 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 571
pascal@24476 572 jnc ReadSectorNextSegment
pascal@25450 573 %if ReadRetry != 0
pascal@24476 574 cbw ; ah = 0 = reset function
pascal@24476 575 int 13h ; reset drive (DL)
pascal@24476 576
pascal@24476 577 dec di
pascal@24476 578 jnz ReadSectorRetry ; extra attempt
pascal@25450 579 %endif
pascal@24476 580
pascal@24476 581 call Error
pascal@24476 582 db "Read error."
pascal@24476 583
pascal@24476 584 ReadSectorNextSegment:
pascal@24476 585
pascal@25450 586 %if LBAsupport != 0
pascal@24476 587 pop ax ; al = 16
pascal@24476 588 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@24476 589 pop cx ; sector count = 1
pascal@24476 590 pop bx
pascal@24476 591 add [si+6], ax ; adjust segment for next sector
pascal@25450 592 %else
pascal@25450 593 mov al, 16
pascal@25450 594 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25450 595 add [si], ax ; adjust segment for next sector
pascal@25450 596 %endif
pascal@24476 597 pop es ; es:0 updated
pascal@24476 598 pop ax
pascal@24476 599 pop dx
pascal@25450 600 %if LBAsupport != 0
pascal@24476 601 pop di
pascal@24476 602 pop di
pascal@24476 603 add ax, cx ; adjust LBA for next sector
pascal@25450 604 %else
pascal@25450 605 add ax, 1 ; adjust LBA for next sector
pascal@25450 606 %endif
pascal@24476 607
pascal@24476 608 pop cx ; cluster sectors to read
pascal@24476 609 pop di ; file sectors to read
pascal@24476 610 dec di ; keep C
pascal@24476 611 loopne ReadSectorNext ; until cluster sector count or file sector count is reached
pascal@24476 612 pop si
pascal@24942 613 mov ax, bx ; clear ax
pascal@25450 614 mov dx, [bx(DriveNumber)] ; pass the BIOS boot drive to Run or Error
pascal@24476 615
pascal@24476 616 ret
pascal@24476 617
pascal@24942 618 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 619 ;; Fill free space with zeroes ;;
pascal@24942 620 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 621
pascal@24942 622 times (512-13-20-($-$$)) db 0
pascal@24942 623
pascal@24476 624 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 625 ;; Error Messaging Code ;;
pascal@24476 626 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 627
pascal@24476 628 Error:
pascal@24476 629 pop si
pascal@24478 630
pascal@24478 631 PutStr:
pascal@24476 632 mov ah, 0Eh
pascal@24476 633 mov bl, 7
pascal@24476 634 lodsb
pascal@24476 635 int 10h
pascal@24476 636 cmp al, "."
pascal@24476 637 jne PutStr
pascal@24476 638
pascal@24476 639 cbw
pascal@24476 640 int 16h ; wait for a key...
pascal@24476 641 int 19h ; bootstrap
pascal@24476 642
pascal@24476 643 Stop:
pascal@24476 644 hlt
pascal@24476 645 jmp short Stop
pascal@24476 646
pascal@24476 647 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 648 ;; Name of the file to load and run ;;
pascal@24476 649 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 650
pascal@24476 651 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@25450 652 times (510-($-$$)) db ' ' ; padded with spaces (11 bytes total)
pascal@25454 653 NameLength equ $-ProgramName
pascal@24476 654
pascal@24476 655 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 656 ;; End of the sector ID ;;
pascal@24476 657 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 658
pascal@24476 659 ClusterList dw 0AA55h ; BIOS checks for this ID
pascal@24479 660