wok-current annotate BootProg/stuff/bootex.asm @ rev 24476

Add some current_version
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri Feb 18 09:29:30 2022 +0000 (2022-02-18)
parents
children 04472f031354
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Limitations: ;;
pascal@24476 28 ;; ~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 29 ;; - Works only on the 1st MBR partition which must be a PRI DOS partition ;;
pascal@24476 30 ;; with exFAT (File System ID: 07h) ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Known Bugs: ;;
pascal@24476 34 ;; ~~~~~~~~~~~ ;;
pascal@24476 35 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 36 ;; on a 128MB qemu image. ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24476 57 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 58 ;; | Boot Sector | ;;
pascal@24476 59 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24476 60 ;; | 1.5KB Boot Stack | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 67 ;; dl = BIOS boot drive number (e.g. 80H) ;;
pascal@24476 68 ;; cs:ip = program entry point ;;
pascal@24476 69 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 70 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 71 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 72 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24476 81 ;; ;;
pascal@24476 82 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 83
pascal@24476 84 %define bx(label) bx+label-boot
pascal@24476 85
pascal@24476 86 [BITS 16]
pascal@24476 87 [CPU 386]
pascal@24476 88
pascal@24476 89 ? equ 0
pascal@24476 90 ImageLoadSeg equ 60h
pascal@24476 91 StackSize equ 1536
pascal@24476 92
pascal@24476 93 [SECTION .text]
pascal@24476 94 [ORG 0]
pascal@24476 95
pascal@24476 96 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 97 ;; Boot sector starts here ;;
pascal@24476 98 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 99
pascal@24476 100 boot:
pascal@24476 101 jmp short start ; Windows checks for this jump
pascal@24476 102 nop
pascal@24476 103 bsOemName DB "EXFAT " ; 0x03
pascal@24476 104 times 53 db 0 ; 0x0B
pascal@24476 105
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107 ;; BPB starts here ;;
pascal@24476 108 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 109
pascal@24476 110 bpbSectorStart DQ ? ; 0x40 partition first sector
pascal@24476 111 bpbSectorCount DQ ? ; 0x48 partition sectors count
pascal@24476 112 bpbFatSectorStart DD ? ; 0x50 FAT first sector
pascal@24476 113 bpbFatSectorCount DD ? ; 0x54 FAT sectors count
pascal@24476 114 bpbClusterSectorStart DD ? ; 0x58 first cluster sector
pascal@24476 115 bpbClusterCount DD ? ; 0x5C total clusters count
pascal@24476 116 bpbRootDirCluster DD ? ; 0x60 first cluster of the root dir
pascal@24476 117 bpbVolumeSerial DD ? ; 0x64 volume serial number
pascal@24476 118 bpbFSVersionMinor DB ? ; 0x68
pascal@24476 119 bpbFSVersionMajor DB ? ; 0x69
pascal@24476 120 bpbVolumeStateFlags DW ? ; 0x6A
pascal@24476 121 bpbSectorSizeBits DB ? ; 0x6C sector size as (1 << n)
pascal@24476 122 bpbSectorPerClusterBits DB ? ; 0x6D sector per cluster as (1 << n)
pascal@24476 123 bpbNumberOfFATs DB ? ; 0x6E always 1
pascal@24476 124 bpbDriveNumber DB ? ; 0x6F alaways 0x80
pascal@24476 125 bpbAllocatedPercent DB ? ; 0x70 percentage of allocated space
pascal@24476 126
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;
pascal@24476 128 ;; BPB ends here ;;
pascal@24476 129 ;;;;;;;;;;;;;;;;;;;
pascal@24476 130
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 132 ;; Boot sector code starts here ;;
pascal@24476 133 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 134
pascal@24476 135 start:
pascal@24476 136 cld
pascal@24476 137
pascal@24476 138 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 139 ;; How much RAM is there? ;;
pascal@24476 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 141
pascal@24476 142 int 12h ; get conventional memory size (in KBs)
pascal@24476 143 mov cx, 106h
pascal@24476 144 dec ax
pascal@24476 145 dec ax ; reserve 2K bytes for the code and the stack
pascal@24476 146 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 147
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 151
pascal@24476 152 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 153 mov ss, ax
pascal@24476 154 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 155
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157 ;; Copy ourselves to top of memory ;;
pascal@24476 158 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 159
pascal@24476 160 mov si, 7C00h
pascal@24476 161 xor di, di
pascal@24476 162 mov ds, di
pascal@24476 163 rep movsw ; move 512 bytes (+ 12)
pascal@24476 164
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 166 ;; Jump to the copy ;;
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168
pascal@24476 169 push es
pascal@24476 170 push main
pascal@24476 171 retf
pascal@24476 172
pascal@24476 173 main:
pascal@24476 174 push cs
pascal@24476 175 pop ds
pascal@24476 176
pascal@24476 177 xor ebx, ebx
pascal@24476 178 mov [bx], dx ; store BIOS boot drive number
pascal@24476 179
pascal@24476 180 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 181
pascal@24476 182 push ImageLoadSeg
pascal@24476 183 pop es
pascal@24476 184
pascal@24476 185 RootDirReadContinue:
pascal@24476 186 call ReadCluster ; read one sector of root dir
pascal@24476 187 pushf ; save carry="not last sector" flag
pascal@24476 188
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 191 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 192
pascal@24476 193 xor di, di ; es:di -> root entries array
pascal@24476 194
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196 ;; Looks for the file/dir ProgramName ;;
pascal@24476 197 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 198 ;; Input: ES:DI -> root directory array ;;
pascal@24476 199 ;; Output: ESI = cluster number ;;
pascal@24476 200 ;; dword [bx+FileSize] file size ;;
pascal@24476 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 202
pascal@24476 203 CurNameSize equ 3
pascal@24476 204 StartCluster equ 14h
pascal@24476 205 FileSize equ 18h
pascal@24476 206
pascal@24476 207 FindNameCycle:
pascal@24476 208 pusha
pascal@24476 209
pascal@24476 210 xor ax, ax
pascal@24476 211 or al, [es:di]
pascal@24476 212 je FindNameFailed
pascal@24476 213
pascal@24476 214 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 215 jne NotFileInfo
pascal@24476 216
pascal@24476 217 mov bl, 30
pascal@24476 218 CopyInfo:
pascal@24476 219 mov ax, [es:di+bx]
pascal@24476 220 mov [bx], ax
pascal@24476 221 dec bx
pascal@24476 222 dec bx
pascal@24476 223 jnz CopyInfo
pascal@24476 224
pascal@24476 225 NotFileInfo:
pascal@24476 226 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 227 mov cx, NameLength+1
pascal@24476 228 mov si, ProgramName ; ds:si -> program name
pascal@24476 229 CheckName:
pascal@24476 230 scasw ; compare UTF-16
pascal@24476 231 lodsb ; with ASCII
pascal@24476 232 loope CheckName
pascal@24476 233 je FindNameFound ; cx = 0
pascal@24476 234 popa ; restore ax, cx, si, di
pascal@24476 235
pascal@24476 236 add di, 32
pascal@24476 237 cmp di, bp
pascal@24476 238 jne FindNameCycle ; next root entry
pascal@24476 239 popf ; restore carry="not last sector" flag
pascal@24476 240 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 241 FindNameFailed: ; end of root directory (dir end reached)
pascal@24476 242 call Error
pascal@24476 243 db "File not found."
pascal@24476 244 FindNameFound:
pascal@24476 245 mov esi, [bx+StartCluster]
pascal@24476 246
pascal@24476 247 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 248 ;; Load the entire file ;;
pascal@24476 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 250
pascal@24476 251 push es
pascal@24476 252 xor bp, bp
pascal@24476 253 FileReadContinue:
pascal@24476 254 shr bp, 4 ; bytes to paragraphs
pascal@24476 255 mov di, es
pascal@24476 256 add di, bp ; adjust segment for next sector
pascal@24476 257 mov es, di ; es:0 updated
pascal@24476 258 call ReadCluster ; read one cluster of root dir
pascal@24476 259 sub [bx+FileSize], ebp
pascal@24476 260 ja FileReadContinue
pascal@24476 261 pop bp
pascal@24476 262
pascal@24476 263 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 264 ;; Type detection, .COM or .EXE? ;;
pascal@24476 265 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 266
pascal@24476 267 mov dl, [bx] ; pass the BIOS boot drive
pascal@24476 268 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 269
pascal@24476 270 add bp, [bx+08h] ; bp = image base
pascal@24476 271 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 272 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 273
pascal@24476 274 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 275 je RelocateEXE ; yes, it's an EXE program
pascal@24476 276
pascal@24476 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 278 ;; Setup and run a .COM program ;;
pascal@24476 279 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24476 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 281
pascal@24476 282 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 283 mov ss, bp
pascal@24476 284 xor sp, sp
pascal@24476 285 push bp ; cs, ds and es
pascal@24476 286 mov bh, 1 ; ip
pascal@24476 287 jmp short Run
pascal@24476 288
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 291 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 292 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24476 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 294
pascal@24476 295 ReloCycle:
pascal@24476 296 add [di+2], bp ; item seg (abs)
pascal@24476 297 les si, [di] ; si = item ofs, es = item seg
pascal@24476 298 add [es:si], bp ; fixup
pascal@24476 299 scasw ; di += 2
pascal@24476 300 scasw ; point to next entry
pascal@24476 301
pascal@24476 302 RelocateEXE:
pascal@24476 303 dec ax ; 32768 max (128KB table)
pascal@24476 304 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 305 ; PSP don't have a valid drive identifier
pascal@24476 306 les si, [bx+0Eh]
pascal@24476 307 add si, bp
pascal@24476 308 mov ss, si ; ss for EXE
pascal@24476 309 mov sp, es ; sp for EXE
pascal@24476 310
pascal@24476 311 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 312 push si ; containing the PSP structure
pascal@24476 313
pascal@24476 314 add bp, [bx+16h] ; cs for EXE
pascal@24476 315 mov bx, [bx+14h] ; ip for EXE
pascal@24476 316 Run:
pascal@24476 317 pop ds
pascal@24476 318 push bp
pascal@24476 319 push bx
pascal@24476 320 push ds
pascal@24476 321 pop es
pascal@24476 322
pascal@24476 323 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 324 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 325 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 326 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 327 mov si, 16381 ; prime number 2**14-3
pascal@24476 328 mov di, 32749 ; prime number 2**15-19
pascal@24476 329 mov bp, 65521 ; prime number 2**16-15
pascal@24476 330
pascal@24476 331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 332 ;; All done, transfer control to the program now ;;
pascal@24476 333 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 334 retf
pascal@24476 335
pascal@24476 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 337 ;; Reads a exFAT cluster ;;
pascal@24476 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 339 ;; Input: EDX:EAX = LBA ;;
pascal@24476 340 ;; EBX = 0 ;;
pascal@24476 341 ;; CX = sector cnt ;;
pascal@24476 342 ;; ESI = cluster no ;;
pascal@24476 343 ;; ES:0 -> buffer adrs ;;
pascal@24476 344 ;; Output: EBX = 0 ;;
pascal@24476 345 ;; CX = next cnt ;;
pascal@24476 346 ;; EBP = bytes/sector;;
pascal@24476 347 ;; ES:0 -> next adrs ;;
pascal@24476 348 ;; C=0 for last sector ;;
pascal@24476 349 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 350
pascal@24476 351 ReadCluster:
pascal@24476 352 inc cx ; jcxnz
pascal@24476 353 add eax, 1
pascal@24476 354 loop ReadSectorC
pascal@24476 355
pascal@24476 356 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 357 dec cx
pascal@24476 358 dec cx
pascal@24476 359 mul ebx ; edx:eax = 0
pascal@24476 360 inc ax
pascal@24476 361 shl eax, cl ; eax=# of exFAT entries per sector
pascal@24476 362 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 363 xchg eax, esi
pascal@24476 364 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 365
pascal@24476 366 imul si, dx, 4 ; si=entry # offset in sector
pascal@24476 367
pascal@24476 368 cdq
pascal@24476 369 add eax, [bx(bpbFatSectorStart)] ; sector # relative to FAT32
pascal@24476 370 call ReadSectorC ; read 1 FAT32 sector
pascal@24476 371
pascal@24476 372 mov esi, [es:si] ; esi=next cluster #
pascal@24476 373
pascal@24476 374 xor eax, eax
pascal@24476 375 inc ax
pascal@24476 376 mov cl, [bx(bpbSectorPerClusterBits)]
pascal@24476 377 shl eax, cl ; 10000h max (32MB cluster)
pascal@24476 378 xchg eax, ecx
pascal@24476 379 xchg eax, edi ; get cluster #-2
pascal@24476 380 mul ecx
pascal@24476 381
pascal@24476 382 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 383 ReadSectorC:
pascal@24476 384 adc edx, ebx
pascal@24476 385
pascal@24476 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 387 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 389 ;; Input: EDX:EAX = LBA ;;
pascal@24476 390 ;; BX = 0 ;;
pascal@24476 391 ;; CX = sector count ;;
pascal@24476 392 ;; ES:0 -> buffer address ;;
pascal@24476 393 ;; Output: BX = 0 ;;
pascal@24476 394 ;; CX = next count ;;
pascal@24476 395 ;; EBP = bytes/sector ;;
pascal@24476 396 ;; ES:0 -> next address ;;
pascal@24476 397 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 398
pascal@24476 399 ReadSector:
pascal@24476 400
pascal@24476 401 xor ebp, ebp
pascal@24476 402 inc bp
pascal@24476 403
pascal@24476 404 pushad
pascal@24476 405
pascal@24476 406 add eax, [bx(bpbSectorStart)]
pascal@24476 407 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 408
pascal@24476 409 push edx
pascal@24476 410 push eax
pascal@24476 411 push es
pascal@24476 412 push bx
pascal@24476 413 push bp ; sector count word = 1
pascal@24476 414 mov cx, 16
pascal@24476 415 push cx ; packet size byte = 16, reserved byte = 0
pascal@24476 416 ReadSectorRetry:
pascal@24476 417 mov si, sp
pascal@24476 418 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 419 mov dl, [bx]
pascal@24476 420 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 421
pascal@24476 422 jnc ReadSuccess
pascal@24476 423
pascal@24476 424 xor ax, ax
pascal@24476 425 int 13h ; reset drive (DL)
pascal@24476 426 loop ReadSectorRetry
pascal@24476 427
pascal@24476 428 call Error
pascal@24476 429 db "Read error."
pascal@24476 430
pascal@24476 431 ReadSuccess:
pascal@24476 432 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 433 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@24476 434 popa ; sp += 16
pascal@24476 435 popad ; real registers
pascal@24476 436
pascal@24476 437 stc
pascal@24476 438 loop ReadSectorNext
pascal@24476 439
pascal@24476 440 cmp esi, 0FFFFFFF6h ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 441 ReadSectorNext:
pascal@24476 442 ret
pascal@24476 443
pascal@24476 444 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 445 ;; Error Messaging Code ;;
pascal@24476 446 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 447
pascal@24476 448 Error:
pascal@24476 449 pop si
pascal@24476 450 mov dl, [bx] ; restore BIOS boot drive number
pascal@24476 451 mov ah, 0Eh
pascal@24476 452 mov bl, 7
pascal@24476 453
pascal@24476 454 PutStr:
pascal@24476 455 lodsb
pascal@24476 456 int 10h
pascal@24476 457 cmp al, "."
pascal@24476 458 jne PutStr
pascal@24476 459
pascal@24476 460 cbw
pascal@24476 461 int 16h ; wait for a key...
pascal@24476 462 int 19h ; bootstrap
pascal@24476 463
pascal@24476 464 Stop:
pascal@24476 465 hlt
pascal@24476 466 jmp short Stop
pascal@24476 467
pascal@24476 468 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 469 ;; Fill free space with zeroes ;;
pascal@24476 470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 471
pascal@24476 472 times (512-13-($-$$)) db 0
pascal@24476 473
pascal@24476 474 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 475 ;; Name of the file to load and run ;;
pascal@24476 476 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 477
pascal@24476 478 ProgramName db "startup.bin" ; name and extension
pascal@24476 479 NameLength equ $-ProgramName
pascal@24476 480
pascal@24476 481 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 482 ;; End of the sector ID ;;
pascal@24476 483 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 484
pascal@24476 485 dw 0AA55h ; BIOS checks for this ID