wok-current annotate BootProg/stuff/boot32.asm @ rev 25458

Update some web_site
author Pascal Bellard <pascal.bellard@slitaz.org>
date Tue Sep 27 16:21:52 2022 +0000 (21 months ago)
parents ad0bc3efbf37
children 7dd01dedad38
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24525 20 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 23 ;; ("File not found" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; Known Bugs: ;;
pascal@24476 29 ;; ~~~~~~~~~~~ ;;
pascal@24476 30 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 31 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; ;;
pascal@24476 34 ;; Memory Layout: ;;
pascal@24476 35 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 36 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 37 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 38 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 39 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; physical address ;;
pascal@24476 42 ;; +------------------------+ 00000H ;;
pascal@24476 43 ;; | Interrupt Vector Table | ;;
pascal@24476 44 ;; +------------------------+ 00400H ;;
pascal@24476 45 ;; | BIOS Data Area | ;;
pascal@24476 46 ;; +------------------------+ 00500H ;;
pascal@24476 47 ;; | PrtScr Status / Unused | ;;
pascal@24476 48 ;; +------------------------+ 00600H ;;
pascal@24476 49 ;; | Loaded Image | ;;
pascal@24476 50 ;; +------------------------+ nnnnnH ;;
pascal@24476 51 ;; | Available Memory | ;;
pascal@24525 52 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 53 ;; | Boot Sector | ;;
pascal@24525 54 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24525 55 ;; | 1.5KB Boot Stack | ;;
pascal@24476 56 ;; +------------------------+ A0000H ;;
pascal@24476 57 ;; | Video RAM | ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; ;;
pascal@24476 60 ;; Boot Image Startup (register values): ;;
pascal@24476 61 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 62 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 63 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 64 ;; cs:ip = program entry point ;;
pascal@24476 65 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 66 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 67 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 68 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 69 ;; Magic numbers: ;;
pascal@24476 70 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 71 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 72 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 73 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 74 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 75 ;; metal and MS-DOS programs. ;;
pascal@24945 76 ;; The command line contains no arguments. ;;
pascal@24476 77 ;; ;;
pascal@24476 78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 79
pascal@24491 80 %define bx(label) bx+label-boot
pascal@25449 81 %define si(label) si+label-boot
pascal@25449 82 ClusterMask equ 1 ; +9 bytes
pascal@25458 83 NullEntryCheck equ 0 ; +5 bytes
pascal@25449 84 ReadRetry equ 1 ; +7 bytes
pascal@25458 85 LBA48bits equ 1 ; +15 bytes
pascal@25449 86 CHSsupport equ 1 ; +27 bytes
pascal@25458 87 CHSupTo8GB equ 1 ; +11 bytes
pascal@25458 88 CHSupTo32MB equ 1 ; +7 bytes
pascal@25458 89 SectorOf512Bytes equ 1 ; -5 bytes
pascal@25458 90 Always2FATs equ 0 ; -4 bytes
pascal@24491 91
pascal@24476 92 [BITS 16]
pascal@24476 93
pascal@24478 94 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@24525 95 StackSize equ 1536
pascal@24476 96
pascal@24476 97 [SECTION .text]
pascal@24476 98 [ORG 0]
pascal@24476 99
pascal@24476 100 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 101 ;; Boot sector starts here ;;
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103
pascal@24491 104 boot:
pascal@25458 105 DriveNumber equ boot+0
pascal@25458 106 HiLBA equ boot+2
pascal@24476 107 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 108 nop
pascal@24476 109 bsOemName DB "BootProg" ; 0x03
pascal@24476 110
pascal@24476 111 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 112 ;; BPB1 starts here ;;
pascal@24476 113 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 114
pascal@24479 115 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 116 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 117 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 118 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 119 bpbRootEntries DW 0 ; 0x11
pascal@24479 120 bpbTotalSectors DW 0 ; 0x13
pascal@24479 121 bpbMedia DB 0 ; 0x15
pascal@24479 122 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 123 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 124 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 125 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 126 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 127
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 129 ;; BPB1 ends here ;;
pascal@24476 130 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 131
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133 ;; BPB2 starts here ;;
pascal@24476 134 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 135
pascal@24479 136 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 137 bsExtendedFlags DW 0 ; 0x28
pascal@24479 138 bsFSVersion DW 0 ; 0x2A
pascal@24479 139 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 140 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 141 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 142 bsreserved times 12 DB 0 ; 0x34
pascal@24479 143 bsDriveNumber DB 0 ; 0x40
pascal@24479 144 bsreserved1 DB 0 ; 0x41
pascal@24479 145 bsExtendedBootSignature DB 0 ; 0x42
pascal@24479 146 bsVolumeSerialNumber DD 0 ; 0x43
pascal@25458 147 bsVolumeLabel times 11 DB " " ; 0x47 "NO NAME "
pascal@25458 148 bsFileSystemName times 8 DB " " ; 0x52 "FAT32 "
pascal@24476 149
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 151 ;; BPB2 ends here ;;
pascal@24476 152 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Boot sector code starts here ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 start:
pascal@24476 159 cld
pascal@24476 160
pascal@24476 161 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 162 ;; How much RAM is there? ;;
pascal@24476 163 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 164
pascal@24476 165 int 12h ; get conventional memory size (in KBs)
pascal@24525 166 dec ax
pascal@24525 167 dec ax ; reserve 2K bytes for the code and the stack
pascal@24525 168 mov cx, 106h
pascal@24525 169 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 170
pascal@24476 171 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 172 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 173 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 174
pascal@24525 175 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24525 176 mov ss, ax
pascal@24525 177 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 178
pascal@24476 179 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 180 ;; Copy ourselves to top of memory ;;
pascal@24476 181 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 182
pascal@24476 183 mov si, 7C00h
pascal@24476 184 xor di, di
pascal@24476 185 mov ds, di
pascal@25449 186 push es
pascal@25449 187 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24478 188 rep movsw
pascal@24476 189
pascal@24476 190 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 191 ;; Jump to the copy ;;
pascal@24476 192 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 193
pascal@25450 194 push byte main
pascal@24476 195 retf
pascal@24476 196
pascal@24476 197 main:
pascal@24476 198 push cs
pascal@24476 199 pop ds
pascal@24476 200
pascal@25449 201 xor ebx, ebx
pascal@24476 202
pascal@25449 203 %if ClusterMask != 0
pascal@24491 204 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@25449 205 %endif
pascal@24491 206 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 207
pascal@24478 208 push byte ImageLoadSeg
pascal@24478 209 pop es
pascal@25449 210
pascal@25449 211 RootDirReadContinue:
pascal@25458 212 call ReadClusterSector ; read one sector of the root dir
pascal@24476 213
pascal@24476 214 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 215 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 216 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 217
pascal@24476 218 xor di, di ; es:di -> root entries array
pascal@24476 219
pascal@24476 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 221 ;; Looks for a file/dir by its name ;;
pascal@24476 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 223 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 224 ;; ES:DI -> root directory array ;;
pascal@24525 225 ;; BP = paragraphs in sector ;;
pascal@24476 226 ;; Output: ESI = cluster number ;;
pascal@24476 227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 228
pascal@24476 229 FindNameCycle:
pascal@25449 230 %if NullEntryCheck != 0
pascal@24525 231 cmp byte [es:di], bh
pascal@24478 232 je ErrFind ; end of root directory (NULL entry found)
pascal@25449 233 %endif
pascal@24478 234 pusha
pascal@25454 235 mov cl, NameLength
pascal@24525 236 mov si, ProgramName ; ds:si -> program name
pascal@24476 237 repe cmpsb
pascal@24525 238 je FindNameFound
pascal@24478 239 popa
pascal@24525 240 add di, byte 32
pascal@24476 241 dec bp
pascal@24476 242 dec bp
pascal@24476 243 jnz FindNameCycle ; next root entry
pascal@25458 244 loop RootDirReadContinue ; next sector in cluster
pascal@25458 245 cmp esi, 0FFFFFF6h ; carry=0 if last cluster, and carry=1 otherwise
pascal@25458 246 jnc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 247 ErrFind:
pascal@24478 248 call Error ; end of root directory (dir end reached)
pascal@24476 249 db "File not found."
pascal@24476 250 FindNameFound:
pascal@24525 251 push word [es:di+14h-11]
pascal@24525 252 push word [es:di+1Ah-11]
pascal@24478 253 pop esi ; esi = cluster no. cx = 0
pascal@24476 254
pascal@24525 255 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 256 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 257
pascal@24476 258 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 259 ;; Load the entire file ;;
pascal@24476 260 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 261
pascal@24476 262 push es
pascal@24476 263 FileReadContinue:
pascal@24476 264 push di
pascal@25458 265 call ReadClusterSector ; read one sector of the boot file
pascal@25458 266 dec cx
pascal@24476 267 mov di, es
pascal@24478 268 add di, bp
pascal@24478 269 mov es, di ; es:bx updated
pascal@24476 270 pop di
pascal@24478 271
pascal@24476 272 sub di, bp
pascal@24476 273 jae FileReadContinue
pascal@24943 274 xor ax, ax
pascal@24476 275 pop bp
pascal@24476 276
pascal@24476 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 278 ;; Type detection, .COM or .EXE? ;;
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280
pascal@24476 281 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 282
pascal@24476 283 add bp, [bx+08h] ; bp = image base
pascal@24476 284 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 285
pascal@24476 286 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 287 je RelocateEXE ; yes, it's an EXE program
pascal@24476 288
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Setup and run a .COM program ;;
pascal@24535 291 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 292 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 293 ;; cmdline=void ;;
pascal@24476 294 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 295
pascal@24535 296 mov di, 100h ; ip
pascal@24476 297 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 298 mov ss, bp
pascal@24476 299 xor sp, sp
pascal@24476 300 push bp ; cs, ds and es
pascal@24476 301 jmp short Run
pascal@24476 302
pascal@24476 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 304 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 305 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 306 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 307 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 308 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 309
pascal@24476 310 ReloCycle:
pascal@24476 311 add [di+2], bp ; item seg (abs)
pascal@24476 312 les si, [di] ; si = item ofs, es = item seg
pascal@24476 313 add [es:si], bp ; fixup
pascal@24525 314 scasw ; di += 2
pascal@24525 315 scasw ; point to next entry
pascal@24476 316
pascal@24476 317 RelocateEXE:
pascal@24942 318 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 319 jns ReloCycle
pascal@24942 320
pascal@24945 321 les si, [bx+0Eh]
pascal@24945 322 add si, bp
pascal@24945 323 mov ss, si ; ss for EXE
pascal@24945 324 mov sp, es ; sp for EXE
pascal@24476 325
pascal@24476 326 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 327 push si ; containing the PSP structure
pascal@24476 328
pascal@24476 329 add bp, [bx+16h] ; cs for EXE
pascal@24535 330 mov di, [bx+14h] ; ip for EXE
pascal@24476 331 Run:
pascal@24476 332 pop ds
pascal@24476 333 push bp
pascal@24535 334 push di
pascal@24476 335 push ds
pascal@24476 336 pop es
pascal@24942 337 mov [80h], ax ; clear cmdline
pascal@24942 338 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 339
pascal@24476 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 341 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 342 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 344 mov si, 16381 ; prime number 2**14-3
pascal@24476 345 mov di, 32749 ; prime number 2**15-19
pascal@24476 346 mov bp, 65521 ; prime number 2**16-15
pascal@24476 347
pascal@24476 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 349 ;; All done, transfer control to the program now ;;
pascal@24476 350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 351 retf
pascal@24476 352
pascal@25458 353 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 354 ;; Error Messaging Code ;;
pascal@25458 355 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 356
pascal@25458 357 Error:
pascal@25458 358 pop si
pascal@25458 359 puts:
pascal@25458 360 mov ah, 0Eh
pascal@25458 361 mov bl, 7
pascal@25458 362 lodsb
pascal@25458 363 int 10h
pascal@25458 364 cmp al, '.'
pascal@25458 365 jne puts
pascal@25458 366 cbw
pascal@25458 367 int 16h ; wait for a key...
pascal@25458 368 int 19h ; bootstrap
pascal@25458 369
pascal@25458 370 Stop:
pascal@25458 371 hlt
pascal@25458 372 jmp short Stop
pascal@25458 373
pascal@25458 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 375 ;; Reads a FAT32 sector ;;
pascal@25458 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 377 ;; Inout: ES:BX -> buffer ;;
pascal@25458 378 ;; EAX = prev sector ;;
pascal@25458 379 ;; CX = rem sectors in cluster ;;
pascal@25458 380 ;; ESI = next cluster ;;
pascal@25458 381 ;; Output: EAX = current sector ;;
pascal@25458 382 ;; CX = rem sectors in cluster ;;
pascal@25458 383 ;; ESI = next cluster ;;
pascal@25458 384 ;; BP -> para / sector ;;
pascal@25458 385 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 386
pascal@25458 387 ReadClusterSector:
pascal@25458 388 %if SectorOf512Bytes != 0
pascal@25458 389 mov bp, 32 ; bp = paragraphs per sector
pascal@25458 390 %else
pascal@24525 391 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 392 shr bp, 4 ; bp = paragraphs per sector
pascal@25458 393 %endif
pascal@25449 394 mov dx, 1 ; adjust LBA for next sector
pascal@24525 395 inc cx
pascal@24525 396 loop ReadSectorLBA
pascal@24525 397
pascal@25449 398 mul ebx ; edx:eax = 0
pascal@25458 399 %if SectorOf512Bytes != 0
pascal@25458 400 mov al, 128 ; ax=# of FAT32 entries per sector
pascal@25458 401 %else
pascal@24945 402 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@25458 403 %endif
pascal@24525 404 lea edi, [esi-2] ; esi=cluster #
pascal@24476 405 xchg eax, esi
pascal@24478 406 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 407
pascal@24525 408 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@25449 409 %if LBA48bits != 0
pascal@25458 410 xor dx, dx
pascal@25449 411 %endif
pascal@25458 412 call ReadSectorLBAfromFAT ; read 1 FAT32 sector
pascal@24476 413
pascal@25449 414 %if ClusterMask != 0
pascal@24478 415 and byte [es:si+3], 0Fh ; mask cluster value
pascal@25449 416 %endif
pascal@24478 417 mov esi, [es:si] ; esi=next cluster #
pascal@24476 418
pascal@25458 419 %if Always2FATs != 0
pascal@25458 420 imul eax, dword [bx(bsSectorsPerFAT32)], 2
pascal@25458 421 %else
pascal@24525 422 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 423 mul dword [bx(bsSectorsPerFAT32)]
pascal@25458 424 %endif
pascal@24525 425
pascal@24525 426 xchg eax, edi
pascal@25454 427 movzx ecx, byte [bx(bpbSectorsPerCluster)] ; 8..128
pascal@24945 428 mul ecx ; edx:eax=sector number in data area
pascal@24525 429 add eax, edi
pascal@25458 430 %if LBA48bits != 0
pascal@25458 431 adc dx, bx
pascal@25458 432 %endif
pascal@24476 433
pascal@25458 434 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 435 ;; Reads a sector form the start of FAT ;;
pascal@25458 436 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 437
pascal@25458 438 ReadSectorLBAfromFAT:
pascal@25458 439 add eax, [bx(bpbHiddenSectors)]
pascal@25449 440 %if LBA48bits != 0
pascal@25449 441 adc dx, bx
pascal@25449 442 mov word [bx(HiLBA)], dx
pascal@25449 443 %endif
pascal@25454 444 mov dx, [bx(bpbReservedSectors)]
pascal@24476 445
pascal@24478 446 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 447 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 448 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 449 ;; Input: EAX = LBA ;;
pascal@24478 450 ;; CX = sector count ;;
pascal@24478 451 ;; ES:BX -> buffer address ;;
pascal@24478 452 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 453 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 454
pascal@24476 455 ReadSectorLBA:
pascal@25449 456 add eax, edx
pascal@25449 457 %if LBA48bits != 0
pascal@24535 458 adc word [bx(HiLBA)], bx
pascal@25449 459 %endif
pascal@25449 460 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 461 pusha
pascal@24476 462
pascal@24478 463 push bx
pascal@25449 464 %if LBA48bits != 0
pascal@24491 465 push word [bx(HiLBA)] ; 48-bit LBA
pascal@25449 466 %else
pascal@25449 467 push bx
pascal@25449 468 %endif
pascal@24478 469 push eax
pascal@24476 470 push es
pascal@24476 471 push bx
pascal@24478 472 push byte 1 ; sector count word = 1
pascal@24525 473 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 474
pascal@25449 475 %if CHSsupport != 0
pascal@25458 476 %if CHSupTo8GB != 0
pascal@25449 477 push eax
pascal@25449 478 pop cx ; save low LBA
pascal@25449 479 pop ax ; get high LBA
pascal@25449 480 cwd ; clear dx (assume LBA offset <1TB)
pascal@25449 481 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks, avoid divide error
pascal@25449 482
pascal@25449 483 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25458 484 %else
pascal@25449 485 ; Busybox mkdosfs creates fat32 for floppies.
pascal@25449 486 ; Floppies may support CHS only.
pascal@25458 487 %if CHSupTo32MB != 0
pascal@25458 488 xor dx, dx ; clear dx (LBA offset <32MB)
pascal@25458 489 %else
pascal@25449 490 cwd ; clear dx (LBA offset <16MB)
pascal@25458 491 %endif
pascal@25450 492 xor cx, cx ; high LBA / SPT = 0
pascal@25458 493 %endif
pascal@25449 494 idiv word [bx(bpbSectorsPerTrack)]
pascal@25449 495 ; ax = LBA / SPT
pascal@25449 496 ; dx = LBA % SPT = sector - 1
pascal@25449 497 inc dx
pascal@25449 498
pascal@25449 499 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25450 500 idiv word [bx(bpbHeadsPerCylinder)]
pascal@25449 501 ; ax = (LBA / SPT) / HPC = cylinder
pascal@25449 502 ; dx = (LBA / SPT) % HPC = head
pascal@25449 503
pascal@25458 504 xchg ch, al ; clear al
pascal@25449 505 ; ch = LSB 0...7 of cylinder no.
pascal@25458 506 %if CHSupTo8GB != 0 || CHSupTo32MB != 0
pascal@25458 507 shr ax, 2
pascal@25458 508 or cl, al
pascal@25449 509 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@25458 510 %endif
pascal@25449 511 mov dh, dl
pascal@25449 512 ; dh = head no.
pascal@25449 513 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25449 514 %endif
pascal@25449 515
pascal@25454 516 ReadSectorRetry:
pascal@24525 517 mov si, sp
pascal@24478 518 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 519 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 520 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 521
pascal@25449 522 %if CHSsupport != 0
pascal@25449 523 mov ax, 201h ; al = sector count = 1
pascal@25449 524 ; ah = 2 = read function no.
pascal@25449 525 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@25449 526
pascal@25449 527 jnc ReadSuccess ; CF = 0 if no error
pascal@25449 528 %endif
pascal@25449 529 %if ReadRetry != 0
pascal@25458 530 %if CHSsupport != 0
pascal@25449 531 cbw ; ah = 0 = reset function
pascal@25458 532 %else
pascal@24945 533 xor ax, ax ; ah = 0 = reset function
pascal@25458 534 %endif
pascal@24476 535 int 13h ; reset drive (DL)
pascal@24476 536
pascal@25457 537 dec bp ; up to 32 retries
pascal@25454 538 jnz ReadSectorRetry
pascal@25449 539 %endif
pascal@24525 540
pascal@24476 541 call Error
pascal@24476 542 db "Read error."
pascal@24476 543
pascal@24478 544 ReadSuccess:
pascal@24476 545
pascal@24476 546 popa ; sp += 16
pascal@24478 547 popa
pascal@24476 548 ret
pascal@24476 549
pascal@24942 550 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 551 ;; Fill free space with zeroes ;;
pascal@24942 552 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 553
pascal@25458 554 times (512-13-($-$$)) db 0
pascal@24476 555
pascal@24476 556 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 557 ;; Name of the file to load and run ;;
pascal@24476 558 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 559
pascal@24476 560 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@25449 561 times (510-($-$$)) db ' ' ; padded with spaces (11 bytes total)
pascal@25454 562 NameLength equ $-ProgramName
pascal@24476 563
pascal@24476 564 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 565 ;; End of the sector ID ;;
pascal@24476 566 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 567
pascal@24476 568 dw 0AA55h ; BIOS checks for this ID