wok annotate BootProg/stuff/boot32.asm @ rev 24478

Typos in BootProg
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri Feb 18 10:06:45 2022 +0000 (2022-02-18)
parents 89c8d8b6cf48
children d211771a0500
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24478 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24478 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Limitations: ;;
pascal@24476 28 ;; ~~~~~~~~~~~~~~~~~~ ;;
pascal@24478 29 ;; - Works only on the 1st MBR partition which must be a DOS partition ;;
pascal@24476 30 ;; with FAT32 (File System ID: 0Bh,0Ch) ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Known Bugs: ;;
pascal@24476 34 ;; ~~~~~~~~~~~ ;;
pascal@24476 35 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 36 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24478 57 ;; +------------------------+ A0000H - 512 - 2KB ;;
pascal@24478 58 ;; | 2KB Boot Stack | ;;
pascal@24478 59 ;; +------------------------+ A0000H - 512 ;;
pascal@24476 60 ;; | Boot Sector | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 67 ;; dl = BIOS boot drive number (e.g. 80H) ;;
pascal@24476 68 ;; cs:ip = program entry point ;;
pascal@24476 69 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 70 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 71 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 72 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24476 81 ;; ;;
pascal@24476 82 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 83
pascal@24476 84 [BITS 16]
pascal@24476 85
pascal@24476 86 ? equ 0
pascal@24478 87 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@24476 88
pascal@24476 89 [SECTION .text]
pascal@24476 90 [ORG 0]
pascal@24476 91
pascal@24476 92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 93 ;; Boot sector starts here ;;
pascal@24476 94 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 95
pascal@24476 96 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 97 nop
pascal@24476 98 bsOemName DB "BootProg" ; 0x03
pascal@24476 99
pascal@24476 100 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 101 ;; BPB1 starts here ;;
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103
pascal@24476 104 bpbBytesPerSector DW ? ; 0x0B
pascal@24476 105 bpbSectorsPerCluster DB ? ; 0x0D
pascal@24476 106 bpbReservedSectors DW ? ; 0x0E
pascal@24476 107 bpbNumberOfFATs DB ? ; 0x10
pascal@24476 108 bpbRootEntries DW ? ; 0x11
pascal@24476 109 bpbTotalSectors DW ? ; 0x13
pascal@24476 110 bpbMedia DB ? ; 0x15
pascal@24476 111 bpbSectorsPerFAT DW ? ; 0x16
pascal@24476 112 bpbSectorsPerTrack DW ? ; 0x18
pascal@24476 113 bpbHeadsPerCylinder DW ? ; 0x1A
pascal@24476 114 bpbHiddenSectors DD ? ; 0x1C
pascal@24476 115 bpbTotalSectorsBig DD ? ; 0x20
pascal@24476 116
pascal@24476 117 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 118 ;; BPB1 ends here ;;
pascal@24476 119 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 120
pascal@24476 121 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 122 ;; BPB2 starts here ;;
pascal@24476 123 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 124
pascal@24476 125 bsSectorsPerFAT32 DD ? ; 0x24
pascal@24476 126 bsExtendedFlags DW ? ; 0x28
pascal@24476 127 bsFSVersion DW ? ; 0x2A
pascal@24476 128 bsRootDirectoryClusterNo DD ? ; 0x2C
pascal@24476 129 bsFSInfoSectorNo DW ? ; 0x30
pascal@24476 130 bsBackupBootSectorNo DW ? ; 0x32
pascal@24476 131 bsreserved times 12 DB ? ; 0x34
pascal@24476 132 bsDriveNumber DB ? ; 0x40
pascal@24476 133 bsreserved1 DB ? ; 0x41
pascal@24476 134 bsExtendedBootSignature DB ? ; 0x42
pascal@24476 135 bsVolumeSerialNumber DD ? ; 0x43
pascal@24476 136 bsVolumeLabel DB "NO NAME " ; 0x47
pascal@24476 137 bsFileSystemName DB "FAT32 " ; 0x52
pascal@24476 138
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 140 ;; BPB2 ends here ;;
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 142
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 144 ;; Boot sector code starts here ;;
pascal@24476 145 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 146
pascal@24476 147 start:
pascal@24476 148 cld
pascal@24476 149
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 151 ;; How much RAM is there? ;;
pascal@24476 152 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 153
pascal@24476 154 int 12h ; get conventional memory size (in KBs)
pascal@24478 155 shl ax, 6 ; and convert it to 16-byte paragraphs
pascal@24476 156
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 159 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 160
pascal@24478 161 sub ax, 512 / 16 ; reserve 512 bytes for the boot sector code
pascal@24478 162 mov es, ax ; es:0 -> top - 512
pascal@24478 163
pascal@24478 164 sub ax, 2048 / 16 ; reserve 2048 bytes for the stack
pascal@24478 165 mov ss, ax ; ss:0 -> top - 512 - 2048
pascal@24478 166 mov sp, 2048 ; 2048 bytes for the stack
pascal@24476 167
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169 ;; Copy ourselves to top of memory ;;
pascal@24476 170 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 171
pascal@24478 172 mov cx, 256
pascal@24476 173 mov si, 7C00h
pascal@24476 174 xor di, di
pascal@24476 175 mov ds, di
pascal@24478 176 rep movsw
pascal@24476 177
pascal@24476 178 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 179 ;; Jump to the copy ;;
pascal@24476 180 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 181
pascal@24476 182 push es
pascal@24478 183 push byte main
pascal@24476 184 retf
pascal@24476 185
pascal@24476 186 main:
pascal@24476 187 push cs
pascal@24476 188 pop ds
pascal@24476 189
pascal@24478 190 mov [bsDriveNumber], dl ; store BIOS boot drive number
pascal@24476 191
pascal@24478 192 and byte [bsRootDirectoryClusterNo+3], 0Fh ; mask cluster value
pascal@24478 193 mov esi, [bsRootDirectoryClusterNo] ; esi=cluster # of root dir
pascal@24476 194
pascal@24476 195 RootDirReadContinue:
pascal@24478 196 push byte ImageLoadSeg
pascal@24478 197 pop es
pascal@24478 198 xor bx, bx
pascal@24478 199 push es
pascal@24478 200 call ReadCluster ; read one cluster of root dir
pascal@24478 201 pop es
pascal@24478 202 pushad ; save esi=next cluster # of root dir
pascal@24478 203 ; save eax=next sector # of root dir
pascal@24478 204 pushf ; save carry="not last cluster" flag
pascal@24476 205
pascal@24476 206 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 207 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 208 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 209
pascal@24476 210 xor di, di ; es:di -> root entries array
pascal@24478 211 mov si, ProgramName ; ds:si -> program name
pascal@24476 212
pascal@24476 213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 214 ;; Looks for a file/dir by its name ;;
pascal@24476 215 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 216 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 217 ;; ES:DI -> root directory array ;;
pascal@24478 218 ;; DX = number of root entries ;;
pascal@24476 219 ;; Output: ESI = cluster number ;;
pascal@24476 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 221
pascal@24478 222 FindName:
pascal@24478 223 mov cx, 11
pascal@24476 224 FindNameCycle:
pascal@24478 225 cmp byte [es:di], ch
pascal@24478 226 je ErrFind ; end of root directory (NULL entry found)
pascal@24478 227 FindNameNotEnd:
pascal@24478 228 pusha
pascal@24476 229 repe cmpsb
pascal@24478 230 popa
pascal@24476 231 je FindNameFound
pascal@24478 232 add di, 32
pascal@24476 233 dec bp
pascal@24476 234 dec bp
pascal@24476 235 jnz FindNameCycle ; next root entry
pascal@24478 236 popf ; restore carry="not last cluster" flag
pascal@24478 237 ; restore eax=next sector # of root dir
pascal@24478 238 popad ; restore esi=next cluster # of root dir
pascal@24476 239 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 240 ErrFind:
pascal@24478 241 call Error ; end of root directory (dir end reached)
pascal@24476 242 db "File not found."
pascal@24476 243 FindNameFound:
pascal@24478 244 push word [es:di+14h]
pascal@24478 245 push word [es:di+1Ah]
pascal@24478 246 pop esi ; esi = cluster no. cx = 0
pascal@24476 247
pascal@24476 248 dec dword [es:di+1Ch] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24478 249 imul di, [es:di+1Ch+1], 16 ; file size in paragraphs (full pages)
pascal@24478 250 xor cx, cx
pascal@24476 251
pascal@24476 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 253 ;; Load the entire file ;;
pascal@24476 254 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 255
pascal@24476 256 push es
pascal@24476 257 FileReadContinue:
pascal@24476 258 push di
pascal@24478 259 call ReadCluster ; read one cluster of root dir
pascal@24476 260 mov di, es
pascal@24478 261 add di, bp
pascal@24478 262 mov es, di ; es:bx updated
pascal@24476 263 pop di
pascal@24478 264
pascal@24476 265 sub di, bp
pascal@24476 266 jae FileReadContinue
pascal@24476 267 pop bp
pascal@24476 268
pascal@24476 269 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 270 ;; Type detection, .COM or .EXE? ;;
pascal@24476 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 272
pascal@24476 273 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 274 add bp, [bx+08h] ; bp = image base
pascal@24476 275 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 276 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 277
pascal@24476 278 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24478 279
pascal@24476 280 je RelocateEXE ; yes, it's an EXE program
pascal@24476 281
pascal@24476 282 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 283 ;; Setup and run a .COM program ;;
pascal@24478 284 ;; Set CS=DS=ES=SP SP=0 IP=100h ;;
pascal@24476 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 286
pascal@24476 287 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 288 mov ss, bp
pascal@24476 289 xor sp, sp
pascal@24476 290 push bp ; cs, ds and es
pascal@24476 291 mov bh, 1 ; ip
pascal@24476 292 jmp short Run
pascal@24476 293
pascal@24476 294 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 295 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 296 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 297 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24476 298 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 299
pascal@24476 300 ReloCycle:
pascal@24476 301 add [di+2], bp ; item seg (abs)
pascal@24476 302 les si, [di] ; si = item ofs, es = item seg
pascal@24476 303 add [es:si], bp ; fixup
pascal@24478 304 add di, 4 ; point to next entry
pascal@24476 305
pascal@24476 306 RelocateEXE:
pascal@24476 307 dec ax ; 32768 max (128KB table)
pascal@24476 308 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 309 ; PSP don't have a valid drive identifier
pascal@24476 310 les si, [bx+0Eh]
pascal@24476 311 add si, bp
pascal@24476 312 mov ss, si ; ss for EXE
pascal@24476 313 mov sp, es ; sp for EXE
pascal@24476 314
pascal@24476 315 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 316 push si ; containing the PSP structure
pascal@24476 317
pascal@24476 318 add bp, [bx+16h] ; cs for EXE
pascal@24476 319 mov bx, [bx+14h] ; ip for EXE
pascal@24476 320 Run:
pascal@24476 321 pop ds
pascal@24476 322 push bp
pascal@24476 323 push bx
pascal@24476 324 push ds
pascal@24476 325 pop es
pascal@24476 326
pascal@24476 327 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 328 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 329 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 mov si, 16381 ; prime number 2**14-3
pascal@24476 332 mov di, 32749 ; prime number 2**15-19
pascal@24476 333 mov bp, 65521 ; prime number 2**16-15
pascal@24476 334
pascal@24476 335 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 336 ;; All done, transfer control to the program now ;;
pascal@24476 337 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 338 retf
pascal@24476 339
pascal@24478 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 341 ;; Reads a FAT32 cluster ;;
pascal@24478 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 343 ;; Inout: ES:BX -> buffer ;;
pascal@24478 344 ;; ESI = cluster no ;;
pascal@24478 345 ;; Output: ESI = next cluster ;;
pascal@24478 346 ;; ES:BX -> next addr ;;
pascal@24478 347 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 348
pascal@24476 349 ReadCluster:
pascal@24476 350 inc cx
pascal@24478 351 loop ReadSectorLBA
pascal@24476 352
pascal@24478 353 mov ax, [bpbBytesPerSector]
pascal@24478 354 push ax
pascal@24478 355 shr ax, 2 ; ax=# of FAT32 entries per sector
pascal@24478 356 cwde
pascal@24478 357 lea ebp, [esi-2] ; esi=cluster #
pascal@24476 358 xchg eax, esi
pascal@24476 359 cdq
pascal@24478 360 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 361
pascal@24478 362 imul si, dx, 4 ; si=entry # in sector
pascal@24478 363 call ReadSectorLBAabsolute ; read 1 FAT32 sector
pascal@24476 364
pascal@24478 365 and byte [es:si+3], 0Fh ; mask cluster value
pascal@24478 366 mov esi, [es:si] ; esi=next cluster #
pascal@24476 367
pascal@24478 368 xchg eax, ebp
pascal@24478 369 movzx ecx, byte [bpbSectorsPerCluster]
pascal@24478 370 mul ecx
pascal@24478 371 xchg eax, ebp
pascal@24476 372
pascal@24478 373 movzx eax, byte [bpbNumberOfFATs]
pascal@24478 374 mul dword [bsSectorsPerFAT32]
pascal@24476 375
pascal@24478 376 add eax, ebp
pascal@24476 377
pascal@24478 378 pop bp ; [bpbBytesPerSector]
pascal@24478 379 shr bp, 4 ; bp = paragraphs per sector
pascal@24476 380
pascal@24478 381 ReadSectorLBAabsolute:
pascal@24478 382 movzx edx, word [bpbReservedSectors]
pascal@24478 383 add eax, edx
pascal@24478 384 add eax, [bpbHiddenSectors]
pascal@24476 385
pascal@24478 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 387 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 389 ;; Input: EAX = LBA ;;
pascal@24478 390 ;; CX = sector count ;;
pascal@24478 391 ;; ES:BX -> buffer address ;;
pascal@24478 392 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 393 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 394
pascal@24476 395 ReadSectorLBA:
pascal@24478 396 mov dl, [bsDriveNumber] ; restore BIOS boot drive number
pascal@24476 397 pusha
pascal@24476 398
pascal@24478 399 push bx
pascal@24478 400 push bx ; 32-bit LBA only: up to 2TB disks
pascal@24478 401 push eax
pascal@24476 402 push es
pascal@24476 403 push bx
pascal@24478 404 push byte 1 ; sector count word = 1
pascal@24478 405 mov cx, 16 ; retry count
pascal@24478 406 push cx ; packet size byte = 16, reserved byte = 0
pascal@24476 407
pascal@24478 408 ReadSectorRetry:
pascal@24478 409 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 410 mov si, sp
pascal@24478 411 push ss
pascal@24478 412 pop ds
pascal@24478 413 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 414 push cs
pascal@24478 415 pop ds
pascal@24478 416 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 417
pascal@24478 418 xor ax, ax ; ah = 0 = reset function
pascal@24476 419 int 13h ; reset drive (DL)
pascal@24476 420
pascal@24478 421 loop ReadSectorRetry ; extra attempt
pascal@24476 422 call Error
pascal@24476 423 db "Read error."
pascal@24476 424
pascal@24478 425 ReadSuccess:
pascal@24476 426
pascal@24476 427 popa ; sp += 16
pascal@24478 428
pascal@24478 429 popa
pascal@24478 430
pascal@24478 431 inc eax ; adjust LBA for next sector
pascal@24478 432
pascal@24476 433 stc
pascal@24478 434 loop ReadSectorNext
pascal@24476 435
pascal@24478 436 cmp esi, 0FFFFFF8h ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 437
pascal@24478 438 ReadSectorNext:
pascal@24476 439 ret
pascal@24476 440
pascal@24476 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 442 ;; Error Messaging Code ;;
pascal@24476 443 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 444
pascal@24476 445 Error:
pascal@24476 446 pop si
pascal@24478 447 puts:
pascal@24476 448 mov ah, 0Eh
pascal@24476 449 mov bl, 7
pascal@24476 450 lodsb
pascal@24476 451 int 10h
pascal@24478 452 cmp al, '.'
pascal@24478 453 jne puts
pascal@24476 454 cbw
pascal@24476 455 int 16h ; wait for a key...
pascal@24476 456 int 19h ; bootstrap
pascal@24476 457
pascal@24476 458 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 459 ;; Fill free space with zeroes ;;
pascal@24476 460 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 461
pascal@24476 462 times (512-13-($-$$)) db 0
pascal@24476 463
pascal@24476 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 465 ;; Name of the file to load and run ;;
pascal@24476 466 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 467
pascal@24476 468 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 469 ; padded with spaces (11 bytes total)
pascal@24476 470
pascal@24476 471 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 472 ;; End of the sector ID ;;
pascal@24476 473 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 474
pascal@24476 475 dw 0AA55h ; BIOS checks for this ID