wok annotate linld/stuff/src/VCPI.ASM @ rev 21777

linld: fix strdup (again)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Thu Jul 11 14:43:21 2019 +0200 (2019-07-11)
parents cbcb33ee9044
children 6e3d30b3031f
rev   line source
pascal@19538 1 ;***************************************************************
pascal@19538 2 ;****** This file is distributed under GPL
pascal@19538 3 ;***************************************************************
pascal@19538 4 ;VDPI init:
pascal@19538 5 ;Call char* prepare_vcpi(void *pagebuf) first to
pascal@19538 6 ;initialize paging tables needed for vm86.
pascal@19538 7 ;pagebuf needs to be 8k+4 bytes. Returns ptr to 1st unused byte.
pascal@19538 8 ;Then call int get_vcpi_interface(). Returns 1 if ok, 0 if bad.
pascal@19538 9 ;
pascal@19538 10 ;VCPI use:
pascal@19538 11 ;u32* malloc_vcpi(u32 size) - source in HIMEM.CPP
pascal@19538 12 ; Returns ptr to mallocated zero-terminated list of 4k page addrs
pascal@19538 13 ; Addresses are sorted in ascending order
pascal@19538 14 ; Never fails (will die if not enough mem)
pascal@19538 15 ;void read2vcpi(int fd, u32* vp, u32 size,
pascal@19538 16 ;void* xfer_buf, u16 xfer_size) - source in HIMEM.CPP
pascal@19538 17 ; Reads opened fd data into malloc_vcpi'ed memory
pascal@19538 18 ; Dies if file isn't exactly 'size' bytes long
pascal@19538 19 ; Needs intermediate buffer of exactly Nx4k bytes
pascal@19538 20 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs)
pascal@19538 21 ; copies 4k from conventional memory to VCPI
pascal@19538 22 ;void _vm2rm()
pascal@19538 23 ; switches you from vm86 to plain real mode
pascal@19538 24
pascal@19538 25
pascal@19538 26 ideal
pascal@19538 27 %crefref
pascal@19538 28 %noincl
pascal@19538 29 %nomacs
pascal@19538 30 p386
pascal@19538 31
pascal@19538 32 ;****** Stuff for declaring descriptors
pascal@19538 33 struc descr
pascal@19538 34 limit dw ?
pascal@19538 35 base0 dw ?
pascal@19538 36 base16 db ?
pascal@19538 37 type db ?
pascal@19538 38 limit16 db ?
pascal@19538 39 base24 db ?
pascal@19538 40 ends descr
pascal@19538 41 macro descriptor name,typ,plevel,present,limit,gran,base
pascal@19538 42 ;;name descr <limit and 0ffffh,base and 0ffffh,low (base shr 16),typ or plevel or present,(limit shr 16) or gran,high (base shr 16)>
pascal@19538 43 name descr <limit and 0ffffh,base ,0 ,typ or plevel or present,(limit shr 16) or gran,0 >
pascal@19538 44 endm
pascal@19538 45 ; decriptor types (bit0..4 of descr.type )
pascal@19538 46 tss386_avail = 09h
pascal@19538 47 data_seg = 00010000b ; data segment
pascal@19538 48 expand_down = 00000100b ; =1 limit counts down from base
pascal@19538 49 writable = 00000010b ; =1 if write access allowed to data segment
pascal@19538 50 code_seg = 00011000b ; code segment
pascal@19538 51 conforming = 00000100b ; =1 code can be accesses and executed at any PL
pascal@19538 52 readable = 00000010b ; =1 if code also can be read (cannot be ovwritten)
pascal@19538 53 ; privilege levels (bit5..6 of descr.type )
pascal@19538 54 priv0 = 00000000b
pascal@19538 55 priv1 = 00100000b
pascal@19538 56 priv2 = 01000000b
pascal@19538 57 priv3 = 01100000b
pascal@19538 58 ; segment present bit (bit7 of descr.type )
pascal@19538 59 is_present = 10000000b
pascal@19538 60 not_present = 00000000b
pascal@19538 61 ;definition of granularity ( bits6..7 in descr.limit16 )
pascal@19538 62 gran_byte = 00000000b
pascal@19538 63 gran_page = 10000000b ; 4k granularity
pascal@19538 64 use_16 = 00000000b
pascal@19538 65 use_32 = 01000000b
pascal@19538 66
pascal@19538 67 ;****** rm32,imm16 helpers
pascal@19538 68 macro addzx_e rm,i
pascal@19538 69 db 66h
pascal@19538 70 add rm,i
pascal@19538 71 dw 0
pascal@19538 72 endm
pascal@19538 73
pascal@19538 74
pascal@20534 75 group DGROUP _TEXT,_BSS
pascal@19538 76 assume cs:DGROUP,ds:DGROUP
pascal@19538 77
pascal@20534 78 segment _BSS byte public use16 'BSS'
pascal@20534 79
pascal@20534 80 tss dd ?,? ;enough, we'll never use it anyway
pascal@20534 81
pascal@20534 82 ends _BSS
pascal@20534 83
pascal@20534 84 segment _TEXT byte public use16 'CODE'
pascal@19538 85
pascal@19538 86 label gdt byte
pascal@19538 87 gdt_null descr <?> ;0000
pascal@19538 88 gdt_vcpi descr <?> ;0008
pascal@19538 89 gdt_vcpi2 descr <?> ;0010
pascal@19538 90 gdt_vcpi3 descr <?> ;0018
pascal@19538 91 descriptor gdt_abs ,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_32),0
pascal@19538 92 ;Note: code/data segs must be flagged use16 (i.e. use ip/sp, not eip/esp)
pascal@19538 93 ;Note: base addrs will be fixed up in prepare_vcpi()
pascal@19538 94 descriptor gdt_code,(code_seg+readable),priv0,is_present,0fffffh,(gran_page+use_16),0
pascal@20751 95 global gdt_data:descr
pascal@19538 96 descriptor gdt_data,(data_seg+writable),priv0,is_present,0fffffh,(gran_page+use_16),0
pascal@19538 97 descriptor gdt_tss ,tss386_avail ,priv0,is_present,0ffh ,gran_byte ,<offset tss>
pascal@19538 98 SEL_VCPI = (gdt_vcpi - gdt_null)
pascal@19538 99 SEL_TSS = (gdt_tss - gdt_null)
pascal@19538 100 SEL_ABS = (gdt_abs - gdt_null)
pascal@19538 101 SEL_CODE = (gdt_code - gdt_null)
pascal@19538 102 SEL_DATA = (gdt_data - gdt_null)
pascal@19538 103
pascal@19538 104 label gdtr pword
pascal@19538 105 gdt_lim dw 0ffffh
pascal@19538 106 gdt_base dw offset gdt,0
pascal@19538 107
pascal@19538 108 ;Note: layout dictated by vcpi api, don't rearrange!
pascal@19538 109 label sw2pm_params byte
pascal@19538 110 ;Note: base addrs will be fixed up in prepare_vcpi()
pascal@19634 111 label pagedir_laddr dword
pascal@19906 112 sw2pm_cr3 dd 1000h
pascal@19538 113 sw2pm_gdtr_ptr dw offset gdtr,0
pascal@19538 114 sw2pm_idtr_ptr dw offset idtr,0
pascal@19538 115 sw2pm_ldtr dw 0 ;we don't need it
pascal@19538 116 sw2pm_tr dw SEL_TSS ;vcpi thinks we need it... can't set to 0
pascal@19634 117 sw2pm_jumpaddr dd 0
pascal@19538 118 dw SEL_CODE
pascal@19538 119
pascal@19634 120 vcpi_pm_entry dd 0
pascal@19634 121 dw SEL_VCPI
pascal@19634 122
pascal@19634 123 label idtr pword
pascal@19634 124 idt_lim dw 03ffh ;we won't enable ints,
pascal@19634 125 idt_base dd 0 ; so let's leave it the same as for rm
pascal@19634 126
pascal@19538 127
pascal@19538 128 ;***************************************************************
pascal@19538 129 ;char* prepare_vcpi(void *pagebuf);
pascal@19538 130 ;****** Return: AX=>first unused byte in pagebuf
pascal@19538 131 ;****** Uses: Flags
pascal@19538 132 ;***************************************************************
pascal@19538 133 global prepare_vcpi:near
pascal@20486 134 proc prepare_vcpi near
pascal@19538 135
pascal@19538 136 ;pop ax
pascal@19538 137 ;pop bx ;pgbuf
pascal@19538 138 ;push bx
pascal@19538 139 ;push ax
pascal@19538 140
pascal@19538 141 ;Calculate pagedir/page0 addrs, initialize cr3 and pagedir[0]
pascal@19538 142 xor eax,eax
pascal@19538 143 ; heap_top = prepare_vcpi(malloc_or_die(8*1024+4));
pascal@21777 144 mov ah,8*1024/256
pascal@19538 145 extrn malloc_or_die:near
pascal@21777 146 call malloc_or_die
pascal@19538 147
pascal@19538 148 mov edx,cs
pascal@21777 149 shl edx,4 ;edx = linear addr of CS
pascal@19634 150 mov si,offset gdt_vcpi
pascal@19538 151 ; Fix up base of some gdt descriptors
pascal@19538 152 ; Note: 'add [dword xx.base0],edx' actually updates 24 bit quantity!
pascal@19538 153 ; Do NOT replace with mov!
pascal@19919 154 mov ebx,10000h-28h
pascal@19906 155 add [dword bx+si+sw2pm_idtr_ptr-gdt_vcpi+28h],edx
pascal@19634 156 @@fixup:
pascal@19906 157 add [dword bx+si+(gdt_code.base0)-gdt_vcpi+28h],edx
pascal@19919 158 add bx,8
pascal@19906 159 js @@fixup
pascal@19919 160 mov bh,10h
pascal@19538 161 add eax,edx
pascal@19919 162 and ax,0f000h ;eax = 4k aligned linear addr of pagebuf
pascal@19919 163 add eax,ebx ;eax=page0 linear addr
pascal@19906 164 add [si+sw2pm_cr3-gdt_vcpi],eax
pascal@19919 165 mov edi,eax
pascal@19919 166 sub edi,edx
pascal@19538 167 mov al,3 ;add present+writable bits
pascal@19919 168 mov [bx+di],eax ;stuff it into pagedir[0]
pascal@19634 169 push ds
pascal@19919 170 pop es ;es:di->page0,es:di+1000h->pagedir
pascal@19538 171 ;page directory will use only one entry (4 bytes):
pascal@19538 172 ;cr3 => pagedir => page0 => ########
pascal@19538 173 ; (1 entry) (1024 => # 4M #
pascal@19538 174 ; entries)=> # page #
pascal@19538 175 ; => ########
pascal@19538 176 ; Return
pascal@19919 177 lea ax,[bx+di+4]
pascal@19538 178 extrn _heap_top:word
pascal@19538 179 mov [_heap_top],ax
pascal@19538 180 ;ret
pascal@19538 181
pascal@20486 182 endp prepare_vcpi
pascal@19538 183
pascal@19538 184
pascal@19538 185 ;***************************************************************
pascal@19538 186 ;int get_vcpi_interface();
pascal@19634 187 ;****** Return: Z - page mapping for low 640k is 1:1
pascal@19634 188 ;****** NZ - otherwise (it's bad)
pascal@19538 189 ;****** Uses: Flags
pascal@19538 190 ;***************************************************************
pascal@20486 191 ;global _get_vcpi_interface:near
pascal@19538 192 proc _get_vcpi_interface near
pascal@19538 193
pascal@19538 194 ;push si di
pascal@19538 195
pascal@19538 196 ; Get and save VCPI pm interface
pascal@19634 197 ;mov si,offset gdt_vcpi ;DS:DI => 3 GDT entries for VCPI
pascal@19546 198 ;mov di,[si+page0_ofs-gdt_vcpi] ;ES:DI => page0
pascal@19546 199 ;push ds
pascal@19546 200 ;pop es
pascal@19634 201 push di
pascal@19538 202 mov ax,0DE01h ;get vcpi pm interface
pascal@19538 203 int 67h
pascal@19634 204 xchg [vcpi_pm_entry],ebx ;clear ebx
pascal@19634 205 ;xor bx,bx
pascal@19538 206
pascal@19538 207 ; Check that mapping for low 640k is 1:1
pascal@19634 208 pop si ; [page0_ofs]
pascal@19571 209 ;cld
pascal@19538 210 @@map_chk:
pascal@19538 211 lodsd
pascal@19538 212 shr eax,12
pascal@19538 213 cmp ax,bx
pascal@19538 214 jne @@bad
pascal@19538 215 inc bx
pascal@19634 216 cmp al,((640*1024) shr 12)-1
pascal@19538 217 jne @@map_chk
pascal@19538 218 ; Return
pascal@19538 219 @@bad:
pascal@19538 220 ret
pascal@19538 221 endp _get_vcpi_interface
pascal@19538 222
pascal@19538 223
pascal@19538 224 ;***************************************************************
pascal@19538 225 ;void memcpy_vcpi(u32 dstofs,u16 srcseg,u32 srcofs);
pascal@19538 226 ;***************************************************************
pascal@19538 227 ;****** Copies PAGE_SIZE bytes
pascal@19538 228 ;****** Uses: Flags
pascal@19538 229 ;***************************************************************
pascal@20534 230 global vcpi_pm_copy_routine:near
pascal@20534 231 proc vcpi_pm_copy_routine near
pascal@19538 232
pascal@19538 233 arg dstofs :dword, \
pascal@19538 234 srcseg :word, \
pascal@19538 235 srcofs :dword = PARAM_SIZE
pascal@19538 236
pascal@19538 237 struc pm_regs
pascal@19538 238 $$retaddr dw ?
pascal@19538 239 $$edi dd ?
pascal@19538 240 $$esi dd ?
pascal@19538 241 $$ebp dd ?
pascal@19538 242 $$esp dd ?
pascal@19538 243 $$ebx dd ?
pascal@19538 244 $$edx dd ?
pascal@19538 245 $$ecx dd ?
pascal@19538 246 $$eax dd ?
pascal@19538 247 ends
pascal@19538 248
pascal@19538 249 ;***************************************************************
pascal@19538 250 ;****** Helper: goes into 16bit pm and calls routine (addr on stk)
pascal@19538 251 ;***************************************************************
pascal@19538 252 mov bp,sp ; ss:bp => struct pm_regs
pascal@19538 253
pascal@19538 254 xor ax,ax ; IRET stack for return to vm
pascal@19538 255 push ax gs ; (9 dwords)
pascal@19538 256 push ax fs ;
pascal@19538 257 push ax ds ;
pascal@19538 258 push ax es ;
pascal@19538 259 push ax ss ;
pascal@19538 260 push ebp ; esp
pascal@19538 261 pushfd ; eflags: IF saved here
pascal@19538 262 push ax cs ;
pascal@19538 263 push ax ;\eip
pascal@19538 264 push offset @@vm_ret ;/
pascal@19538 265
pascal@19538 266 ;;mov [saved_xx],xx ;use if your vcpi trashes bp/etc
pascal@19538 267
pascal@19634 268 call switch_to_pm
pascal@19634 269
pascal@19538 270 ; Now we are in 16-bit protected mode
pascal@19538 271 mov ax,SEL_DATA
pascal@19538 272 mov ss,ax
pascal@19538 273 ;;mov ds,ax
pascal@19538 274 ;;mov es,ax
pascal@19538 275 ;;mov fs,ax
pascal@19538 276 ;;mov gs,ax
pascal@19538 277 assume nothing
pascal@19538 278 assume cs:DGROUP
pascal@19538 279
pascal@19538 280 ;;mov xx,[saved_xx] ;use if your vcpi trashes bp/etc
pascal@19538 281 lea sp,[bp-9*4] ;else we can do this trick with bp
pascal@19538 282
pascal@19538 283 ; Call the routine (bp points to params on stack if any)
pascal@19538 284 mov bp,[word (pm_regs bp).$$ebp] ;ss:bp => params
pascal@20534 285 call do_memcpy_vcpi
pascal@19538 286
pascal@19538 287 ; Ok, let's return to vm
pascal@19634 288 mov ax,0DE0Ch ; maybe we need whole eax?
pascal@19538 289 cli ; to be safe
pascal@19538 290 clts ;
pascal@20534 291 ;;push SEL_ABS ; vcpi wants ds=all_addrspace
pascal@20534 292 ;;pop ds ;
pascal@19538 293 call [pword cs:vcpi_pm_entry]
pascal@19538 294 @@vm_ret:
pascal@19538 295 ; Now we are in vm86 mode. Sregs, esp, eflags (IF) restored from IRET stack
pascal@19538 296 ret
pascal@19538 297
pascal@19538 298 ;***************************************************************
pascal@19634 299 switch_to_pm:
pascal@19634 300 assume cs:DGROUP,ds:DGROUP
pascal@19634 301 pop [word sw2pm_jumpaddr]
pascal@19634 302 ;mov [word sw2pm_jumpaddr+2],0
pascal@19634 303 ;mov [word sw2pm_jumpaddr+4],SEL_CODE
pascal@19634 304 mov esi,cs
pascal@19634 305 shl esi,4
pascal@19634 306 addzx_e si,<offset sw2pm_params>
pascal@19634 307 mov ax,0DE0Ch ; vcpi: switch to pm
pascal@19634 308 cli
pascal@19634 309 int 67h
pascal@19634 310
pascal@19634 311 ;***************************************************************
pascal@19538 312 ;****** Helper: This is where real copy is done
pascal@19538 313 ;***************************************************************
pascal@19538 314 global do_memcpy_vcpi:near
pascal@19538 315 label do_memcpy_vcpi near
pascal@19538 316
pascal@19538 317 ; Note: ss:bp => params
pascal@19538 318 ; Move data
pascal@20534 319 mov al,SEL_ABS
pascal@19634 320 mov ds,ax
pascal@19634 321 mov es,ax
pascal@19538 322 assume nothing
pascal@19538 323 assume cs:DGROUP
pascal@19538 324
pascal@19538 325 ; Set up target addr:
pascal@19538 326 ; replace page mapping for page at 0 so
pascal@19538 327 ; that it points to dstofs
pascal@19538 328 mov eax,[dstofs]
pascal@19538 329 mov al,03h ; writeable, present
pascal@19634 330 call @@set_mapping
pascal@19538 331 ;push eax ;X we'll need to restore mapping...
pascal@19538 332 xor edi,edi ;es:edi => remapped page
pascal@19538 333
pascal@19538 334 ; Set up source addr
pascal@19538 335 mov esi,[srcofs]
pascal@19538 336
pascal@19538 337 ; Do copying
pascal@19634 338 xor ecx,ecx
pascal@19634 339 mov ch,4096/256
pascal@19571 340 ;cld
pascal@19538 341 ;; cmp esi,edi
pascal@19538 342 ;; jae @@do_copy
pascal@19538 343 ;; add esi,ecx ;src<dst: we must do
pascal@19538 344 ;; dec esi ; copy backwards to avoid
pascal@19538 345 ;; add edi,ecx ; overwrite bug
pascal@19538 346 ;; dec edi ;
pascal@19538 347 ;; std ;
pascal@19538 348 ;;@@do_copy:
pascal@19538 349 db 67h ;address width override for esi/edi
pascal@19634 350 rep movsb
pascal@19538 351 ;; cld
pascal@19538 352
pascal@19538 353 ; Restore page mapping for page at 0
pascal@19538 354 ;pop eax ;X
pascal@19634 355 @@set_mapping:
pascal@19906 356 mov esi,[cs:sw2pm_cr3]
pascal@19906 357 xchg [esi-1000h],eax ; restore page0[0]
pascal@19538 358 mov ecx,cr3 ; reload TLB cache
pascal@19538 359 mov cr3,ecx ;
pascal@19538 360 ; Return
pascal@19907 361 vcpi_ret:
pascal@19538 362 ret
pascal@19538 363
pascal@20534 364 endp vcpi_pm_copy_routine
pascal@20534 365 assume cs:DGROUP,ds:DGROUP
pascal@19538 366
pascal@19538 367
pascal@19538 368 ;***************************************************************
pascal@19538 369 ;void _vm2rm();
pascal@19538 370 ;***************************************************************
pascal@19538 371 ;****** Uses: Flags
pascal@19538 372 ;***************************************************************
pascal@19538 373 global _vm2rm:near
pascal@19538 374 proc _vm2rm near
pascal@19538 375
pascal@20473 376 ifdef NO386
pascal@19825 377 p8086
pascal@19580 378 extrn _vcpi:byte
pascal@19580 379 test [_vcpi],-1
pascal@20473 380 else
pascal@20473 381 p386
pascal@20473 382 smsw ax ;SMSW cannot be trapped! :-)
pascal@20473 383 and al,1 ;MSW_PE
pascal@20473 384 endif
pascal@19907 385 jz vcpi_ret
pascal@19825 386 p386
pascal@19907 387 pop ax
pascal@19907 388 push cs ;*
pascal@19907 389 push ax
pascal@19634 390 push si
pascal@19538 391 push ds
pascal@20453 392 extrn sssp:word
pascal@20453 393 mov [sssp],sp
pascal@20473 394 ;mov [sssp+2],ss
pascal@19538 395
pascal@19634 396 call switch_to_pm
pascal@19634 397
pascal@19538 398 ; Now we are in 16-bit protected mode
pascal@19538 399 mov ax,SEL_DATA ; load data sregs with limit >=64k
pascal@19538 400 mov ss,ax ; or you may get limit violations
pascal@19538 401 mov ds,ax ; later in rm
pascal@19634 402 ;mov es,ax ; (actually I prefer 4gig limits :-)
pascal@19571 403 ;mov fs,ax ;
pascal@19571 404 ;mov gs,ax ;
pascal@19538 405
pascal@19538 406 ; Black magic here
pascal@19538 407 mov eax,cr0
pascal@19538 408 and eax,7ffffffeh ; clear PG,P bits
pascal@19538 409 mov cr0,eax ; look mommy, we're in rm now!
pascal@19538 410 mov cr3,eax ; flush TLB cache
pascal@19538 411
pascal@19538 412 ; Now we are in rm, but not yet: have to restore sregs:
pascal@20453 413 lss sp,[dword sssp]; SS
pascal@19538 414 pop ds ; DS
pascal@19907 415 pop si
pascal@19538 416 retf ; CS
pascal@19571 417
pascal@19538 418 endp _vm2rm
pascal@19538 419
pascal@19538 420 ends _TEXT
pascal@19538 421
pascal@19538 422 end
pascal@19538 423
pascal@19538 424 ;###### END OF FILE ############################################