wok annotate BootProg/stuff/boot16.asm @ rev 24476

Add some current_version
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri Feb 18 09:29:30 2022 +0000 (2022-02-18)
parents
children 04472f031354
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - FAT12 and FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@24476 29 ;; Known Limitations: ;;
pascal@24476 30 ;; ~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 31 ;; - Works only on the 1st MBR partition which must be a PRI DOS partition ;;
pascal@24476 32 ;; with FAT12 (File System ID: 1) and FAT16 (File System ID: 4, 6) ;;
pascal@24476 33 ;; ;;
pascal@24476 34 ;; ;;
pascal@24476 35 ;; Known Bugs: ;;
pascal@24476 36 ;; ~~~~~~~~~~~ ;;
pascal@24476 37 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 38 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 39 ;; - 360KB 5"25 ;;
pascal@24476 40 ;; - 1.2MB 5"25 ;;
pascal@24476 41 ;; - 1.44MB 3"5 ;;
pascal@24476 42 ;; on my HDD (FAT16). ;;
pascal@24476 43 ;; ;;
pascal@24476 44 ;; ;;
pascal@24476 45 ;; Memory Layout: ;;
pascal@24476 46 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 47 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 48 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 49 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 50 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 51 ;; ;;
pascal@24476 52 ;; physical address ;;
pascal@24476 53 ;; +------------------------+ 00000H ;;
pascal@24476 54 ;; | Interrupt Vector Table | ;;
pascal@24476 55 ;; +------------------------+ 00400H ;;
pascal@24476 56 ;; | BIOS Data Area | ;;
pascal@24476 57 ;; +------------------------+ 00500H ;;
pascal@24476 58 ;; | PrtScr Status / Unused | ;;
pascal@24476 59 ;; +------------------------+ 00600H ;;
pascal@24476 60 ;; | Loaded Image | ;;
pascal@24476 61 ;; +------------------------+ nnnnnH ;;
pascal@24476 62 ;; | Available Memory | ;;
pascal@24476 63 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 64 ;; | Boot Sector | ;;
pascal@24476 65 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 66 ;; | 3KB Boot Stack | ;;
pascal@24476 67 ;; +------------------------+ A0000H ;;
pascal@24476 68 ;; | Video RAM | ;;
pascal@24476 69 ;; ;;
pascal@24476 70 ;; ;;
pascal@24476 71 ;; Boot Image Startup (register values): ;;
pascal@24476 72 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 73 ;; dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 74 ;; cs:ip = program entry point ;;
pascal@24476 75 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 76 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 77 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 78 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 79 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 80 ;; Magic numbers: ;;
pascal@24476 81 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 82 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 83 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 84 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 85 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 86 ;; metal and MS-DOS programs. ;;
pascal@24476 87 ;; ;;
pascal@24476 88 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 89
pascal@24476 90 %define bx(label) bx+label-boot
pascal@24476 91
pascal@24476 92 [BITS 16]
pascal@24476 93 [CPU 8086]
pascal@24476 94
pascal@24476 95 ? equ 0
pascal@24476 96 ImageLoadSeg equ 60h
pascal@24476 97 StackSize equ 3072 ; Stack + cluster list
pascal@24476 98
pascal@24476 99 [SECTION .text]
pascal@24476 100 [ORG 0]
pascal@24476 101
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103 ;; Boot sector starts here ;;
pascal@24476 104 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 105
pascal@24476 106 boot:
pascal@24476 107 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 108 nop
pascal@24476 109 bsOemName DB "BootProg" ; 0x03
pascal@24476 110
pascal@24476 111 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 112 ;; BPB starts here ;;
pascal@24476 113 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 114
pascal@24476 115 bpbBytesPerSector DW ? ; 0x0B
pascal@24476 116 bpbSectorsPerCluster DB ? ; 0x0D
pascal@24476 117 bpbReservedSectors DW ? ; 0x0E
pascal@24476 118 bpbNumberOfFATs DB ? ; 0x10
pascal@24476 119 bpbRootEntries DW ? ; 0x11
pascal@24476 120 bpbTotalSectors DW ? ; 0x13
pascal@24476 121 bpbMedia DB ? ; 0x15
pascal@24476 122 bpbSectorsPerFAT DW ? ; 0x16
pascal@24476 123 bpbSectorsPerTrack DW ? ; 0x18
pascal@24476 124 bpbHeadsPerCylinder DW ? ; 0x1A
pascal@24476 125 bpbHiddenSectors DD ? ; 0x1C
pascal@24476 126 bpbTotalSectorsBig DD ? ; 0x20
pascal@24476 127
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;
pascal@24476 129 ;; BPB ends here ;;
pascal@24476 130 ;;;;;;;;;;;;;;;;;;;
pascal@24476 131
pascal@24476 132 bsDriveNumber DB ? ; 0x24
pascal@24476 133 bsUnused DB ? ; 0x25
pascal@24476 134 bsExtBootSignature DB ? ; 0x26
pascal@24476 135 bsSerialNumber DD ? ; 0x27
pascal@24476 136 bsVolumeLabel DB "NO NAME " ; 0x2B
pascal@24476 137 bsFileSystem DB "FAT12 " ; 0x36
pascal@24476 138
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 140 ;; Boot sector code starts here ;;
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 142
pascal@24476 143 start:
pascal@24476 144 cld
pascal@24476 145
pascal@24476 146 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 147 ;; How much RAM is there? ;;
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149
pascal@24476 150 int 12h ; get conventional memory size (in KBs)
pascal@24476 151 mov cx, 106h
pascal@24476 152 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 159 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 160 mov ss, ax
pascal@24476 161 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 162
pascal@24476 163 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 164 ;; Copy ourselves to top of memory ;;
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 166
pascal@24476 167 mov si, 7C00h
pascal@24476 168 xor di, di
pascal@24476 169 mov ds, di
pascal@24476 170 mov [si], dx ; store BIOS boot drive number
pascal@24476 171 rep movsw ; move 512 bytes (+ 12)
pascal@24476 172
pascal@24476 173 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 174 ;; Jump to the copy ;;
pascal@24476 175 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 176
pascal@24476 177 push es
pascal@24476 178 mov cl, byte main
pascal@24476 179 push cx
pascal@24476 180 retf
pascal@24476 181
pascal@24476 182 main:
pascal@24476 183 %if ImageLoadSeg != main-boot
pascal@24476 184 %if ImageLoadSeg >= 100h
pascal@24476 185 mov cx, ImageLoadSeg
pascal@24476 186 %else
pascal@24476 187 mov cl, ImageLoadSeg
pascal@24476 188 %endif
pascal@24476 189 %endif
pascal@24476 190 push cx
pascal@24476 191
pascal@24476 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 193 ;; Get drive parameters ;;
pascal@24476 194 ;; Update heads count ;;
pascal@24476 195 ;; for current BIOS ;;
pascal@24476 196 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 197
pascal@24476 198 mov ah, 8
pascal@24476 199 int 13h ; may destroy SI,BP, and DS registers
pascal@24476 200 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 201 push cs
pascal@24476 202 pop ds
pascal@24476 203 xor bx, bx
pascal@24476 204
pascal@24476 205 and cx, 3Fh
pascal@24476 206 cmp [bx(bpbSectorsPerTrack)], cx
pascal@24476 207 jne BadParams ; verify updated and validity
pascal@24476 208 mov al, dh
pascal@24476 209 inc ax
pascal@24476 210 mov [bpbHeadsPerCylinder], ax
pascal@24476 211 BadParams:
pascal@24476 212
pascal@24476 213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 214 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 215 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 216
pascal@24476 217 pop es ; ImageLoadSeg
pascal@24476 218 push es
pascal@24476 219
pascal@24476 220 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@24476 221 mov cx, word [bx(bpbSectorsPerFAT)]
pascal@24476 222
pascal@24476 223 call ReadCXSectors ; read fat and clear cx
pascal@24476 224
pascal@24476 225 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 226 ;; load the root directory in ;;
pascal@24476 227 ;; its entirety (16KB max) ;;
pascal@24476 228 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 229
pascal@24476 230 mov ax, 32
pascal@24476 231
pascal@24476 232 mul word [bx(bpbRootEntries)]
pascal@24476 233 div word [bx(bpbBytesPerSector)]
pascal@24476 234 xchg ax, cx ; cx = root directory size in sectors, clear ax
pascal@24476 235
pascal@24476 236 mov al, [bpbNumberOfFATs]
pascal@24476 237 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadCXSectors
pascal@24476 238
pascal@24476 239 push es
pascal@24476 240 call ReadCXSectors ; read root directory, clear cx and di
pascal@24476 241 pop es
pascal@24476 242
pascal@24476 243 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 244 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 246
pascal@24476 247 ; es:di -> root entries array
pascal@24476 248
pascal@24476 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 250 ;; Looks for the file/dir ProgramName ;;
pascal@24476 251 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 252 ;; Input: ES:DI -> root directory array ;;
pascal@24476 253 ;; Output: SI = cluster number ;;
pascal@24476 254 ;; AX = file sector count ;;
pascal@24476 255 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 256
pascal@24476 257 FindNameCycle:
pascal@24476 258 cmp byte [es:di], ch
pascal@24476 259 je FindNameFailed ; end of root directory (NULL entry found)
pascal@24476 260 push di
pascal@24476 261 mov cl, 11
pascal@24476 262 mov si, ProgramName ; ds:si -> program name
pascal@24476 263 repe cmpsb
pascal@24476 264 pop di
pascal@24476 265 je FindNameFound
pascal@24476 266 add di, 32
pascal@24476 267 dec word [bx(bpbRootEntries)]
pascal@24476 268 jnz FindNameCycle ; next root entry
pascal@24476 269
pascal@24476 270 FindNameFailed:
pascal@24476 271 call Error
pascal@24476 272 db "File not found."
pascal@24476 273
pascal@24476 274 FindNameFound:
pascal@24476 275 push si
pascal@24476 276 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 277 les ax, [es:di+1Ch] ; file size
pascal@24476 278 mov dx, es
pascal@24476 279 div word [bx(bpbBytesPerSector)]
pascal@24476 280 cmp bx, dx ; sector aligned ?
pascal@24476 281 adc ax, bx ; file last sector
pascal@24476 282 pop di ; di = ClusterList
pascal@24476 283
pascal@24476 284 pop es ; ImageLoadSeg
pascal@24476 285 push ax
pascal@24476 286
pascal@24476 287 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 288 ;; build cluster list ;;
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Input: ES:0 -> FAT ;;
pascal@24476 291 ;; SI = first cluster ;;
pascal@24476 292 ;; DI = cluster list :;
pascal@24476 293 ;; CH = 0 ;;
pascal@24476 294 ;; Output: SI = cluster list ;;
pascal@24476 295 ;; CH = 0 ;;
pascal@24476 296 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 297
pascal@24476 298 push di ; up to 2 * 635K / BytesPerCluster bytes
pascal@24476 299 mov cl, 12
pascal@24476 300 ClusterLoop:
pascal@24476 301 mov [di], si
pascal@24476 302
pascal@24476 303 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@24476 304 add si, si ; si = cluster * 2
pascal@24476 305 jnc First64
pascal@24476 306 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@24476 307 First64:
pascal@24476 308 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@24476 309 mov ds, ax
pascal@24476 310 jbe ReadClusterFat12
pascal@24476 311
pascal@24476 312 lodsw ; ax = next cluster
pascal@24476 313 cmp ax, 0FFF8h
pascal@24476 314 jmp ReadClusterDone
pascal@24476 315
pascal@24476 316 ReadClusterFat12:
pascal@24476 317 add si, [cs:di]
pascal@24476 318 shr si, 1 ; si = cluster * 3 / 2
pascal@24476 319
pascal@24476 320 lodsw ; ax = next cluster
pascal@24476 321 jnc ReadClusterEven
pascal@24476 322
pascal@24476 323 rol ax, cl
pascal@24476 324
pascal@24476 325 ReadClusterEven:
pascal@24476 326 and ax, 0FFFh ; mask cluster value
pascal@24476 327 cmp ax, 0FF8h
pascal@24476 328
pascal@24476 329 ReadClusterDone:
pascal@24476 330 push cs
pascal@24476 331 pop ds
pascal@24476 332 inc di
pascal@24476 333 inc di
pascal@24476 334 xchg ax, si
pascal@24476 335 jc ClusterLoop
pascal@24476 336 pop si
pascal@24476 337 pop di ; file size in sectors
pascal@24476 338
pascal@24476 339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 340 ;; Load the entire file ;;
pascal@24476 341 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 342 ;; Input: ES:0 -> buffer ;;
pascal@24476 343 ;; SI = cluster list ;;
pascal@24476 344 ;; DI = file sectors ;;
pascal@24476 345 ;; CH = 0 ;;
pascal@24476 346 ;; Output: BP:0 -> buffer ;;
pascal@24476 347 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 348
pascal@24476 349 push es
pascal@24476 350
pascal@24476 351 ReadClusters:
pascal@24476 352 lodsw
pascal@24476 353 dec ax
pascal@24476 354 dec ax
pascal@24476 355
pascal@24476 356 mov cl, [bx(bpbSectorsPerCluster)]
pascal@24476 357 mul cx ; cx = sector count (ch = 0)
pascal@24476 358
pascal@24476 359 add ax, bp ; LBA for cluster data
pascal@24476 360 adc dx, bx ; dx:ax = LBA
pascal@24476 361
pascal@24476 362 call ReadSector ; clear cx
pascal@24476 363
pascal@24476 364 jne ReadClusters
pascal@24476 365
pascal@24476 366 pop bp ; ImageLoadSeg
pascal@24476 367
pascal@24476 368 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 369 ;; Type detection, .COM or .EXE? ;;
pascal@24476 370 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 371
pascal@24476 372 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 373
pascal@24476 374 add bp, [bx+08h] ; bp = image base
pascal@24476 375 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 376 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 377
pascal@24476 378 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 379 je RelocateEXE ; yes, it's an EXE program
pascal@24476 380
pascal@24476 381 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 382 ;; Setup and run a .COM program ;;
pascal@24476 383 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24476 384 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 385
pascal@24476 386 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 387 mov ss, bp
pascal@24476 388 xor sp, sp
pascal@24476 389 push bp ; cs, ds and es
pascal@24476 390 mov bh, 1 ; ip
pascal@24476 391 jmp short Run
pascal@24476 392
pascal@24476 393 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 394 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 395 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 396 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24476 397 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 398
pascal@24476 399 ReloCycle:
pascal@24476 400 add [di+2], bp ; item seg (abs)
pascal@24476 401 les si, [di] ; si = item ofs, es = item seg
pascal@24476 402 add [es:si], bp ; fixup
pascal@24476 403 scasw ; di += 2
pascal@24476 404 scasw ; point to next entry
pascal@24476 405
pascal@24476 406 RelocateEXE:
pascal@24476 407 dec ax ; 32768 max (128KB table)
pascal@24476 408 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 409 ; PSP don't have a valid drive identifier
pascal@24476 410 les si, [bx+0Eh]
pascal@24476 411 add si, bp
pascal@24476 412 mov ss, si ; ss for EXE
pascal@24476 413 mov sp, es ; sp for EXE
pascal@24476 414
pascal@24476 415 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 416 push si ; containing the PSP structure
pascal@24476 417
pascal@24476 418 add bp, [bx+16h] ; cs for EXE
pascal@24476 419 mov bx, [bx+14h] ; ip for EXE
pascal@24476 420 Run:
pascal@24476 421 pop ds
pascal@24476 422 push bp
pascal@24476 423 push bx
pascal@24476 424 push ds
pascal@24476 425 pop es
pascal@24476 426
pascal@24476 427 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 428 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 429 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 430 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 431 mov si, 16381 ; prime number 2**14-3
pascal@24476 432 mov di, 32749 ; prime number 2**15-19
pascal@24476 433 mov bp, 65521 ; prime number 2**16-15
pascal@24476 434
pascal@24476 435 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 436 ;; All done, transfer control to the program now ;;
pascal@24476 437 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 438 retf
pascal@24476 439
pascal@24476 440 ReadCXSectors:
pascal@24476 441 mov bp, cx
pascal@24476 442 add bp, ax ; adjust LBA for cluster data
pascal@24476 443
pascal@24476 444 mov di, cx ; no file size limit
pascal@24476 445
pascal@24476 446 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 447 ;; Reads sectors using BIOS Int 13h ;;
pascal@24476 448 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 449 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 450 ;; BX = 0 ;;
pascal@24476 451 ;; CX = sector count ;;
pascal@24476 452 ;; DI = file sectors ;;
pascal@24476 453 ;; ES:BX -> buffer address ;;
pascal@24476 454 ;; Output: ES:BX -> next address ;;
pascal@24476 455 ;; BX = 0 ;;
pascal@24476 456 ;; CX or DI = 0 ;;
pascal@24476 457 ;; DL = drive number ;;
pascal@24476 458 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 459
pascal@24476 460 ReadSector:
pascal@24476 461 add ax, [bx(bpbHiddenSectors)]
pascal@24476 462 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 463 add ax, [bx(bpbReservedSectors)]
pascal@24476 464
pascal@24476 465 push si
pascal@24476 466 ReadSectorNext:
pascal@24476 467 adc dx, bx
pascal@24476 468 push di
pascal@24476 469 push cx
pascal@24476 470
pascal@24476 471 push bx
pascal@24476 472 push bx
pascal@24476 473 push dx ; 32-bit LBA: up to 2TB
pascal@24476 474 push ax
pascal@24476 475 push es
pascal@24476 476 push bx
pascal@24476 477 inc bx ; sector count word = 1
pascal@24476 478 push bx
pascal@24476 479 dec bx
pascal@24476 480 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 481 push di
pascal@24476 482
pascal@24476 483 xchg ax, cx ; save low LBA
pascal@24476 484 xchg ax, dx ; get high LBA
pascal@24476 485 cwd ; clear dx (LBA offset <2TB)
pascal@24476 486 div word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 487
pascal@24476 488 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@24476 489 div word [bx(bpbSectorsPerTrack)]
pascal@24476 490 ; ax = LBA / SPT
pascal@24476 491 ; dx = LBA % SPT = sector - 1
pascal@24476 492 inc dx
pascal@24476 493
pascal@24476 494 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@24476 495 div word [bx(bpbHeadsPerCylinder)]
pascal@24476 496 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 497 ; dx = (LBA / SPT) % HPC = head
pascal@24476 498 mov ch, al
pascal@24476 499 ; ch = LSB 0...7 of cylinder no.
pascal@24476 500 mov al, 64
pascal@24476 501 mul ah
pascal@24476 502 or cl, al
pascal@24476 503 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 504 mov dh, dl
pascal@24476 505 ; dh = head no.
pascal@24476 506
pascal@24476 507 ReadSectorRetry:
pascal@24476 508 mov dl, [bx]
pascal@24476 509 ; dl = drive no.
pascal@24476 510 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 511 mov si, sp
pascal@24476 512 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 513 jnc ReadSectorNextSegment
pascal@24476 514
pascal@24476 515 mov ax, 201h ; al = sector count = 1
pascal@24476 516 ; ah = 2 = read function no.
pascal@24476 517 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 518
pascal@24476 519 jnc ReadSectorNextSegment
pascal@24476 520 cbw ; ah = 0 = reset function
pascal@24476 521 int 13h ; reset drive (DL)
pascal@24476 522
pascal@24476 523 dec di
pascal@24476 524 jnz ReadSectorRetry ; extra attempt
pascal@24476 525
pascal@24476 526 call Error
pascal@24476 527 db "Read error."
pascal@24476 528
pascal@24476 529 ReadSectorNextSegment:
pascal@24476 530
pascal@24476 531 pop ax ; al = 16
pascal@24476 532 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@24476 533 pop cx ; sector count = 1
pascal@24476 534 pop bx
pascal@24476 535 add [si+6], ax ; adjust segment for next sector
pascal@24476 536 pop es ; es:0 updated
pascal@24476 537 pop ax
pascal@24476 538 pop dx
pascal@24476 539 pop di
pascal@24476 540 pop di
pascal@24476 541
pascal@24476 542 add ax, cx ; adjust LBA for next sector
pascal@24476 543
pascal@24476 544 pop cx ; cluster sectors to read
pascal@24476 545 pop di ; file sectors to read
pascal@24476 546 dec di ; keep C
pascal@24476 547 loopne ReadSectorNext ; until cluster sector count or file sector count is reached
pascal@24476 548 pop si
pascal@24476 549 mov dx, [bx] ; pass the BIOS boot drive to Run or Error
pascal@24476 550
pascal@24476 551 ret
pascal@24476 552
pascal@24476 553 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 554 ;; Error Messaging Code ;;
pascal@24476 555 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 556
pascal@24476 557 Error:
pascal@24476 558 pop si
pascal@24476 559 mov ah, 0Eh
pascal@24476 560 mov bl, 7
pascal@24476 561
pascal@24476 562 PutStr:
pascal@24476 563 lodsb
pascal@24476 564 int 10h
pascal@24476 565 cmp al, "."
pascal@24476 566 jne PutStr
pascal@24476 567
pascal@24476 568 cbw
pascal@24476 569 int 16h ; wait for a key...
pascal@24476 570 int 19h ; bootstrap
pascal@24476 571
pascal@24476 572 Stop:
pascal@24476 573 hlt
pascal@24476 574 jmp short Stop
pascal@24476 575
pascal@24476 576 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 577 ;; Fill free space with zeroes ;;
pascal@24476 578 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 579
pascal@24476 580 times (512-13-($-$$)) db 0
pascal@24476 581
pascal@24476 582 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 583 ;; Name of the file to load and run ;;
pascal@24476 584 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 585
pascal@24476 586 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 587 ; padded with spaces (11 bytes total)
pascal@24476 588
pascal@24476 589 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 590 ;; End of the sector ID ;;
pascal@24476 591 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 592
pascal@24476 593 ClusterList dw 0AA55h ; BIOS checks for this ID