wok annotate BootProg/stuff/boot32.asm @ rev 24491

Add some current_version
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri Feb 18 22:59:06 2022 +0000 (2022-02-18)
parents d211771a0500
children d77ab883a8b3
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24478 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24478 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@24478 51 ;; +------------------------+ A0000H - 512 - 2KB ;;
pascal@24478 52 ;; | 2KB Boot Stack | ;;
pascal@24478 53 ;; +------------------------+ A0000H - 512 ;;
pascal@24476 54 ;; | Boot Sector | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24476 61 ;; dl = BIOS boot drive number (e.g. 80H) ;;
pascal@24476 62 ;; cs:ip = program entry point ;;
pascal@24476 63 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 64 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 65 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 66 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24476 75 ;; ;;
pascal@24476 76 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 77
pascal@24491 78 %define bx(label) bx+label-boot
pascal@24491 79
pascal@24476 80 [BITS 16]
pascal@24476 81
pascal@24478 82 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@24476 83
pascal@24476 84 [SECTION .text]
pascal@24476 85 [ORG 0]
pascal@24476 86
pascal@24476 87 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 88 ;; Boot sector starts here ;;
pascal@24476 89 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 90
pascal@24491 91 boot:
pascal@24491 92 HiLBA equ boot+0
pascal@24476 93 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 94 nop
pascal@24476 95 bsOemName DB "BootProg" ; 0x03
pascal@24476 96
pascal@24476 97 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 98 ;; BPB1 starts here ;;
pascal@24476 99 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 100
pascal@24479 101 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 102 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 103 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 104 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 105 bpbRootEntries DW 0 ; 0x11
pascal@24479 106 bpbTotalSectors DW 0 ; 0x13
pascal@24479 107 bpbMedia DB 0 ; 0x15
pascal@24479 108 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 109 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 110 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 111 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 112 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 113
pascal@24476 114 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 115 ;; BPB1 ends here ;;
pascal@24476 116 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 117
pascal@24476 118 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 119 ;; BPB2 starts here ;;
pascal@24476 120 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 121
pascal@24479 122 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 123 bsExtendedFlags DW 0 ; 0x28
pascal@24479 124 bsFSVersion DW 0 ; 0x2A
pascal@24479 125 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 126 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 127 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 128 bsreserved times 12 DB 0 ; 0x34
pascal@24479 129 bsDriveNumber DB 0 ; 0x40
pascal@24479 130 bsreserved1 DB 0 ; 0x41
pascal@24479 131 bsExtendedBootSignature DB 0 ; 0x42
pascal@24479 132 bsVolumeSerialNumber DD 0 ; 0x43
pascal@24476 133 bsVolumeLabel DB "NO NAME " ; 0x47
pascal@24476 134 bsFileSystemName DB "FAT32 " ; 0x52
pascal@24476 135
pascal@24476 136 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 137 ;; BPB2 ends here ;;
pascal@24476 138 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 139
pascal@24476 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 141 ;; Boot sector code starts here ;;
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 143
pascal@24476 144 start:
pascal@24476 145 cld
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; How much RAM is there? ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 int 12h ; get conventional memory size (in KBs)
pascal@24478 152 shl ax, 6 ; and convert it to 16-byte paragraphs
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24478 158 sub ax, 512 / 16 ; reserve 512 bytes for the boot sector code
pascal@24478 159 mov es, ax ; es:0 -> top - 512
pascal@24478 160
pascal@24478 161 sub ax, 2048 / 16 ; reserve 2048 bytes for the stack
pascal@24478 162 mov ss, ax ; ss:0 -> top - 512 - 2048
pascal@24478 163 mov sp, 2048 ; 2048 bytes for the stack
pascal@24476 164
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 166 ;; Copy ourselves to top of memory ;;
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168
pascal@24478 169 mov cx, 256
pascal@24476 170 mov si, 7C00h
pascal@24476 171 xor di, di
pascal@24476 172 mov ds, di
pascal@24478 173 rep movsw
pascal@24476 174
pascal@24476 175 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 176 ;; Jump to the copy ;;
pascal@24476 177 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 178
pascal@24476 179 push es
pascal@24478 180 push byte main
pascal@24476 181 retf
pascal@24476 182
pascal@24476 183 main:
pascal@24476 184 push cs
pascal@24476 185 pop ds
pascal@24476 186
pascal@24491 187 xor bx, bx
pascal@24491 188 mov [bx(bsDriveNumber)], dx ; store BIOS boot drive number
pascal@24476 189
pascal@24491 190 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@24491 191 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 192
pascal@24476 193 RootDirReadContinue:
pascal@24478 194 push byte ImageLoadSeg
pascal@24478 195 pop es
pascal@24478 196 push es
pascal@24478 197 call ReadCluster ; read one cluster of root dir
pascal@24478 198 pop es
pascal@24478 199 pushad ; save esi=next cluster # of root dir
pascal@24478 200 ; save eax=next sector # of root dir
pascal@24478 201 pushf ; save carry="not last cluster" flag
pascal@24476 202
pascal@24476 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 204 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 206
pascal@24476 207 xor di, di ; es:di -> root entries array
pascal@24478 208 mov si, ProgramName ; ds:si -> program name
pascal@24476 209
pascal@24476 210 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 211 ;; Looks for a file/dir by its name ;;
pascal@24476 212 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 213 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 214 ;; ES:DI -> root directory array ;;
pascal@24478 215 ;; DX = number of root entries ;;
pascal@24476 216 ;; Output: ESI = cluster number ;;
pascal@24476 217 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 218
pascal@24478 219 FindName:
pascal@24478 220 mov cx, 11
pascal@24476 221 FindNameCycle:
pascal@24478 222 cmp byte [es:di], ch
pascal@24478 223 je ErrFind ; end of root directory (NULL entry found)
pascal@24478 224 FindNameNotEnd:
pascal@24478 225 pusha
pascal@24476 226 repe cmpsb
pascal@24478 227 popa
pascal@24476 228 je FindNameFound
pascal@24478 229 add di, 32
pascal@24476 230 dec bp
pascal@24476 231 dec bp
pascal@24476 232 jnz FindNameCycle ; next root entry
pascal@24478 233 popf ; restore carry="not last cluster" flag
pascal@24478 234 ; restore eax=next sector # of root dir
pascal@24478 235 popad ; restore esi=next cluster # of root dir
pascal@24476 236 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 237 ErrFind:
pascal@24478 238 call Error ; end of root directory (dir end reached)
pascal@24476 239 db "File not found."
pascal@24476 240 FindNameFound:
pascal@24478 241 push word [es:di+14h]
pascal@24478 242 push word [es:di+1Ah]
pascal@24478 243 pop esi ; esi = cluster no. cx = 0
pascal@24476 244
pascal@24476 245 dec dword [es:di+1Ch] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24478 246 imul di, [es:di+1Ch+1], 16 ; file size in paragraphs (full pages)
pascal@24478 247 xor cx, cx
pascal@24476 248
pascal@24476 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 250 ;; Load the entire file ;;
pascal@24476 251 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 252
pascal@24476 253 push es
pascal@24476 254 FileReadContinue:
pascal@24476 255 push di
pascal@24478 256 call ReadCluster ; read one cluster of root dir
pascal@24476 257 mov di, es
pascal@24478 258 add di, bp
pascal@24478 259 mov es, di ; es:bx updated
pascal@24476 260 pop di
pascal@24478 261
pascal@24476 262 sub di, bp
pascal@24476 263 jae FileReadContinue
pascal@24476 264 pop bp
pascal@24476 265
pascal@24476 266 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 267 ;; Type detection, .COM or .EXE? ;;
pascal@24476 268 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 269
pascal@24476 270 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 271 add bp, [bx+08h] ; bp = image base
pascal@24476 272 mov ax, [bx+06h] ; ax = reloc items
pascal@24476 273 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 274
pascal@24476 275 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24478 276
pascal@24476 277 je RelocateEXE ; yes, it's an EXE program
pascal@24476 278
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280 ;; Setup and run a .COM program ;;
pascal@24478 281 ;; Set CS=DS=ES=SP SP=0 IP=100h ;;
pascal@24476 282 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 283
pascal@24476 284 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 285 mov ss, bp
pascal@24476 286 xor sp, sp
pascal@24476 287 push bp ; cs, ds and es
pascal@24476 288 mov bh, 1 ; ip
pascal@24476 289 jmp short Run
pascal@24476 290
pascal@24476 291 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 292 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 293 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 294 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24476 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 296
pascal@24476 297 ReloCycle:
pascal@24476 298 add [di+2], bp ; item seg (abs)
pascal@24476 299 les si, [di] ; si = item ofs, es = item seg
pascal@24476 300 add [es:si], bp ; fixup
pascal@24478 301 add di, 4 ; point to next entry
pascal@24476 302
pascal@24476 303 RelocateEXE:
pascal@24476 304 dec ax ; 32768 max (128KB table)
pascal@24476 305 jns ReloCycle ; leave with ax=0ffffh: both FCB in the
pascal@24476 306 ; PSP don't have a valid drive identifier
pascal@24476 307 les si, [bx+0Eh]
pascal@24476 308 add si, bp
pascal@24476 309 mov ss, si ; ss for EXE
pascal@24476 310 mov sp, es ; sp for EXE
pascal@24476 311
pascal@24476 312 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 313 push si ; containing the PSP structure
pascal@24476 314
pascal@24476 315 add bp, [bx+16h] ; cs for EXE
pascal@24476 316 mov bx, [bx+14h] ; ip for EXE
pascal@24476 317 Run:
pascal@24476 318 pop ds
pascal@24476 319 push bp
pascal@24476 320 push bx
pascal@24476 321 push ds
pascal@24476 322 pop es
pascal@24476 323
pascal@24476 324 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 325 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 326 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 327 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 328 mov si, 16381 ; prime number 2**14-3
pascal@24476 329 mov di, 32749 ; prime number 2**15-19
pascal@24476 330 mov bp, 65521 ; prime number 2**16-15
pascal@24476 331
pascal@24476 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 333 ;; All done, transfer control to the program now ;;
pascal@24476 334 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 335 retf
pascal@24476 336
pascal@24478 337 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 338 ;; Reads a FAT32 cluster ;;
pascal@24478 339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 340 ;; Inout: ES:BX -> buffer ;;
pascal@24478 341 ;; ESI = cluster no ;;
pascal@24478 342 ;; Output: ESI = next cluster ;;
pascal@24478 343 ;; ES:BX -> next addr ;;
pascal@24478 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 345
pascal@24476 346 ReadCluster:
pascal@24476 347 inc cx
pascal@24478 348 loop ReadSectorLBA
pascal@24476 349
pascal@24478 350 mov ax, [bpbBytesPerSector]
pascal@24478 351 push ax
pascal@24478 352 shr ax, 2 ; ax=# of FAT32 entries per sector
pascal@24478 353 cwde
pascal@24478 354 lea ebp, [esi-2] ; esi=cluster #
pascal@24476 355 xchg eax, esi
pascal@24476 356 cdq
pascal@24478 357 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 358
pascal@24478 359 imul si, dx, 4 ; si=entry # in sector
pascal@24491 360 mov word [bx(HiLBA)], bx
pascal@24478 361 call ReadSectorLBAabsolute ; read 1 FAT32 sector
pascal@24476 362
pascal@24478 363 and byte [es:si+3], 0Fh ; mask cluster value
pascal@24478 364 mov esi, [es:si] ; esi=next cluster #
pascal@24476 365
pascal@24478 366 xchg eax, ebp
pascal@24491 367 movzx ecx, byte [bx(bpbSectorsPerCluster)]
pascal@24491 368 mul ecx ; edx:eax=sector number in data area
pascal@24478 369 xchg eax, ebp
pascal@24491 370 mov word [bx(HiLBA)], dx
pascal@24476 371
pascal@24491 372 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24491 373 mul dword [bx(bsSectorsPerFAT32)]
pascal@24476 374
pascal@24478 375 add eax, ebp
pascal@24491 376 adc word [bx(HiLBA)], dx
pascal@24476 377
pascal@24478 378 pop bp ; [bpbBytesPerSector]
pascal@24478 379 shr bp, 4 ; bp = paragraphs per sector
pascal@24476 380
pascal@24478 381 ReadSectorLBAabsolute:
pascal@24491 382 movzx edx, word [bx(bpbReservedSectors)]
pascal@24478 383 add eax, edx
pascal@24491 384 adc word [bx(HiLBA)], bx
pascal@24491 385 add eax, [bx(bpbHiddenSectors)]
pascal@24491 386 adc word [bx(HiLBA)], bx
pascal@24476 387
pascal@24478 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 389 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 390 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 391 ;; Input: EAX = LBA ;;
pascal@24478 392 ;; CX = sector count ;;
pascal@24478 393 ;; ES:BX -> buffer address ;;
pascal@24478 394 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 395 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 396
pascal@24476 397 ReadSectorLBA:
pascal@24491 398 mov dx, [bx(bsDriveNumber)] ; restore BIOS boot drive number
pascal@24476 399 pusha
pascal@24476 400
pascal@24478 401 push bx
pascal@24491 402 push word [bx(HiLBA)] ; 48-bit LBA
pascal@24478 403 push eax
pascal@24476 404 push es
pascal@24476 405 push bx
pascal@24478 406 push byte 1 ; sector count word = 1
pascal@24478 407 mov cx, 16 ; retry count
pascal@24478 408 push cx ; packet size byte = 16, reserved byte = 0
pascal@24476 409
pascal@24478 410 ReadSectorRetry:
pascal@24478 411 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 412 mov si, sp
pascal@24478 413 push ss
pascal@24478 414 pop ds
pascal@24478 415 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 416 push cs
pascal@24478 417 pop ds
pascal@24478 418 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 419
pascal@24478 420 xor ax, ax ; ah = 0 = reset function
pascal@24476 421 int 13h ; reset drive (DL)
pascal@24476 422
pascal@24478 423 loop ReadSectorRetry ; extra attempt
pascal@24476 424 call Error
pascal@24476 425 db "Read error."
pascal@24476 426
pascal@24478 427 ReadSuccess:
pascal@24476 428
pascal@24476 429 popa ; sp += 16
pascal@24478 430
pascal@24478 431 popa
pascal@24478 432
pascal@24491 433 add eax, byte 1 ; adjust LBA for next sector
pascal@24491 434 adc word [bx(HiLBA)], bx
pascal@24478 435
pascal@24476 436 stc
pascal@24478 437 loop ReadSectorNext
pascal@24476 438
pascal@24478 439 cmp esi, 0FFFFFF8h ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 440
pascal@24478 441 ReadSectorNext:
pascal@24476 442 ret
pascal@24476 443
pascal@24476 444 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 445 ;; Error Messaging Code ;;
pascal@24476 446 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 447
pascal@24476 448 Error:
pascal@24476 449 pop si
pascal@24478 450 puts:
pascal@24476 451 mov ah, 0Eh
pascal@24476 452 mov bl, 7
pascal@24476 453 lodsb
pascal@24476 454 int 10h
pascal@24478 455 cmp al, '.'
pascal@24478 456 jne puts
pascal@24476 457 cbw
pascal@24476 458 int 16h ; wait for a key...
pascal@24476 459 int 19h ; bootstrap
pascal@24476 460
pascal@24476 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 462 ;; Fill free space with zeroes ;;
pascal@24476 463 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 464
pascal@24476 465 times (512-13-($-$$)) db 0
pascal@24476 466
pascal@24476 467 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 468 ;; Name of the file to load and run ;;
pascal@24476 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 470
pascal@24476 471 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 472 ; padded with spaces (11 bytes total)
pascal@24476 473
pascal@24476 474 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 475 ;; End of the sector ID ;;
pascal@24476 476 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 477
pascal@24476 478 dw 0AA55h ; BIOS checks for this ID