wok-current annotate BootProg/stuff/bootex.asm @ rev 25454

oldrunner: add apple2 keys mapping
author Pascal Bellard <pascal.bellard@slitaz.org>
date Thu Sep 22 07:58:57 2022 +0000 (21 months ago)
parents e3609bca2577
children ad0bc3efbf37
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@24476 51 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@24476 53 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24476 54 ;; | 1.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 61 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 62 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 63 ;; cs:ip = program entry point ;;
pascal@24476 64 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 65 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 66 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24945 75 ;; The command line contains no arguments. ;;
pascal@24476 76 ;; ;;
pascal@24476 77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 78
pascal@24476 79 %define bx(label) bx+label-boot
pascal@25450 80 %define si(label) si+label-boot
pascal@25450 81 NullEntryCheck equ 1 ; +3 bytes
pascal@25450 82 ReadRetry equ 1 ; +8 bytes
pascal@24476 83
pascal@24476 84 [BITS 16]
pascal@24476 85 [CPU 386]
pascal@24476 86
pascal@24476 87 ImageLoadSeg equ 60h
pascal@24476 88 StackSize equ 1536
pascal@24476 89
pascal@24476 90 [SECTION .text]
pascal@24476 91 [ORG 0]
pascal@24476 92
pascal@24476 93 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 94 ;; Boot sector starts here ;;
pascal@24476 95 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 96
pascal@24476 97 boot:
pascal@25450 98 DriveNumber:
pascal@24476 99 jmp short start ; Windows checks for this jump
pascal@24476 100 nop
pascal@24476 101 bsOemName DB "EXFAT " ; 0x03
pascal@24476 102 times 53 db 0 ; 0x0B
pascal@24476 103
pascal@24476 104 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 105 ;; BPB starts here ;;
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107
pascal@24479 108 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 109 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 110 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 111 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 112 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 113 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 114 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 115 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 116 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 117 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 118 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 119 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 120 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 121 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 122 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 123 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 124
pascal@24476 125 ;;;;;;;;;;;;;;;;;;;
pascal@24476 126 ;; BPB ends here ;;
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;
pascal@24476 128
pascal@24476 129 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 130 ;; Boot sector code starts here ;;
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 132
pascal@24476 133 start:
pascal@24476 134 cld
pascal@24476 135
pascal@24476 136 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 137 ;; How much RAM is there? ;;
pascal@24476 138 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 139
pascal@24476 140 int 12h ; get conventional memory size (in KBs)
pascal@24476 141 mov cx, 106h
pascal@24476 142 dec ax
pascal@24476 143 dec ax ; reserve 2K bytes for the code and the stack
pascal@24476 144 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 145
pascal@24476 146 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 147 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 149
pascal@24476 150 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 151 mov ss, ax
pascal@24476 152 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Copy ourselves to top of memory ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 mov si, 7C00h
pascal@24476 159 xor di, di
pascal@24476 160 mov ds, di
pascal@25450 161 push es
pascal@25450 162 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 163 rep movsw ; move 512 bytes (+ 12)
pascal@24476 164
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 166 ;; Jump to the copy ;;
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168
pascal@24942 169 push word main
pascal@24476 170 retf
pascal@24476 171
pascal@24476 172 main:
pascal@24476 173 push cs
pascal@24476 174 pop ds
pascal@24476 175
pascal@24476 176 xor ebx, ebx
pascal@24476 177
pascal@24476 178 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 179
pascal@24479 180 push byte ImageLoadSeg
pascal@24942 181 pop es ; cx = 0
pascal@24476 182
pascal@24476 183 RootDirReadContinue:
pascal@24476 184 call ReadCluster ; read one sector of root dir
pascal@24476 185 pushf ; save carry="not last sector" flag
pascal@24476 186
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190
pascal@25454 191 ; es:di -> root entries array
pascal@24476 192
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194 ;; Looks for the file/dir ProgramName ;;
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196 ;; Input: ES:DI -> root directory array ;;
pascal@24476 197 ;; Output: ESI = cluster number ;;
pascal@24476 198 ;; dword [bx+FileSize] file size ;;
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200
pascal@25450 201 CurNameSize equ 3 ; 1 byte
pascal@25450 202 StartCluster equ 14h ; 4 bytes
pascal@25450 203 FileSize equ 18h ; 8 bytes
pascal@24476 204
pascal@24476 205 FindNameCycle:
pascal@24476 206 pusha
pascal@24476 207
pascal@25450 208 %if NullEntryCheck != 0
pascal@24476 209 xor ax, ax
pascal@24476 210 or al, [es:di]
pascal@24476 211 je FindNameFailed
pascal@25450 212 %else
pascal@25450 213 movzx ax, byte [es:di]
pascal@25450 214 %endif
pascal@24476 215
pascal@24476 216 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 217 jne NotFileInfo
pascal@24476 218
pascal@24942 219 mov bl, 31
pascal@24476 220 CopyInfo:
pascal@24942 221 mov al, [es:di+bx]
pascal@24942 222 mov [bx], al
pascal@24476 223 dec bx
pascal@25450 224 jnz CopyInfo ; keep BIOS boot drive number
pascal@24476 225
pascal@24476 226 NotFileInfo:
pascal@24476 227 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 228 mov cx, NameLength+1
pascal@24476 229 mov si, ProgramName ; ds:si -> program name
pascal@24476 230 CheckName:
pascal@24476 231 scasw ; compare UTF-16
pascal@24476 232 lodsb ; with ASCII
pascal@24476 233 loope CheckName
pascal@24476 234 je FindNameFound ; cx = 0
pascal@24476 235 popa ; restore ax, cx, si, di
pascal@24476 236
pascal@24479 237 add di, byte 32
pascal@24945 238 cmp di, bp
pascal@24945 239 jne FindNameCycle ; next root entry
pascal@24476 240 popf ; restore carry="not last sector" flag
pascal@24476 241 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 242 FindNameFailed: ; end of root directory (dir end reached)
pascal@25454 243 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 244 call Error
pascal@24476 245 db "File not found."
pascal@24476 246 FindNameFound:
pascal@24476 247 mov esi, [bx+StartCluster]
pascal@24476 248
pascal@24476 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 250 ;; Load the entire file ;;
pascal@24476 251 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 252
pascal@24476 253 push es
pascal@24945 254 xor bp, bp
pascal@24476 255 FileReadContinue:
pascal@24476 256 shr bp, 4 ; bytes to paragraphs
pascal@24476 257 mov di, es
pascal@24476 258 add di, bp ; adjust segment for next sector
pascal@24476 259 mov es, di ; es:0 updated
pascal@24943 260 call ReadCluster ; read one more sector of the boot file
pascal@25450 261 sub [bx+FileSize], ebp ; max FileSize is < 640KB : check low 32 bits only
pascal@24476 262 ja FileReadContinue
pascal@25450 263 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25454 264 xchg ax, di
pascal@24476 265 pop bp
pascal@24476 266
pascal@24476 267 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 268 ;; Type detection, .COM or .EXE? ;;
pascal@24476 269 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 270
pascal@24476 271 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 272
pascal@24476 273 add bp, [bx+08h] ; bp = image base
pascal@24476 274 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 275
pascal@24476 276 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 277 je RelocateEXE ; yes, it's an EXE program
pascal@24476 278
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280 ;; Setup and run a .COM program ;;
pascal@24476 281 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 282 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 283 ;; cmdline=void ;;
pascal@24476 284 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 285
pascal@24525 286 mov di, 100h ; ip
pascal@24476 287 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 288 mov ss, bp
pascal@24476 289 xor sp, sp
pascal@24476 290 push bp ; cs, ds and es
pascal@24476 291 jmp short Run
pascal@24476 292
pascal@24476 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 294 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 295 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 296 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 297 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 298 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 299
pascal@24476 300 ReloCycle:
pascal@24476 301 add [di+2], bp ; item seg (abs)
pascal@24476 302 les si, [di] ; si = item ofs, es = item seg
pascal@24476 303 add [es:si], bp ; fixup
pascal@24476 304 scasw ; di += 2
pascal@24476 305 scasw ; point to next entry
pascal@24476 306
pascal@24476 307 RelocateEXE:
pascal@24942 308 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 309 jns ReloCycle
pascal@24942 310
pascal@24945 311 les si, [bx+0Eh]
pascal@24945 312 add si, bp
pascal@24945 313 mov ss, si ; ss for EXE
pascal@24945 314 mov sp, es ; sp for EXE
pascal@24476 315
pascal@24476 316 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 317 push si ; containing the PSP structure
pascal@24476 318
pascal@24476 319 add bp, [bx+16h] ; cs for EXE
pascal@24525 320 mov di, [bx+14h] ; ip for EXE
pascal@24476 321 Run:
pascal@24476 322 pop ds
pascal@24476 323 push bp
pascal@24525 324 push di
pascal@24476 325 push ds
pascal@24476 326 pop es
pascal@24942 327 mov [80h], ax ; clear cmdline
pascal@24942 328 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 329
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 332 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 333 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 334 mov si, 16381 ; prime number 2**14-3
pascal@24476 335 mov di, 32749 ; prime number 2**15-19
pascal@24476 336 mov bp, 65521 ; prime number 2**16-15
pascal@24476 337
pascal@24476 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 339 ;; All done, transfer control to the program now ;;
pascal@24476 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 341 retf
pascal@24476 342
pascal@24476 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 344 ;; Reads a exFAT cluster ;;
pascal@24476 345 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 346 ;; Input: EDX:EAX = LBA ;;
pascal@24476 347 ;; EBX = 0 ;;
pascal@24476 348 ;; CX = sector cnt ;;
pascal@24476 349 ;; ESI = cluster no ;;
pascal@24476 350 ;; ES:0 -> buffer adrs ;;
pascal@24476 351 ;; Output: EBX = 0 ;;
pascal@24476 352 ;; CX = next cnt ;;
pascal@24476 353 ;; EBP = bytes/sector;;
pascal@24476 354 ;; ES:0 -> next adrs ;;
pascal@24476 355 ;; C=0 for last sector ;;
pascal@24476 356 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 357
pascal@24476 358 ReadCluster:
pascal@24945 359 add eax, byte 1
pascal@24945 360
pascal@24476 361 inc cx ; jcxnz
pascal@24476 362 loop ReadSectorC
pascal@24476 363
pascal@24945 364 mul ebx ; edx:eax = 0
pascal@25452 365 mov cl, -2
pascal@25450 366 add cl, [bx(bpbSectorSizeBits)]
pascal@25450 367 bts ax, cx ; eax=# of exFAT entries per sector
pascal@24476 368 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 369 xchg eax, esi
pascal@24476 370 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 371
pascal@24525 372 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 373
pascal@24476 374 cdq
pascal@25452 375 add eax, [bx(bpbFatSectorStart)] ; sector # relative to exFAT
pascal@25454 376 call ReadSectorFAT ; read 1 exFAT sector, keep edx=0, set C
pascal@24476 377
pascal@24476 378 mov esi, [es:si] ; esi=next cluster #
pascal@24476 379
pascal@25450 380 mov dl, [bx(bpbSectorPerClusterBits)]
pascal@25452 381 xor ecx, ecx
pascal@25450 382 bts ecx, edx ; 10000h max (32MB cluster)
pascal@24476 383 xchg eax, edi ; get cluster #-2
pascal@24476 384 mul ecx
pascal@24476 385
pascal@24476 386 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 387 ReadSectorC:
pascal@25454 388 mov di, bx
pascal@25454 389 ReadSectorFAT:
pascal@24476 390 adc edx, ebx
pascal@24476 391
pascal@24476 392 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 393 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 394 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 395 ;; Input: EDX:EAX = LBA ;;
pascal@24476 396 ;; BX = 0 ;;
pascal@24476 397 ;; CX = sector count ;;
pascal@24476 398 ;; ES:0 -> buffer address ;;
pascal@24476 399 ;; Output: BX = 0 ;;
pascal@24476 400 ;; CX = next count ;;
pascal@24476 401 ;; EBP = bytes/sector ;;
pascal@24476 402 ;; ES:0 -> next address ;;
pascal@24476 403 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 404
pascal@24476 405 xor ebp, ebp
pascal@24476 406 inc bp
pascal@24476 407
pascal@24476 408 pushad
pascal@24476 409
pascal@24476 410 add eax, [bx(bpbSectorStart)]
pascal@24476 411 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 412
pascal@24476 413 push edx
pascal@24476 414 push eax
pascal@24476 415 push es
pascal@24476 416 push bx
pascal@24476 417 push bp ; sector count word = 1
pascal@25454 418 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 419 %if ReadRetry != 0
pascal@25454 420 pop cx
pascal@25454 421 push cx
pascal@24476 422 ReadSectorRetry:
pascal@25450 423 %endif
pascal@24476 424 mov si, sp
pascal@24476 425 mov ah, 42h ; ah = 42h = extended read function no.
pascal@25450 426 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 427 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 428
pascal@24476 429 jnc ReadSuccess
pascal@24476 430
pascal@25450 431 %if ReadRetry != 0
pascal@24476 432 xor ax, ax
pascal@24476 433 int 13h ; reset drive (DL)
pascal@24954 434 loop ReadSectorRetry ; up to 16 retries
pascal@25450 435 %endif
pascal@24476 436
pascal@24476 437 call Error
pascal@24476 438 db "Read error."
pascal@24476 439
pascal@24476 440 ReadSuccess:
pascal@24476 441 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 442 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@24476 443 popa ; sp += 16
pascal@24476 444 popad ; real registers
pascal@24476 445
pascal@24476 446 stc
pascal@24476 447 loop ReadSectorNext
pascal@24476 448
pascal@24479 449 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 450 ReadSectorNext:
pascal@24476 451 ret
pascal@24476 452
pascal@24942 453 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 454 ;; Fill free space with zeroes ;;
pascal@24942 455 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 456
pascal@24942 457 times (512-13-20-($-$$)) db 0
pascal@24942 458
pascal@24476 459 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 460 ;; Error Messaging Code ;;
pascal@24476 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 462
pascal@24476 463 Error:
pascal@24476 464 pop si
pascal@24478 465
pascal@24478 466 PutStr:
pascal@24476 467 mov ah, 0Eh
pascal@24476 468 mov bl, 7
pascal@24476 469 lodsb
pascal@24476 470 int 10h
pascal@24476 471 cmp al, "."
pascal@24476 472 jne PutStr
pascal@24476 473
pascal@24476 474 cbw
pascal@24476 475 int 16h ; wait for a key...
pascal@24476 476 int 19h ; bootstrap
pascal@24476 477
pascal@24476 478 Stop:
pascal@24476 479 hlt
pascal@24476 480 jmp short Stop
pascal@24476 481
pascal@24476 482 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 483 ;; Name of the file to load and run ;;
pascal@24476 484 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 485
pascal@24476 486 ProgramName db "startup.bin" ; name and extension
pascal@24476 487 NameLength equ $-ProgramName
pascal@24476 488
pascal@24476 489 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 490 ;; End of the sector ID ;;
pascal@24476 491 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 492
pascal@24476 493 dw 0AA55h ; BIOS checks for this ID