wok annotate BootProg/stuff/boot16.asm @ rev 25564

Up memtest (6.20)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Thu May 11 15:58:49 2023 +0000 (16 months ago)
parents f40d97a52c42
children 64471e67874e
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - FAT12 and FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@25564 29 ;; Known Limitation: ;;
pascal@25564 30 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 31 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 32 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 33 ;; ;;
pascal@25564 34 ;; - Partition must fit in the first 8GB disk for CHS reads. ;;
pascal@25564 35 ;; ;;
pascal@25564 36 ;; ;;
pascal@24476 37 ;; Known Bugs: ;;
pascal@24476 38 ;; ~~~~~~~~~~~ ;;
pascal@24476 39 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 40 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 41 ;; - 360KB 5"25 ;;
pascal@24476 42 ;; - 1.2MB 5"25 ;;
pascal@24476 43 ;; - 1.44MB 3"5 ;;
pascal@24476 44 ;; on my HDD (FAT16). ;;
pascal@24476 45 ;; ;;
pascal@24476 46 ;; ;;
pascal@24476 47 ;; Memory Layout: ;;
pascal@24476 48 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 49 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 50 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 51 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 52 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 53 ;; ;;
pascal@24476 54 ;; physical address ;;
pascal@24476 55 ;; +------------------------+ 00000H ;;
pascal@24476 56 ;; | Interrupt Vector Table | ;;
pascal@24476 57 ;; +------------------------+ 00400H ;;
pascal@24476 58 ;; | BIOS Data Area | ;;
pascal@24476 59 ;; +------------------------+ 00500H ;;
pascal@24476 60 ;; | PrtScr Status / Unused | ;;
pascal@24476 61 ;; +------------------------+ 00600H ;;
pascal@24476 62 ;; | Loaded Image | ;;
pascal@24476 63 ;; +------------------------+ nnnnnH ;;
pascal@24476 64 ;; | Available Memory | ;;
pascal@24476 65 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 66 ;; | Boot Sector | ;;
pascal@24476 67 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 68 ;; | 3KB Boot Stack | ;;
pascal@24476 69 ;; +------------------------+ A0000H ;;
pascal@24476 70 ;; | Video RAM | ;;
pascal@24476 71 ;; ;;
pascal@24476 72 ;; ;;
pascal@24476 73 ;; Boot Image Startup (register values): ;;
pascal@24476 74 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 75 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 76 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 77 ;; cs:ip = program entry point ;;
pascal@24476 78 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 79 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 80 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 81 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 82 ;; Magic numbers: ;;
pascal@24476 83 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 84 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 85 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 86 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 87 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 88 ;; metal and MS-DOS programs. ;;
pascal@24945 89 ;; The command line contains no arguments. ;;
pascal@24476 90 ;; ;;
pascal@24476 91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 92
pascal@24476 93 %define bx(label) bx+label-boot
pascal@25450 94 %define si(label) si+label-boot
pascal@25458 95 NullEntryCheck equ 1 ; +2 bytes
pascal@25564 96 ReadRetry equ 1 ; +9/+10 bytes
pascal@25450 97 LBAsupport equ 1 ; +16 bytes
pascal@25564 98 CHSsanityCheck equ 1 ; +12/+16 bytes
pascal@25450 99 GeometryCheck equ 1 ; +18 bytes
pascal@25564 100 CheckAttrib equ 0 ; +6 bytes
pascal@25564 101 WaitForKey equ 0 ; +5 bytes
pascal@25550 102 SectorOf512Bytes equ 0 ; -4/-6 bytes
pascal@25564 103 Always2FATs equ 0 ; -1 bytes
pascal@24476 104
pascal@24476 105 [BITS 16]
pascal@24476 106 [CPU 8086]
pascal@24476 107
pascal@24476 108 ImageLoadSeg equ 60h
pascal@24476 109 StackSize equ 3072 ; Stack + cluster list
pascal@24476 110
pascal@24476 111 [SECTION .text]
pascal@24476 112 [ORG 0]
pascal@24476 113
pascal@24476 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 115 ;; Boot sector starts here ;;
pascal@24476 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 117
pascal@24476 118 boot:
pascal@25450 119 DriveNumber:
pascal@24476 120 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 121 nop
pascal@24476 122 bsOemName DB "BootProg" ; 0x03
pascal@24476 123
pascal@24476 124 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 125 ;; BPB starts here ;;
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 127
pascal@25564 128 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 129 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32 or 64
pascal@25564 130 bpbReservedSectors DW 0 ; 0x0E 1
pascal@25564 131 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@24479 132 bpbRootEntries DW 0 ; 0x11
pascal@24479 133 bpbTotalSectors DW 0 ; 0x13
pascal@24479 134 bpbMedia DB 0 ; 0x15
pascal@24479 135 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 136 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 137 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 138 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 139 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 140
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;
pascal@24476 142 ;; BPB ends here ;;
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;
pascal@24476 144
pascal@24479 145 bsDriveNumber DB 0 ; 0x24
pascal@24479 146 bsUnused DB 0 ; 0x25
pascal@25564 147 bsExtBootSignature DB 0 ; 0x26 29
pascal@24479 148 bsSerialNumber DD 0 ; 0x27
pascal@25458 149 bsVolumeLabel times 11 DB " " ; 0x2B "NO NAME "
pascal@25458 150 bsFileSystem times 8 DB " " ; 0x36 "FAT12 " or "FAT16 "
pascal@24476 151
pascal@24476 152 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 153 ;; Boot sector code starts here ;;
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155
pascal@24476 156 start:
pascal@24476 157 cld
pascal@24476 158
pascal@24476 159 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 160 ;; How much RAM is there? ;;
pascal@24476 161 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 162
pascal@24476 163 int 12h ; get conventional memory size (in KBs)
pascal@24476 164 mov cx, 106h
pascal@24476 165 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 166
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 169 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 170
pascal@24476 171 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 172 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 173 mov ss, ax
pascal@24476 174 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 175
pascal@24476 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 177 ;; Copy ourselves to top of memory ;;
pascal@24476 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 179
pascal@24476 180 mov si, 7C00h
pascal@24476 181 xor di, di
pascal@24476 182 mov ds, di
pascal@25450 183 push es
pascal@25450 184 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 185 rep movsw ; move 512 bytes (+ 12)
pascal@24476 186
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188 ;; Jump to the copy ;;
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190
pascal@24476 191 mov cl, byte main
pascal@24476 192 push cx
pascal@24476 193 retf
pascal@24476 194
pascal@24476 195 main:
pascal@24476 196 %if ImageLoadSeg != main-boot
pascal@24476 197 %if ImageLoadSeg >= 100h
pascal@24476 198 mov cx, ImageLoadSeg
pascal@24476 199 %else
pascal@24476 200 mov cl, ImageLoadSeg
pascal@24476 201 %endif
pascal@24476 202 %endif
pascal@24476 203 push cx
pascal@24476 204
pascal@24476 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 206 ;; Get drive parameters ;;
pascal@24476 207 ;; Update heads count ;;
pascal@24476 208 ;; for current BIOS ;;
pascal@24476 209 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 210
pascal@25450 211 %if GeometryCheck != 0
pascal@25564 212 %if ((main-boot) & 3Fh) != 0
pascal@25564 213 xchg ax, cx ; ax & 3Fh == 0
pascal@25564 214 %endif
pascal@25564 215 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 216 int 13h ; may destroy SI,BP, and DS registers
pascal@25450 217 %endif
pascal@24476 218 push cs
pascal@24476 219 pop ds
pascal@24476 220 xor bx, bx
pascal@24476 221
pascal@25450 222 %if GeometryCheck != 0
pascal@24479 223 and cx, byte 3Fh
pascal@25564 224 je BadParams ; verify updated and validity
pascal@25564 225 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 226 mov cl, dh
pascal@25564 227 inc cx
pascal@25564 228 mov [bx(bpbHeadsPerCylinder)], cx
pascal@24476 229 BadParams:
pascal@25450 230 %endif
pascal@24476 231
pascal@24476 232 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 233 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 234 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 235
pascal@24476 236 pop es ; ImageLoadSeg
pascal@24476 237 push es
pascal@24476 238
pascal@24476 239 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@25458 240 mov di, word [bx(bpbSectorsPerFAT)]
pascal@24476 241
pascal@25458 242 call ReadDISectors ; read fat; clear ax, cx, di; bp = SectorsPerFAT
pascal@24476 243
pascal@24476 244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 245 ;; load the root directory in ;;
pascal@24476 246 ;; its entirety (16KB max) ;;
pascal@24476 247 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 248
pascal@25458 249 %if SectorOf512Bytes != 0
pascal@25458 250 mov di, word [bx(bpbRootEntries)]
pascal@25458 251 mov cl, 4
pascal@25458 252 shr di, cl ; di = root directory size in sectors
pascal@25458 253 %else
pascal@24942 254 mov al, 32
pascal@24476 255
pascal@24476 256 mul word [bx(bpbRootEntries)]
pascal@24476 257 div word [bx(bpbBytesPerSector)]
pascal@25458 258 xchg ax, di ; di = root directory size in sectors, clear ah
pascal@25458 259 %endif
pascal@24476 260
pascal@25564 261 %if Always2FATs != 0
pascal@25564 262 mov al, 2
pascal@25564 263 %else
pascal@24476 264 mov al, [bpbNumberOfFATs]
pascal@25564 265 %endif
pascal@25458 266 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadDISectors
pascal@24476 267
pascal@25457 268 push es ; read root directory
pascal@25458 269 call ReadDISectors ; clear ax, cx, di; bp = first data sector
pascal@24476 270 pop es
pascal@24476 271
pascal@24476 272 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 273 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 274 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 275
pascal@24476 276 ; es:di -> root entries array
pascal@24476 277
pascal@24476 278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 279 ;; Looks for the file/dir ProgramName ;;
pascal@24476 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 281 ;; Input: ES:DI -> root directory array ;;
pascal@24476 282 ;; Output: SI = cluster number ;;
pascal@24476 283 ;; AX = file sector count ;;
pascal@24476 284 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 285
pascal@24476 286 FindNameCycle:
pascal@24476 287 push di
pascal@25454 288 mov cl, NameLength
pascal@24476 289 mov si, ProgramName ; ds:si -> program name
pascal@24476 290 repe cmpsb
pascal@25467 291 %if CheckAttrib != 0
pascal@25467 292 VolumeLabel equ 8
pascal@25467 293 SubDirectory equ 10h
pascal@25467 294 jnz SkipFindName
pascal@25467 295 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 296 SkipFindName:
pascal@25467 297 %endif
pascal@24476 298 pop di
pascal@24476 299 je FindNameFound
pascal@25450 300 %if NullEntryCheck != 0
pascal@25564 301 scasb ; Z == NC
pascal@25458 302 cmc
pascal@25458 303 lea di, [di+31]
pascal@25458 304 dec word [bx(bpbRootEntries)]
pascal@25458 305 ja FindNameCycle ; next root entry
pascal@25450 306 %else
pascal@25450 307 add di, byte 32
pascal@24476 308 dec word [bx(bpbRootEntries)]
pascal@24476 309 jnz FindNameCycle ; next root entry
pascal@25458 310 %endif
pascal@24476 311
pascal@24476 312 FindNameFailed:
pascal@24476 313 call Error
pascal@24476 314 db "File not found."
pascal@24476 315
pascal@24476 316 FindNameFound:
pascal@24476 317 push si
pascal@24476 318 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 319 les ax, [es:di+1Ch] ; file size
pascal@24476 320 mov dx, es
pascal@24476 321 div word [bx(bpbBytesPerSector)]
pascal@24476 322 cmp bx, dx ; sector aligned ?
pascal@24476 323 adc ax, bx ; file last sector
pascal@24476 324 pop di ; di = ClusterList
pascal@24476 325
pascal@24476 326 pop es ; ImageLoadSeg
pascal@24476 327 push ax
pascal@24476 328
pascal@24476 329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 330 ;; build cluster list ;;
pascal@24476 331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 332 ;; Input: ES:0 -> FAT ;;
pascal@24476 333 ;; SI = first cluster ;;
pascal@24476 334 ;; DI = cluster list :;
pascal@24476 335 ;; CH = 0 ;;
pascal@24476 336 ;; Output: SI = cluster list ;;
pascal@24476 337 ;; CH = 0 ;;
pascal@24476 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 339
pascal@25458 340 FAT12 equ 1
pascal@25458 341 FAT16 equ 1
pascal@25550 342 TINYFAT16 equ 1 ; < 4072 clusters fat16 support
pascal@25453 343 push di ; up to 2 * 635K / BytesPerCluster = 2540 bytes
pascal@25450 344 %if FAT12 == 1
pascal@25454 345 mov cl, 12
pascal@25564 346 %else
pascal@25564 347 nop
pascal@25564 348 nop
pascal@25450 349 %endif
pascal@24476 350 ClusterLoop:
pascal@24476 351 mov [di], si
pascal@25450 352 add si, si ; si = cluster * 2
pascal@25450 353 %if FAT16 == 1
pascal@24476 354 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@25094 355 jnc First64k
pascal@24476 356 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 357 First64k:
pascal@25453 358 %if FAT12 == 1
pascal@25457 359 mov dx, 0FFF6h
pascal@25454 360 %if TINYFAT16 == 1
pascal@25550 361 test [bx(bsFileSystem+4)], cl ; FAT12 or FAT16 ? clear C (bit 2)
pascal@25458 362 jne ReadClusterFat16
pascal@25454 363 %else
pascal@25454 364 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@25458 365 ja ReadClusterFat16
pascal@25454 366 %endif
pascal@24942 367 mov dh, 0Fh
pascal@25453 368 %endif
pascal@25450 369 %endif
pascal@25450 370 %if FAT12 == 1
pascal@25087 371 add si, [di]
pascal@24476 372 shr si, 1 ; si = cluster * 3 / 2
pascal@25564 373 %else
pascal@25564 374 nop
pascal@25564 375 nop
pascal@25450 376 %endif
pascal@25450 377 %if FAT16 == 1
pascal@24942 378 ReadClusterFat16:
pascal@25094 379 push ds
pascal@25087 380 mov ds, ax
pascal@24476 381 lodsw ; ax = next cluster
pascal@25094 382 pop ds
pascal@25450 383 %else
pascal@25453 384 es lodsw
pascal@25450 385 %endif
pascal@25450 386 %if FAT12 == 1
pascal@24476 387 jnc ReadClusterEven
pascal@25454 388 rol ax, cl
pascal@24476 389 ReadClusterEven:
pascal@25094 390 scasw ; di += 2
pascal@25454 391 %if FAT16 == 1
pascal@24942 392 and ah, dh ; mask cluster value
pascal@24942 393 cmp ax, dx
pascal@25454 394 %else
pascal@25453 395 and ah, 0Fh ; mask cluster value
pascal@25457 396 cmp ax, 0FF6h
pascal@25454 397 %endif
pascal@25454 398 %else
pascal@25454 399 scasw ; di += 2
pascal@25457 400 cmp ax, 0FFF6h
pascal@25453 401 %endif
pascal@24476 402 xchg ax, si
pascal@24476 403 jc ClusterLoop
pascal@24476 404 pop si
pascal@24476 405 pop di ; file size in sectors
pascal@24476 406
pascal@24476 407 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 408 ;; Load the entire file ;;
pascal@24476 409 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 410 ;; Input: ES:0 -> buffer ;;
pascal@24476 411 ;; SI = cluster list ;;
pascal@24476 412 ;; DI = file sectors ;;
pascal@24476 413 ;; CH = 0 ;;
pascal@24945 414 ;; BP = 1st data sec ;;
pascal@24476 415 ;; Output: BP:0 -> buffer ;;
pascal@24476 416 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 417
pascal@24476 418 push es
pascal@24476 419
pascal@24476 420 ReadClusters:
pascal@24476 421 lodsw
pascal@24476 422 dec ax
pascal@24476 423 dec ax
pascal@24476 424
pascal@25454 425 mov cl, [bx(bpbSectorsPerCluster)] ; 1..128
pascal@24476 426 mul cx ; cx = sector count (ch = 0)
pascal@24476 427
pascal@24476 428 add ax, bp ; LBA for cluster data
pascal@24476 429 adc dx, bx ; dx:ax = LBA
pascal@24476 430
pascal@25458 431 call ReadSectors ; clear ax, restore dx
pascal@24476 432
pascal@25458 433 jne ReadClusters ; until end of file
pascal@24476 434
pascal@24476 435 pop bp ; ImageLoadSeg
pascal@24476 436
pascal@24476 437 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 438 ;; Type detection, .COM or .EXE? ;;
pascal@24476 439 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 440
pascal@24476 441 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 442
pascal@24476 443 add bp, [bx+08h] ; bp = image base
pascal@24476 444 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 445
pascal@24476 446 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 447 je RelocateEXE ; yes, it's an EXE program
pascal@24476 448
pascal@24476 449 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 450 ;; Setup and run a .COM program ;;
pascal@24476 451 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 452 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 453 ;; cmdline=void ;;
pascal@24476 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 455
pascal@24942 456 mov di, 100h ; ip
pascal@24476 457 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 458 mov ss, bp
pascal@24476 459 xor sp, sp
pascal@24476 460 push bp ; cs, ds and es
pascal@24476 461 jmp short Run
pascal@24476 462
pascal@24476 463 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 464 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 465 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 466 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 467 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 468 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 469
pascal@24476 470 ReloCycle:
pascal@24476 471 add [di+2], bp ; item seg (abs)
pascal@24476 472 les si, [di] ; si = item ofs, es = item seg
pascal@24476 473 add [es:si], bp ; fixup
pascal@24476 474 scasw ; di += 2
pascal@24476 475 scasw ; point to next entry
pascal@24476 476
pascal@24476 477 RelocateEXE:
pascal@24942 478 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 479 jns ReloCycle
pascal@24476 480 ; PSP don't have a valid drive identifier
pascal@24476 481 les si, [bx+0Eh]
pascal@24476 482 add si, bp
pascal@24476 483 mov ss, si ; ss for EXE
pascal@24476 484 mov sp, es ; sp for EXE
pascal@24476 485
pascal@24476 486 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 487 push si ; containing the PSP structure
pascal@24476 488
pascal@24476 489 add bp, [bx+16h] ; cs for EXE
pascal@24942 490 mov di, [bx+14h] ; ip for EXE
pascal@24476 491 Run:
pascal@24476 492 pop ds
pascal@24476 493 push bp
pascal@24942 494 push di
pascal@24476 495 push ds
pascal@24476 496 pop es
pascal@24942 497 mov [80h], ax ; clear cmdline
pascal@24942 498 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 499
pascal@24476 500 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 501 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 502 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 503 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 504 mov si, 16381 ; prime number 2**14-3
pascal@24476 505 mov di, 32749 ; prime number 2**15-19
pascal@24476 506 mov bp, 65521 ; prime number 2**16-15
pascal@24476 507
pascal@24476 508 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 509 ;; All done, transfer control to the program now ;;
pascal@24476 510 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 511 retf
pascal@24476 512
pascal@25458 513 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 514 ;; Error Messaging Code ;;
pascal@25458 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 516
pascal@25458 517 Error:
pascal@25458 518 pop si
pascal@25458 519
pascal@25458 520 PutStr:
pascal@25458 521 mov ah, 0Eh
pascal@25458 522 mov bl, 7
pascal@25458 523 lodsb
pascal@25458 524 int 10h
pascal@25458 525 cmp al, "."
pascal@25458 526 jne PutStr
pascal@25564 527 %if WaitForKey != 0
pascal@25458 528 cbw
pascal@25458 529 int 16h ; wait for a key...
pascal@25458 530 int 19h ; bootstrap
pascal@25564 531 %endif
pascal@25458 532 Stop:
pascal@25458 533 hlt
pascal@25458 534 jmp short Stop
pascal@25458 535
pascal@25458 536 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 537 ;; Read sectors using BIOS Int 13h ;;
pascal@25458 538 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 539 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@25458 540 ;; BX = 0 ;;
pascal@25458 541 ;; DI = sector count ;;
pascal@25458 542 ;; ES:BX -> buffer address ;;
pascal@25458 543 ;; Output: ES:BX -> next address ;;
pascal@25458 544 ;; BX = 0 ;;
pascal@25458 545 ;; CX = 0 ;;
pascal@25458 546 ;; DI = 0 ;;
pascal@25458 547 ;; DL = drive number ;;
pascal@25564 548 ;; 0:BP = next LBA from FAT ;;
pascal@25458 549 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 550
pascal@25458 551 ReadDISectors:
pascal@25458 552 mov bp, di
pascal@24476 553 add bp, ax ; adjust LBA for cluster data
pascal@24476 554
pascal@25458 555 mov cx, di ; no cluster size limit
pascal@24476 556
pascal@24476 557 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 558 ;; Read sectors using BIOS Int 13h ;;
pascal@24476 559 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 560 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 561 ;; BX = 0 ;;
pascal@24476 562 ;; CX = sector count ;;
pascal@24476 563 ;; DI = file sectors ;;
pascal@24476 564 ;; ES:BX -> buffer address ;;
pascal@24476 565 ;; Output: ES:BX -> next address ;;
pascal@24476 566 ;; BX = 0 ;;
pascal@24476 567 ;; CX or DI = 0 ;;
pascal@24476 568 ;; DL = drive number ;;
pascal@25564 569 ;; Keep: BP, SI ;;
pascal@24476 570 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 571
pascal@25458 572 ReadSectors:
pascal@24476 573 add ax, [bx(bpbHiddenSectors)]
pascal@24476 574 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 575 add ax, [bx(bpbReservedSectors)]
pascal@24476 576
pascal@24476 577 push si
pascal@24476 578 ReadSectorNext:
pascal@24476 579 adc dx, bx
pascal@24476 580 push di
pascal@24476 581 push cx
pascal@24476 582
pascal@25450 583 %if LBAsupport != 0
pascal@24476 584 push bx
pascal@24476 585 push bx
pascal@25450 586 %endif
pascal@24476 587 push dx ; 32-bit LBA: up to 2TB
pascal@24476 588 push ax
pascal@24476 589 push es
pascal@25450 590 %if ReadRetry != 0 || LBAsupport != 0
pascal@25450 591 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 592 %endif
pascal@25450 593 %if LBAsupport != 0
pascal@24476 594 push bx
pascal@24476 595 inc bx ; sector count word = 1
pascal@24476 596 push bx
pascal@24476 597 dec bx
pascal@24476 598 push di
pascal@25450 599 %endif
pascal@24476 600
pascal@24476 601 xchg ax, cx ; save low LBA
pascal@24476 602 xchg ax, dx ; get high LBA
pascal@25452 603 cwd ; clear dx (LBA offset <1TB)
pascal@25450 604 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 605
pascal@25564 606 %if CHSsanityCheck != 0
pascal@25564 607 inc ax
pascal@25564 608 cmp ax, [bx(bpbHeadsPerCylinder)]
pascal@25564 609 ja CHSoverflow
pascal@25564 610 dec ax
pascal@25564 611 %endif
pascal@24476 612 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25450 613 idiv word [bx(bpbSectorsPerTrack)]
pascal@24476 614 ; ax = LBA / SPT
pascal@24476 615 ; dx = LBA % SPT = sector - 1
pascal@24476 616 inc dx
pascal@24476 617
pascal@24476 618 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25564 619 idiv word [bx(bpbHeadsPerCylinder)] ; may overflow if SectorsPerTrack * HeadsPerCylinder < 256 or disk > 8GB
pascal@24476 620 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 621 ; dx = (LBA / SPT) % HPC = head
pascal@25458 622
pascal@25458 623 xchg ch, al ; clear al
pascal@24476 624 ; ch = LSB 0...7 of cylinder no.
pascal@25458 625 shr ax, 1
pascal@25458 626 shr ax, 1
pascal@24476 627 or cl, al
pascal@24476 628 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 629 mov dh, dl
pascal@24476 630 ; dh = head no.
pascal@24476 631
pascal@25564 632 %if CHSsanityCheck != 0
pascal@25564 633 %if LBAsupport != 0
pascal@25564 634 or ah, [si+8+3] ; 8GB max, last cylinder 1023
pascal@25564 635 %else
pascal@25564 636 or ah, [si+2+3] ; 8GB max, last cylinder 1023
pascal@25564 637 %endif
pascal@25564 638 %endif
pascal@25564 639 CHSoverflow:
pascal@25450 640 mov dl, [bx(DriveNumber)]
pascal@24476 641 ; dl = drive no.
pascal@25450 642 mov si, sp
pascal@25564 643 %if CHSsanityCheck != 0
pascal@25564 644 %if ReadRetry != 0 || LBAsupport != 0
pascal@25564 645 pushf
pascal@25564 646 %endif
pascal@25564 647 %endif
pascal@25564 648
pascal@25564 649 ReadSectorRetry:
pascal@25450 650 %if LBAsupport != 0
pascal@24476 651 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 652 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 653 jnc ReadSectorNextSegment
pascal@25450 654 %endif
pascal@25564 655 %if CHSsanityCheck != 0
pascal@25564 656 %if ReadRetry != 0 || LBAsupport != 0
pascal@25564 657 popf
pascal@25564 658 pushf
pascal@25564 659 %endif
pascal@25564 660 jne SkipCHS
pascal@25564 661 %endif
pascal@24476 662
pascal@24476 663 mov ax, 201h ; al = sector count = 1
pascal@24476 664 ; ah = 2 = read function no.
pascal@24476 665 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 666
pascal@24476 667 jnc ReadSectorNextSegment
pascal@25564 668 SkipCHS:
pascal@25450 669 %if ReadRetry != 0
pascal@24476 670 cbw ; ah = 0 = reset function
pascal@24476 671 int 13h ; reset drive (DL)
pascal@24476 672
pascal@24476 673 dec di
pascal@25457 674 jnz ReadSectorRetry ; up to 15 extra attempt
pascal@25450 675 %endif
pascal@24476 676
pascal@25564 677 ReadError:
pascal@24476 678 call Error
pascal@24476 679 db "Read error."
pascal@24476 680
pascal@24476 681 ReadSectorNextSegment:
pascal@25564 682 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 683 popf
pascal@25564 684 %endif
pascal@25564 685
pascal@25564 686 %macro adjust_es 2
pascal@25564 687 %if SectorOf512Bytes != 0
pascal@25564 688 add word %1, byte 32 ; adjust segment for next sector
pascal@25564 689 %else
pascal@25564 690 %if %2 != 0
pascal@25564 691 mov al, %2
pascal@25564 692 %endif
pascal@25564 693 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25564 694 add %1, ax ; adjust segment for next sector
pascal@25564 695 %endif
pascal@25564 696 %endmacro
pascal@24476 697
pascal@25450 698 %if LBAsupport != 0
pascal@24476 699 pop ax ; al = 16
pascal@25564 700 adjust_es [si+6], 0
pascal@24476 701 pop cx ; sector count = 1
pascal@24476 702 pop bx
pascal@25450 703 %else
pascal@25564 704 adjust_es [si], 16
pascal@25450 705 %endif
pascal@24476 706 pop es ; es:0 updated
pascal@24476 707 pop ax
pascal@24476 708 pop dx
pascal@25450 709 %if LBAsupport != 0
pascal@24476 710 pop di
pascal@24476 711 pop di
pascal@24476 712 add ax, cx ; adjust LBA for next sector
pascal@25450 713 %else
pascal@25450 714 add ax, 1 ; adjust LBA for next sector
pascal@25450 715 %endif
pascal@24476 716
pascal@24476 717 pop cx ; cluster sectors to read
pascal@24476 718 pop di ; file sectors to read
pascal@24476 719 dec di ; keep C
pascal@25457 720 loopne ReadSectorNext ; until cluster sector count or file sector count
pascal@24476 721 pop si
pascal@24942 722 mov ax, bx ; clear ax
pascal@25450 723 mov dx, [bx(DriveNumber)] ; pass the BIOS boot drive to Run or Error
pascal@24476 724
pascal@24476 725 ret
pascal@24476 726
pascal@24942 727 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 728 ;; Fill free space with zeroes ;;
pascal@24942 729 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 730
pascal@25458 731 times (512-13-($-$$)) db 0
pascal@24476 732
pascal@24476 733 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 734 ;; Name of the file to load and run ;;
pascal@24476 735 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 736
pascal@25463 737 NameLength equ 11
pascal@25463 738 ProgramName times NameLength db 0 ; name and extension
pascal@24476 739
pascal@24476 740 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 741 ;; End of the sector ID ;;
pascal@24476 742 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 743
pascal@24476 744 ClusterList dw 0AA55h ; BIOS checks for this ID