wok-current annotate BootProg/stuff/bootex.asm @ rev 24479

BootProg: nasm 2.15.05 support
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri Feb 18 11:32:41 2022 +0000 (2022-02-18)
parents 04472f031354
children d8c511e24c20
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Limitations: ;;
pascal@24476 28 ;; ~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 29 ;; - Works only on the 1st MBR partition which must be a PRI DOS partition ;;
pascal@24476 30 ;; with exFAT (File System ID: 07h) ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Known Bugs: ;;
pascal@24476 34 ;; ~~~~~~~~~~~ ;;
pascal@24476 35 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 36 ;; on a 128MB qemu image. ;;
pascal@24476 37 ;; ;;
pascal@24476 38 ;; ;;
pascal@24476 39 ;; Memory Layout: ;;
pascal@24476 40 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 41 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 42 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 43 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 44 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; physical address ;;
pascal@24476 47 ;; +------------------------+ 00000H ;;
pascal@24476 48 ;; | Interrupt Vector Table | ;;
pascal@24476 49 ;; +------------------------+ 00400H ;;
pascal@24476 50 ;; | BIOS Data Area | ;;
pascal@24476 51 ;; +------------------------+ 00500H ;;
pascal@24476 52 ;; | PrtScr Status / Unused | ;;
pascal@24476 53 ;; +------------------------+ 00600H ;;
pascal@24476 54 ;; | Loaded Image | ;;
pascal@24476 55 ;; +------------------------+ nnnnnH ;;
pascal@24476 56 ;; | Available Memory | ;;
pascal@24476 57 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 58 ;; | Boot Sector | ;;
pascal@24476 59 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24476 60 ;; | 1.5KB Boot Stack | ;;
pascal@24476 61 ;; +------------------------+ A0000H ;;
pascal@24476 62 ;; | Video RAM | ;;
pascal@24476 63 ;; ;;
pascal@24476 64 ;; ;;
pascal@24476 65 ;; Boot Image Startup (register values): ;;
pascal@24476 66 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 67 ;; dl = BIOS boot drive number (e.g. 80H) ;;
pascal@24476 68 ;; cs:ip = program entry point ;;
pascal@24476 69 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 70 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 71 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 72 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 73 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 74 ;; Magic numbers: ;;
pascal@24476 75 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 76 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 77 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 78 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 79 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 80 ;; metal and MS-DOS programs. ;;
pascal@24476 81 ;; ;;
pascal@24476 82 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 83
pascal@24476 84 %define bx(label) bx+label-boot
pascal@24476 85
pascal@24476 86 [BITS 16]
pascal@24476 87 [CPU 386]
pascal@24476 88
pascal@24476 89 ImageLoadSeg equ 60h
pascal@24476 90 StackSize equ 1536
pascal@24476 91
pascal@24476 92 [SECTION .text]
pascal@24476 93 [ORG 0]
pascal@24476 94
pascal@24476 95 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 96 ;; Boot sector starts here ;;
pascal@24476 97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 98
pascal@24476 99 boot:
pascal@24476 100 jmp short start ; Windows checks for this jump
pascal@24476 101 nop
pascal@24476 102 bsOemName DB "EXFAT " ; 0x03
pascal@24476 103 times 53 db 0 ; 0x0B
pascal@24476 104
pascal@24476 105 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 106 ;; BPB starts here ;;
pascal@24476 107 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 108
pascal@24479 109 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 110 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 111 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 112 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 113 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 114 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 115 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 116 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 117 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 118 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 119 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 120 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 121 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 122 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 123 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 124 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 125
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;
pascal@24476 127 ;; BPB ends here ;;
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;
pascal@24476 129
pascal@24476 130 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 131 ;; Boot sector code starts here ;;
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133
pascal@24476 134 start:
pascal@24476 135 cld
pascal@24476 136
pascal@24476 137 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 138 ;; How much RAM is there? ;;
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 140
pascal@24476 141 int 12h ; get conventional memory size (in KBs)
pascal@24476 142 mov cx, 106h
pascal@24476 143 dec ax
pascal@24476 144 dec ax ; reserve 2K bytes for the code and the stack
pascal@24476 145 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 152 mov ss, ax
pascal@24476 153 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 154
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156 ;; Copy ourselves to top of memory ;;
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158
pascal@24476 159 mov si, 7C00h
pascal@24476 160 xor di, di
pascal@24476 161 mov ds, di
pascal@24476 162 rep movsw ; move 512 bytes (+ 12)
pascal@24476 163
pascal@24476 164 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 165 ;; Jump to the copy ;;
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167
pascal@24476 168 push es
pascal@24479 169 push byte main
pascal@24476 170 retf
pascal@24476 171
pascal@24476 172 main:
pascal@24476 173 push cs
pascal@24476 174 pop ds
pascal@24476 175
pascal@24476 176 xor ebx, ebx
pascal@24476 177 mov [bx], dx ; store BIOS boot drive number
pascal@24476 178
pascal@24476 179 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 180
pascal@24479 181 push byte ImageLoadSeg
pascal@24476 182 pop es
pascal@24476 183
pascal@24476 184 RootDirReadContinue:
pascal@24476 185 call ReadCluster ; read one sector of root dir
pascal@24476 186 pushf ; save carry="not last sector" flag
pascal@24476 187
pascal@24476 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 189 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 190 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 191
pascal@24476 192 xor di, di ; es:di -> root entries array
pascal@24476 193
pascal@24476 194 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 195 ;; Looks for the file/dir ProgramName ;;
pascal@24476 196 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 197 ;; Input: ES:DI -> root directory array ;;
pascal@24476 198 ;; Output: ESI = cluster number ;;
pascal@24476 199 ;; dword [bx+FileSize] file size ;;
pascal@24476 200 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 201
pascal@24476 202 CurNameSize equ 3
pascal@24476 203 StartCluster equ 14h
pascal@24476 204 FileSize equ 18h
pascal@24476 205
pascal@24476 206 FindNameCycle:
pascal@24476 207 pusha
pascal@24476 208
pascal@24476 209 xor ax, ax
pascal@24476 210 or al, [es:di]
pascal@24476 211 je FindNameFailed
pascal@24476 212
pascal@24476 213 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 214 jne NotFileInfo
pascal@24476 215
pascal@24476 216 mov bl, 30
pascal@24476 217 CopyInfo:
pascal@24476 218 mov ax, [es:di+bx]
pascal@24476 219 mov [bx], ax
pascal@24476 220 dec bx
pascal@24476 221 dec bx
pascal@24476 222 jnz CopyInfo
pascal@24476 223
pascal@24476 224 NotFileInfo:
pascal@24476 225 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 226 mov cx, NameLength+1
pascal@24476 227 mov si, ProgramName ; ds:si -> program name
pascal@24476 228 CheckName:
pascal@24476 229 scasw ; compare UTF-16
pascal@24476 230 lodsb ; with ASCII
pascal@24476 231 loope CheckName
pascal@24476 232 je FindNameFound ; cx = 0
pascal@24476 233 popa ; restore ax, cx, si, di
pascal@24476 234
pascal@24479 235 add di, byte 32
pascal@24476 236 cmp di, bp
pascal@24476 237 jne FindNameCycle ; next root entry
pascal@24476 238 popf ; restore carry="not last sector" flag
pascal@24476 239 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 240 FindNameFailed: ; end of root directory (dir end reached)
pascal@24476 241 call Error
pascal@24476 242 db "File not found."
pascal@24476 243 FindNameFound:
pascal@24476 244 mov esi, [bx+StartCluster]
pascal@24476 245
pascal@24476 246 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 247 ;; Load the entire file ;;
pascal@24476 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 249
pascal@24476 250 push es
pascal@24476 251 xor bp, bp
pascal@24476 252 FileReadContinue:
pascal@24476 253 shr bp, 4 ; bytes to paragraphs
pascal@24476 254 mov di, es
pascal@24476 255 add di, bp ; adjust segment for next sector
pascal@24476 256 mov es, di ; es:0 updated
pascal@24476 257 call ReadCluster ; read one cluster of root dir
pascal@24476 258 sub [bx+FileSize], ebp
pascal@24476 259 ja FileReadContinue
pascal@24476 260 pop bp
pascal@24476 261
pascal@24476 262 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 263 ;; Type detection, .COM or .EXE? ;;
pascal@24476 264 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 265
pascal@24476 266 mov dl, [bx] ; pass the BIOS boot drive
pascal@24476 267 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 268
pascal@24476 269 add bp, [bx+08h] ; bp = image base
pascal@24476 270 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 271 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 272
pascal@24476 273 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 274 je RelocateEXE ; yes, it's an EXE program
pascal@24476 275
pascal@24476 276 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 277 ;; Setup and run a .COM program ;;
pascal@24476 278 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280
pascal@24476 281 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 282 mov ss, bp
pascal@24476 283 xor sp, sp
pascal@24476 284 push bp ; cs, ds and es
pascal@24476 285 mov bh, 1 ; ip
pascal@24476 286 jmp short Run
pascal@24476 287
pascal@24476 288 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 289 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 290 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 291 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24476 292 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 293
pascal@24476 294 ReloCycle:
pascal@24476 295 add [di+2], bp ; item seg (abs)
pascal@24476 296 les si, [di] ; si = item ofs, es = item seg
pascal@24476 297 add [es:si], bp ; fixup
pascal@24476 298 scasw ; di += 2
pascal@24476 299 scasw ; point to next entry
pascal@24476 300
pascal@24476 301 RelocateEXE:
pascal@24476 302 dec ax ; 32768 max (128KB table)
pascal@24476 303 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 304 ; PSP don't have a valid drive identifier
pascal@24476 305 les si, [bx+0Eh]
pascal@24476 306 add si, bp
pascal@24476 307 mov ss, si ; ss for EXE
pascal@24476 308 mov sp, es ; sp for EXE
pascal@24476 309
pascal@24476 310 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 311 push si ; containing the PSP structure
pascal@24476 312
pascal@24476 313 add bp, [bx+16h] ; cs for EXE
pascal@24476 314 mov bx, [bx+14h] ; ip for EXE
pascal@24476 315 Run:
pascal@24476 316 pop ds
pascal@24476 317 push bp
pascal@24476 318 push bx
pascal@24476 319 push ds
pascal@24476 320 pop es
pascal@24476 321
pascal@24476 322 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 323 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 324 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 325 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 326 mov si, 16381 ; prime number 2**14-3
pascal@24476 327 mov di, 32749 ; prime number 2**15-19
pascal@24476 328 mov bp, 65521 ; prime number 2**16-15
pascal@24476 329
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 ;; All done, transfer control to the program now ;;
pascal@24476 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 333 retf
pascal@24476 334
pascal@24476 335 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 336 ;; Reads a exFAT cluster ;;
pascal@24476 337 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 338 ;; Input: EDX:EAX = LBA ;;
pascal@24476 339 ;; EBX = 0 ;;
pascal@24476 340 ;; CX = sector cnt ;;
pascal@24476 341 ;; ESI = cluster no ;;
pascal@24476 342 ;; ES:0 -> buffer adrs ;;
pascal@24476 343 ;; Output: EBX = 0 ;;
pascal@24476 344 ;; CX = next cnt ;;
pascal@24476 345 ;; EBP = bytes/sector;;
pascal@24476 346 ;; ES:0 -> next adrs ;;
pascal@24476 347 ;; C=0 for last sector ;;
pascal@24476 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 349
pascal@24476 350 ReadCluster:
pascal@24476 351 inc cx ; jcxnz
pascal@24479 352 add eax, byte 1
pascal@24476 353 loop ReadSectorC
pascal@24476 354
pascal@24476 355 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 356 dec cx
pascal@24476 357 dec cx
pascal@24476 358 mul ebx ; edx:eax = 0
pascal@24476 359 inc ax
pascal@24476 360 shl eax, cl ; eax=# of exFAT entries per sector
pascal@24476 361 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 362 xchg eax, esi
pascal@24476 363 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 364
pascal@24476 365 imul si, dx, 4 ; si=entry # offset in sector
pascal@24476 366
pascal@24476 367 cdq
pascal@24476 368 add eax, [bx(bpbFatSectorStart)] ; sector # relative to FAT32
pascal@24476 369 call ReadSectorC ; read 1 FAT32 sector
pascal@24476 370
pascal@24476 371 mov esi, [es:si] ; esi=next cluster #
pascal@24476 372
pascal@24476 373 xor eax, eax
pascal@24476 374 inc ax
pascal@24476 375 mov cl, [bx(bpbSectorPerClusterBits)]
pascal@24476 376 shl eax, cl ; 10000h max (32MB cluster)
pascal@24476 377 xchg eax, ecx
pascal@24476 378 xchg eax, edi ; get cluster #-2
pascal@24476 379 mul ecx
pascal@24476 380
pascal@24476 381 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 382 ReadSectorC:
pascal@24476 383 adc edx, ebx
pascal@24476 384
pascal@24476 385 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 386 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 387 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 388 ;; Input: EDX:EAX = LBA ;;
pascal@24476 389 ;; BX = 0 ;;
pascal@24476 390 ;; CX = sector count ;;
pascal@24476 391 ;; ES:0 -> buffer address ;;
pascal@24476 392 ;; Output: BX = 0 ;;
pascal@24476 393 ;; CX = next count ;;
pascal@24476 394 ;; EBP = bytes/sector ;;
pascal@24476 395 ;; ES:0 -> next address ;;
pascal@24476 396 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 397
pascal@24476 398 ReadSector:
pascal@24476 399
pascal@24476 400 xor ebp, ebp
pascal@24476 401 inc bp
pascal@24476 402
pascal@24476 403 pushad
pascal@24476 404
pascal@24476 405 add eax, [bx(bpbSectorStart)]
pascal@24476 406 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 407
pascal@24476 408 push edx
pascal@24476 409 push eax
pascal@24476 410 push es
pascal@24476 411 push bx
pascal@24476 412 push bp ; sector count word = 1
pascal@24476 413 mov cx, 16
pascal@24476 414 push cx ; packet size byte = 16, reserved byte = 0
pascal@24476 415 ReadSectorRetry:
pascal@24476 416 mov si, sp
pascal@24476 417 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 418 mov dl, [bx]
pascal@24476 419 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 420
pascal@24476 421 jnc ReadSuccess
pascal@24476 422
pascal@24476 423 xor ax, ax
pascal@24476 424 int 13h ; reset drive (DL)
pascal@24476 425 loop ReadSectorRetry
pascal@24476 426
pascal@24476 427 call Error
pascal@24476 428 db "Read error."
pascal@24476 429
pascal@24476 430 ReadSuccess:
pascal@24476 431 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 432 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@24476 433 popa ; sp += 16
pascal@24476 434 popad ; real registers
pascal@24476 435
pascal@24476 436 stc
pascal@24476 437 loop ReadSectorNext
pascal@24476 438
pascal@24479 439 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 440 ReadSectorNext:
pascal@24476 441 ret
pascal@24476 442
pascal@24476 443 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 444 ;; Error Messaging Code ;;
pascal@24476 445 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 446
pascal@24476 447 Error:
pascal@24476 448 pop si
pascal@24476 449 mov dl, [bx] ; restore BIOS boot drive number
pascal@24478 450
pascal@24478 451 PutStr:
pascal@24476 452 mov ah, 0Eh
pascal@24476 453 mov bl, 7
pascal@24476 454 lodsb
pascal@24476 455 int 10h
pascal@24476 456 cmp al, "."
pascal@24476 457 jne PutStr
pascal@24476 458
pascal@24476 459 cbw
pascal@24476 460 int 16h ; wait for a key...
pascal@24476 461 int 19h ; bootstrap
pascal@24476 462
pascal@24476 463 Stop:
pascal@24476 464 hlt
pascal@24476 465 jmp short Stop
pascal@24476 466
pascal@24476 467 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 468 ;; Fill free space with zeroes ;;
pascal@24476 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 470
pascal@24476 471 times (512-13-($-$$)) db 0
pascal@24476 472
pascal@24476 473 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 474 ;; Name of the file to load and run ;;
pascal@24476 475 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 476
pascal@24476 477 ProgramName db "startup.bin" ; name and extension
pascal@24476 478 NameLength equ $-ProgramName
pascal@24476 479
pascal@24476 480 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 481 ;; End of the sector ID ;;
pascal@24476 482 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 483
pascal@24476 484 dw 0AA55h ; BIOS checks for this ID