wok annotate BootProg/stuff/bootex.asm @ rev 24845

updated libupnp and libupnp-dev (1.12.0 -> 1.14.12)
author Hans-G?nter Theisgen
date Fri Mar 25 14:27:13 2022 +0100 (2022-03-25)
parents d8c511e24c20
children d1f31f5f6401
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@24476 51 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@24476 53 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24476 54 ;; | 1.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 61 ;; dl = BIOS boot drive number (e.g. 80H) ;;
pascal@24476 62 ;; cs:ip = program entry point ;;
pascal@24476 63 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 64 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 65 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 66 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24476 75 ;; ;;
pascal@24476 76 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 77
pascal@24476 78 %define bx(label) bx+label-boot
pascal@24476 79
pascal@24476 80 [BITS 16]
pascal@24476 81 [CPU 386]
pascal@24476 82
pascal@24476 83 ImageLoadSeg equ 60h
pascal@24476 84 StackSize equ 1536
pascal@24476 85
pascal@24476 86 [SECTION .text]
pascal@24476 87 [ORG 0]
pascal@24476 88
pascal@24476 89 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 90 ;; Boot sector starts here ;;
pascal@24476 91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 92
pascal@24476 93 boot:
pascal@24476 94 jmp short start ; Windows checks for this jump
pascal@24476 95 nop
pascal@24476 96 bsOemName DB "EXFAT " ; 0x03
pascal@24476 97 times 53 db 0 ; 0x0B
pascal@24476 98
pascal@24476 99 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 100 ;; BPB starts here ;;
pascal@24476 101 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 102
pascal@24479 103 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 104 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 105 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 106 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 107 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 108 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 109 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 110 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 111 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 112 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 113 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 114 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 115 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 116 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 117 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 118 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 119
pascal@24476 120 ;;;;;;;;;;;;;;;;;;;
pascal@24476 121 ;; BPB ends here ;;
pascal@24476 122 ;;;;;;;;;;;;;;;;;;;
pascal@24476 123
pascal@24476 124 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 125 ;; Boot sector code starts here ;;
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 127
pascal@24476 128 start:
pascal@24476 129 cld
pascal@24476 130
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 132 ;; How much RAM is there? ;;
pascal@24476 133 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 134
pascal@24476 135 int 12h ; get conventional memory size (in KBs)
pascal@24476 136 mov cx, 106h
pascal@24476 137 dec ax
pascal@24476 138 dec ax ; reserve 2K bytes for the code and the stack
pascal@24476 139 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 140
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 142 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 144
pascal@24476 145 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 146 mov ss, ax
pascal@24476 147 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 148
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150 ;; Copy ourselves to top of memory ;;
pascal@24476 151 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 152
pascal@24476 153 mov si, 7C00h
pascal@24476 154 xor di, di
pascal@24476 155 mov ds, di
pascal@24476 156 rep movsw ; move 512 bytes (+ 12)
pascal@24476 157
pascal@24476 158 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 159 ;; Jump to the copy ;;
pascal@24476 160 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 161
pascal@24476 162 push es
pascal@24479 163 push byte main
pascal@24476 164 retf
pascal@24476 165
pascal@24476 166 main:
pascal@24476 167 push cs
pascal@24476 168 pop ds
pascal@24476 169
pascal@24476 170 xor ebx, ebx
pascal@24476 171 mov [bx], dx ; store BIOS boot drive number
pascal@24476 172
pascal@24476 173 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 174
pascal@24479 175 push byte ImageLoadSeg
pascal@24476 176 pop es
pascal@24476 177
pascal@24476 178 RootDirReadContinue:
pascal@24476 179 call ReadCluster ; read one sector of root dir
pascal@24476 180 pushf ; save carry="not last sector" flag
pascal@24476 181
pascal@24476 182 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 183 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 184 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 185
pascal@24476 186 xor di, di ; es:di -> root entries array
pascal@24476 187
pascal@24476 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 189 ;; Looks for the file/dir ProgramName ;;
pascal@24476 190 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 191 ;; Input: ES:DI -> root directory array ;;
pascal@24476 192 ;; Output: ESI = cluster number ;;
pascal@24476 193 ;; dword [bx+FileSize] file size ;;
pascal@24476 194 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 195
pascal@24476 196 CurNameSize equ 3
pascal@24476 197 StartCluster equ 14h
pascal@24476 198 FileSize equ 18h
pascal@24476 199
pascal@24476 200 FindNameCycle:
pascal@24476 201 pusha
pascal@24476 202
pascal@24476 203 xor ax, ax
pascal@24476 204 or al, [es:di]
pascal@24476 205 je FindNameFailed
pascal@24476 206
pascal@24476 207 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 208 jne NotFileInfo
pascal@24476 209
pascal@24476 210 mov bl, 30
pascal@24476 211 CopyInfo:
pascal@24476 212 mov ax, [es:di+bx]
pascal@24476 213 mov [bx], ax
pascal@24476 214 dec bx
pascal@24476 215 dec bx
pascal@24476 216 jnz CopyInfo
pascal@24476 217
pascal@24476 218 NotFileInfo:
pascal@24476 219 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 220 mov cx, NameLength+1
pascal@24476 221 mov si, ProgramName ; ds:si -> program name
pascal@24476 222 CheckName:
pascal@24476 223 scasw ; compare UTF-16
pascal@24476 224 lodsb ; with ASCII
pascal@24476 225 loope CheckName
pascal@24476 226 je FindNameFound ; cx = 0
pascal@24476 227 popa ; restore ax, cx, si, di
pascal@24476 228
pascal@24479 229 add di, byte 32
pascal@24476 230 cmp di, bp
pascal@24476 231 jne FindNameCycle ; next root entry
pascal@24476 232 popf ; restore carry="not last sector" flag
pascal@24476 233 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 234 FindNameFailed: ; end of root directory (dir end reached)
pascal@24476 235 call Error
pascal@24476 236 db "File not found."
pascal@24476 237 FindNameFound:
pascal@24476 238 mov esi, [bx+StartCluster]
pascal@24476 239
pascal@24476 240 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 241 ;; Load the entire file ;;
pascal@24476 242 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 243
pascal@24476 244 push es
pascal@24476 245 xor bp, bp
pascal@24476 246 FileReadContinue:
pascal@24476 247 shr bp, 4 ; bytes to paragraphs
pascal@24476 248 mov di, es
pascal@24476 249 add di, bp ; adjust segment for next sector
pascal@24476 250 mov es, di ; es:0 updated
pascal@24476 251 call ReadCluster ; read one cluster of root dir
pascal@24476 252 sub [bx+FileSize], ebp
pascal@24476 253 ja FileReadContinue
pascal@24476 254 pop bp
pascal@24476 255
pascal@24476 256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 257 ;; Type detection, .COM or .EXE? ;;
pascal@24476 258 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 259
pascal@24476 260 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 261
pascal@24476 262 add bp, [bx+08h] ; bp = image base
pascal@24476 263 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 264 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 265
pascal@24476 266 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 267 je RelocateEXE ; yes, it's an EXE program
pascal@24476 268
pascal@24476 269 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 270 ;; Setup and run a .COM program ;;
pascal@24476 271 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24525 272 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24476 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 274
pascal@24525 275 mov ax, 0ffffh ; both FCB in the PSP don't have a valid drive identifier
pascal@24525 276 mov di, 100h ; ip
pascal@24476 277 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 278 mov ss, bp
pascal@24476 279 xor sp, sp
pascal@24476 280 push bp ; cs, ds and es
pascal@24476 281 jmp short Run
pascal@24476 282
pascal@24476 283 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 284 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 285 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 286 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24525 287 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24476 288 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 289
pascal@24476 290 ReloCycle:
pascal@24476 291 add [di+2], bp ; item seg (abs)
pascal@24476 292 les si, [di] ; si = item ofs, es = item seg
pascal@24476 293 add [es:si], bp ; fixup
pascal@24476 294 scasw ; di += 2
pascal@24476 295 scasw ; point to next entry
pascal@24476 296
pascal@24476 297 RelocateEXE:
pascal@24476 298 dec ax ; 32768 max (128KB table)
pascal@24476 299 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 300 ; PSP don't have a valid drive identifier
pascal@24476 301 les si, [bx+0Eh]
pascal@24476 302 add si, bp
pascal@24476 303 mov ss, si ; ss for EXE
pascal@24476 304 mov sp, es ; sp for EXE
pascal@24476 305
pascal@24476 306 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 307 push si ; containing the PSP structure
pascal@24476 308
pascal@24476 309 add bp, [bx+16h] ; cs for EXE
pascal@24525 310 mov di, [bx+14h] ; ip for EXE
pascal@24476 311 Run:
pascal@24476 312 pop ds
pascal@24476 313 push bp
pascal@24525 314 push di
pascal@24476 315 push ds
pascal@24476 316 pop es
pascal@24476 317
pascal@24476 318 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 319 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 320 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 321 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 322 mov si, 16381 ; prime number 2**14-3
pascal@24476 323 mov di, 32749 ; prime number 2**15-19
pascal@24476 324 mov bp, 65521 ; prime number 2**16-15
pascal@24476 325
pascal@24476 326 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 327 ;; All done, transfer control to the program now ;;
pascal@24476 328 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 329 retf
pascal@24476 330
pascal@24476 331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 332 ;; Reads a exFAT cluster ;;
pascal@24476 333 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 334 ;; Input: EDX:EAX = LBA ;;
pascal@24476 335 ;; EBX = 0 ;;
pascal@24476 336 ;; CX = sector cnt ;;
pascal@24476 337 ;; ESI = cluster no ;;
pascal@24476 338 ;; ES:0 -> buffer adrs ;;
pascal@24476 339 ;; Output: EBX = 0 ;;
pascal@24476 340 ;; CX = next cnt ;;
pascal@24476 341 ;; EBP = bytes/sector;;
pascal@24476 342 ;; ES:0 -> next adrs ;;
pascal@24476 343 ;; C=0 for last sector ;;
pascal@24476 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 345
pascal@24476 346 ReadCluster:
pascal@24476 347 inc cx ; jcxnz
pascal@24479 348 add eax, byte 1
pascal@24476 349 loop ReadSectorC
pascal@24476 350
pascal@24476 351 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 352 dec cx
pascal@24476 353 dec cx
pascal@24476 354 mul ebx ; edx:eax = 0
pascal@24476 355 inc ax
pascal@24476 356 shl eax, cl ; eax=# of exFAT entries per sector
pascal@24476 357 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 358 xchg eax, esi
pascal@24476 359 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 360
pascal@24525 361 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 362
pascal@24476 363 cdq
pascal@24476 364 add eax, [bx(bpbFatSectorStart)] ; sector # relative to FAT32
pascal@24476 365 call ReadSectorC ; read 1 FAT32 sector
pascal@24476 366
pascal@24476 367 mov esi, [es:si] ; esi=next cluster #
pascal@24476 368
pascal@24476 369 xor eax, eax
pascal@24476 370 inc ax
pascal@24476 371 mov cl, [bx(bpbSectorPerClusterBits)]
pascal@24476 372 shl eax, cl ; 10000h max (32MB cluster)
pascal@24476 373 xchg eax, ecx
pascal@24476 374 xchg eax, edi ; get cluster #-2
pascal@24476 375 mul ecx
pascal@24476 376
pascal@24476 377 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 378 ReadSectorC:
pascal@24476 379 adc edx, ebx
pascal@24476 380
pascal@24476 381 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 382 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 383 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 384 ;; Input: EDX:EAX = LBA ;;
pascal@24476 385 ;; BX = 0 ;;
pascal@24476 386 ;; CX = sector count ;;
pascal@24476 387 ;; ES:0 -> buffer address ;;
pascal@24476 388 ;; Output: BX = 0 ;;
pascal@24476 389 ;; CX = next count ;;
pascal@24476 390 ;; EBP = bytes/sector ;;
pascal@24476 391 ;; ES:0 -> next address ;;
pascal@24476 392 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 393
pascal@24476 394 ReadSector:
pascal@24476 395
pascal@24476 396 xor ebp, ebp
pascal@24476 397 inc bp
pascal@24476 398
pascal@24476 399 pushad
pascal@24476 400
pascal@24476 401 add eax, [bx(bpbSectorStart)]
pascal@24476 402 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 403
pascal@24476 404 push edx
pascal@24476 405 push eax
pascal@24476 406 push es
pascal@24476 407 push bx
pascal@24476 408 push bp ; sector count word = 1
pascal@24476 409 mov cx, 16
pascal@24476 410 push cx ; packet size byte = 16, reserved byte = 0
pascal@24476 411 ReadSectorRetry:
pascal@24476 412 mov si, sp
pascal@24476 413 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 414 mov dl, [bx]
pascal@24476 415 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 416
pascal@24476 417 jnc ReadSuccess
pascal@24476 418
pascal@24476 419 xor ax, ax
pascal@24476 420 int 13h ; reset drive (DL)
pascal@24476 421 loop ReadSectorRetry
pascal@24476 422
pascal@24476 423 call Error
pascal@24476 424 db "Read error."
pascal@24476 425
pascal@24476 426 ReadSuccess:
pascal@24476 427 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 428 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@24476 429 popa ; sp += 16
pascal@24476 430 popad ; real registers
pascal@24476 431
pascal@24476 432 stc
pascal@24476 433 loop ReadSectorNext
pascal@24476 434
pascal@24479 435 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 436 ReadSectorNext:
pascal@24491 437 mov dl, [bx] ; restore BIOS boot drive number
pascal@24476 438 ret
pascal@24476 439
pascal@24476 440 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 441 ;; Error Messaging Code ;;
pascal@24476 442 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 443
pascal@24476 444 Error:
pascal@24476 445 pop si
pascal@24478 446
pascal@24478 447 PutStr:
pascal@24476 448 mov ah, 0Eh
pascal@24476 449 mov bl, 7
pascal@24476 450 lodsb
pascal@24476 451 int 10h
pascal@24476 452 cmp al, "."
pascal@24476 453 jne PutStr
pascal@24476 454
pascal@24476 455 cbw
pascal@24476 456 int 16h ; wait for a key...
pascal@24476 457 int 19h ; bootstrap
pascal@24476 458
pascal@24476 459 Stop:
pascal@24476 460 hlt
pascal@24476 461 jmp short Stop
pascal@24476 462
pascal@24476 463 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 464 ;; Fill free space with zeroes ;;
pascal@24476 465 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 466
pascal@24476 467 times (512-13-($-$$)) db 0
pascal@24476 468
pascal@24476 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 470 ;; Name of the file to load and run ;;
pascal@24476 471 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 472
pascal@24476 473 ProgramName db "startup.bin" ; name and extension
pascal@24476 474 NameLength equ $-ProgramName
pascal@24476 475
pascal@24476 476 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 477 ;; End of the sector ID ;;
pascal@24476 478 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 479
pascal@24476 480 dw 0AA55h ; BIOS checks for this ID