wok annotate BootProg/stuff/bootex.asm @ rev 25037

Up glza (0.11.4)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Sat May 21 21:38:29 2022 +0000 (2022-05-21)
parents 584e67527789
children 65784e875d45
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@24476 51 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@24476 53 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24476 54 ;; | 1.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 61 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24945 62 ;; bx = cx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 63 ;; cs:ip = program entry point ;;
pascal@24476 64 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 65 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 66 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24945 75 ;; The command line contains no arguments. ;;
pascal@24476 76 ;; ;;
pascal@24476 77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 78
pascal@24476 79 %define bx(label) bx+label-boot
pascal@24476 80
pascal@24476 81 [BITS 16]
pascal@24476 82 [CPU 386]
pascal@24476 83
pascal@24476 84 ImageLoadSeg equ 60h
pascal@24476 85 StackSize equ 1536
pascal@24476 86
pascal@24476 87 [SECTION .text]
pascal@24476 88 [ORG 0]
pascal@24476 89
pascal@24476 90 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 91 ;; Boot sector starts here ;;
pascal@24476 92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 93
pascal@24476 94 boot:
pascal@24476 95 jmp short start ; Windows checks for this jump
pascal@24476 96 nop
pascal@24476 97 bsOemName DB "EXFAT " ; 0x03
pascal@24476 98 times 53 db 0 ; 0x0B
pascal@24476 99
pascal@24476 100 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 101 ;; BPB starts here ;;
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103
pascal@24479 104 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 105 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 106 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 107 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 108 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 109 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 110 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 111 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 112 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 113 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 114 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 115 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 116 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 117 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 118 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 119 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 120
pascal@24476 121 ;;;;;;;;;;;;;;;;;;;
pascal@24476 122 ;; BPB ends here ;;
pascal@24476 123 ;;;;;;;;;;;;;;;;;;;
pascal@24476 124
pascal@24476 125 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 126 ;; Boot sector code starts here ;;
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 128
pascal@24476 129 start:
pascal@24476 130 cld
pascal@24476 131
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133 ;; How much RAM is there? ;;
pascal@24476 134 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 135
pascal@24476 136 int 12h ; get conventional memory size (in KBs)
pascal@24476 137 mov cx, 106h
pascal@24476 138 dec ax
pascal@24476 139 dec ax ; reserve 2K bytes for the code and the stack
pascal@24476 140 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 141
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 143 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 144 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 145
pascal@24476 146 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 147 mov ss, ax
pascal@24476 148 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 149
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 151 ;; Copy ourselves to top of memory ;;
pascal@24476 152 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 153
pascal@24476 154 mov si, 7C00h
pascal@24476 155 xor di, di
pascal@24476 156 mov ds, di
pascal@24476 157 rep movsw ; move 512 bytes (+ 12)
pascal@24476 158
pascal@24476 159 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 160 ;; Jump to the copy ;;
pascal@24476 161 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 162
pascal@24476 163 push es
pascal@24942 164 push word main
pascal@24476 165 retf
pascal@24476 166
pascal@24476 167 main:
pascal@24476 168 push cs
pascal@24476 169 pop ds
pascal@24476 170
pascal@24476 171 xor ebx, ebx
pascal@24954 172 mov [bx], dl ; store BIOS boot drive number
pascal@24476 173
pascal@24476 174 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 175
pascal@24479 176 push byte ImageLoadSeg
pascal@24942 177 pop es ; cx = 0
pascal@24476 178
pascal@24476 179 RootDirReadContinue:
pascal@24476 180 call ReadCluster ; read one sector of root dir
pascal@24476 181 pushf ; save carry="not last sector" flag
pascal@24476 182
pascal@24476 183 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 184 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 185 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 186
pascal@24476 187 xor di, di ; es:di -> root entries array
pascal@24476 188
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190 ;; Looks for the file/dir ProgramName ;;
pascal@24476 191 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 192 ;; Input: ES:DI -> root directory array ;;
pascal@24476 193 ;; Output: ESI = cluster number ;;
pascal@24476 194 ;; dword [bx+FileSize] file size ;;
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196
pascal@24476 197 CurNameSize equ 3
pascal@24476 198 StartCluster equ 14h
pascal@24476 199 FileSize equ 18h
pascal@24476 200
pascal@24476 201 FindNameCycle:
pascal@24476 202 pusha
pascal@24476 203
pascal@24476 204 xor ax, ax
pascal@24476 205 or al, [es:di]
pascal@24476 206 je FindNameFailed
pascal@24476 207
pascal@24476 208 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 209 jne NotFileInfo
pascal@24476 210
pascal@24942 211 mov bl, 31
pascal@24476 212 CopyInfo:
pascal@24942 213 mov al, [es:di+bx]
pascal@24942 214 mov [bx], al
pascal@24476 215 dec bx
pascal@24954 216 jnz CopyInfo ; keep BIOS boot drive number
pascal@24476 217
pascal@24476 218 NotFileInfo:
pascal@24476 219 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 220 mov cx, NameLength+1
pascal@24476 221 mov si, ProgramName ; ds:si -> program name
pascal@24476 222 CheckName:
pascal@24476 223 scasw ; compare UTF-16
pascal@24476 224 lodsb ; with ASCII
pascal@24476 225 loope CheckName
pascal@24476 226 je FindNameFound ; cx = 0
pascal@24476 227 popa ; restore ax, cx, si, di
pascal@24476 228
pascal@24479 229 add di, byte 32
pascal@24945 230 cmp di, bp
pascal@24945 231 jne FindNameCycle ; next root entry
pascal@24476 232 popf ; restore carry="not last sector" flag
pascal@24476 233 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 234 FindNameFailed: ; end of root directory (dir end reached)
pascal@24954 235 mov dl, [bx] ; restore BIOS boot drive number
pascal@24476 236 call Error
pascal@24476 237 db "File not found."
pascal@24476 238 FindNameFound:
pascal@24476 239 mov esi, [bx+StartCluster]
pascal@24476 240
pascal@24476 241 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 242 ;; Load the entire file ;;
pascal@24476 243 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 244
pascal@24476 245 push es
pascal@24945 246 xor bp, bp
pascal@24476 247 FileReadContinue:
pascal@24476 248 shr bp, 4 ; bytes to paragraphs
pascal@24476 249 mov di, es
pascal@24476 250 add di, bp ; adjust segment for next sector
pascal@24476 251 mov es, di ; es:0 updated
pascal@24943 252 call ReadCluster ; read one more sector of the boot file
pascal@24476 253 sub [bx+FileSize], ebp
pascal@24476 254 ja FileReadContinue
pascal@24954 255 mov dl, [bx] ; restore BIOS boot drive number
pascal@24943 256 xor ax, ax
pascal@24476 257 pop bp
pascal@24476 258
pascal@24476 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 260 ;; Type detection, .COM or .EXE? ;;
pascal@24476 261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 262
pascal@24476 263 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 264
pascal@24476 265 add bp, [bx+08h] ; bp = image base
pascal@24476 266 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 267
pascal@24476 268 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 269 je RelocateEXE ; yes, it's an EXE program
pascal@24476 270
pascal@24476 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 272 ;; Setup and run a .COM program ;;
pascal@24476 273 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24525 274 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24942 275 ;; and cmdline=void ;;
pascal@24476 276 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 277
pascal@24525 278 mov di, 100h ; ip
pascal@24476 279 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 280 mov ss, bp
pascal@24476 281 xor sp, sp
pascal@24476 282 push bp ; cs, ds and es
pascal@24476 283 jmp short Run
pascal@24476 284
pascal@24476 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 286 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 287 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 288 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24942 289 ;; AX=0ffffh BX=0 CX=0 DX=drive cmdline=void ;;
pascal@24476 290 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 291
pascal@24476 292 ReloCycle:
pascal@24476 293 add [di+2], bp ; item seg (abs)
pascal@24476 294 les si, [di] ; si = item ofs, es = item seg
pascal@24476 295 add [es:si], bp ; fixup
pascal@24476 296 scasw ; di += 2
pascal@24476 297 scasw ; point to next entry
pascal@24476 298
pascal@24476 299 RelocateEXE:
pascal@24942 300 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 301 jns ReloCycle
pascal@24942 302
pascal@24945 303 les si, [bx+0Eh]
pascal@24945 304 add si, bp
pascal@24945 305 mov ss, si ; ss for EXE
pascal@24945 306 mov sp, es ; sp for EXE
pascal@24476 307
pascal@24476 308 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 309 push si ; containing the PSP structure
pascal@24476 310
pascal@24476 311 add bp, [bx+16h] ; cs for EXE
pascal@24525 312 mov di, [bx+14h] ; ip for EXE
pascal@24476 313 Run:
pascal@24476 314 pop ds
pascal@24476 315 push bp
pascal@24525 316 push di
pascal@24476 317 push ds
pascal@24476 318 pop es
pascal@24942 319 mov [80h], ax ; clear cmdline
pascal@24942 320 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 321
pascal@24476 322 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 323 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 324 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 325 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 326 mov si, 16381 ; prime number 2**14-3
pascal@24476 327 mov di, 32749 ; prime number 2**15-19
pascal@24476 328 mov bp, 65521 ; prime number 2**16-15
pascal@24476 329
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 ;; All done, transfer control to the program now ;;
pascal@24476 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 333 retf
pascal@24476 334
pascal@24476 335 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 336 ;; Reads a exFAT cluster ;;
pascal@24476 337 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 338 ;; Input: EDX:EAX = LBA ;;
pascal@24476 339 ;; EBX = 0 ;;
pascal@24476 340 ;; CX = sector cnt ;;
pascal@24476 341 ;; ESI = cluster no ;;
pascal@24476 342 ;; ES:0 -> buffer adrs ;;
pascal@24476 343 ;; Output: EBX = 0 ;;
pascal@24476 344 ;; CX = next cnt ;;
pascal@24476 345 ;; EBP = bytes/sector;;
pascal@24476 346 ;; ES:0 -> next adrs ;;
pascal@24476 347 ;; C=0 for last sector ;;
pascal@24476 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 349
pascal@24476 350 ReadCluster:
pascal@24945 351 add eax, byte 1
pascal@24945 352
pascal@24476 353 inc cx ; jcxnz
pascal@24476 354 loop ReadSectorC
pascal@24476 355
pascal@24945 356 mul ebx ; edx:eax = 0
pascal@24476 357 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 358 dec cx
pascal@24945 359 stc
pascal@24945 360 rcl eax, cl ; eax=# of exFAT entries per sector
pascal@24476 361 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 362 xchg eax, esi
pascal@24476 363 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 364
pascal@24525 365 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 366
pascal@24476 367 cdq
pascal@24476 368 add eax, [bx(bpbFatSectorStart)] ; sector # relative to FAT32
pascal@24476 369 call ReadSectorC ; read 1 FAT32 sector
pascal@24476 370
pascal@24476 371 mov esi, [es:si] ; esi=next cluster #
pascal@24476 372
pascal@24954 373 inc dx
pascal@24476 374 mov cl, [bx(bpbSectorPerClusterBits)]
pascal@24954 375 shl edx, cl ; 10000h max (32MB cluster)
pascal@24954 376 mov ecx, edx
pascal@24476 377 xchg eax, edi ; get cluster #-2
pascal@24476 378 mul ecx
pascal@24476 379
pascal@24476 380 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 381 ReadSectorC:
pascal@24476 382 adc edx, ebx
pascal@24476 383
pascal@24476 384 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 385 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 387 ;; Input: EDX:EAX = LBA ;;
pascal@24476 388 ;; BX = 0 ;;
pascal@24476 389 ;; CX = sector count ;;
pascal@24476 390 ;; ES:0 -> buffer address ;;
pascal@24476 391 ;; Output: BX = 0 ;;
pascal@24476 392 ;; CX = next count ;;
pascal@24476 393 ;; EBP = bytes/sector ;;
pascal@24476 394 ;; ES:0 -> next address ;;
pascal@24476 395 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 396
pascal@24476 397 xor ebp, ebp
pascal@24476 398 inc bp
pascal@24476 399
pascal@24476 400 pushad
pascal@24476 401
pascal@24476 402 add eax, [bx(bpbSectorStart)]
pascal@24476 403 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 404
pascal@24476 405 push edx
pascal@24476 406 push eax
pascal@24476 407 push es
pascal@24476 408 push bx
pascal@24476 409 push bp ; sector count word = 1
pascal@24954 410 mov cx, 16
pascal@24954 411 push cx ; packet size byte = 16, reserved byte = 0
pascal@24476 412 ReadSectorRetry:
pascal@24476 413 mov si, sp
pascal@24476 414 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24954 415 mov dl, [bx] ; restore BIOS boot drive number
pascal@24476 416 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 417
pascal@24476 418 jnc ReadSuccess
pascal@24476 419
pascal@24476 420 xor ax, ax
pascal@24476 421 int 13h ; reset drive (DL)
pascal@24954 422 loop ReadSectorRetry ; up to 16 retries
pascal@24476 423
pascal@24476 424 call Error
pascal@24476 425 db "Read error."
pascal@24476 426
pascal@24476 427 ReadSuccess:
pascal@24476 428 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 429 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@24476 430 popa ; sp += 16
pascal@24476 431 popad ; real registers
pascal@24476 432
pascal@24476 433 stc
pascal@24476 434 loop ReadSectorNext
pascal@24476 435
pascal@24479 436 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 437 ReadSectorNext:
pascal@24476 438 ret
pascal@24476 439
pascal@24942 440 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 441 ;; Fill free space with zeroes ;;
pascal@24942 442 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 443
pascal@24942 444 times (512-13-20-($-$$)) db 0
pascal@24942 445
pascal@24476 446 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 447 ;; Error Messaging Code ;;
pascal@24476 448 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 449
pascal@24476 450 Error:
pascal@24476 451 pop si
pascal@24478 452
pascal@24478 453 PutStr:
pascal@24476 454 mov ah, 0Eh
pascal@24476 455 mov bl, 7
pascal@24476 456 lodsb
pascal@24476 457 int 10h
pascal@24476 458 cmp al, "."
pascal@24476 459 jne PutStr
pascal@24476 460
pascal@24476 461 cbw
pascal@24476 462 int 16h ; wait for a key...
pascal@24476 463 int 19h ; bootstrap
pascal@24476 464
pascal@24476 465 Stop:
pascal@24476 466 hlt
pascal@24476 467 jmp short Stop
pascal@24476 468
pascal@24476 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 470 ;; Name of the file to load and run ;;
pascal@24476 471 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 472
pascal@24476 473 ProgramName db "startup.bin" ; name and extension
pascal@24476 474 NameLength equ $-ProgramName
pascal@24476 475
pascal@24476 476 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 477 ;; End of the sector ID ;;
pascal@24476 478 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 479
pascal@24476 480 dw 0AA55h ; BIOS checks for this ID