wok annotate BootProg/stuff/boot32.asm @ rev 24945

fix BootProg
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri Apr 22 16:00:56 2022 +0000 (2022-04-22)
parents 810e3d0a38f7
children 6023b31d568c
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24525 20 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 23 ;; ("File not found" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; Known Bugs: ;;
pascal@24476 29 ;; ~~~~~~~~~~~ ;;
pascal@24476 30 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 31 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; ;;
pascal@24476 34 ;; Memory Layout: ;;
pascal@24476 35 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 36 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 37 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 38 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 39 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; physical address ;;
pascal@24476 42 ;; +------------------------+ 00000H ;;
pascal@24476 43 ;; | Interrupt Vector Table | ;;
pascal@24476 44 ;; +------------------------+ 00400H ;;
pascal@24476 45 ;; | BIOS Data Area | ;;
pascal@24476 46 ;; +------------------------+ 00500H ;;
pascal@24476 47 ;; | PrtScr Status / Unused | ;;
pascal@24476 48 ;; +------------------------+ 00600H ;;
pascal@24476 49 ;; | Loaded Image | ;;
pascal@24476 50 ;; +------------------------+ nnnnnH ;;
pascal@24476 51 ;; | Available Memory | ;;
pascal@24525 52 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 53 ;; | Boot Sector | ;;
pascal@24525 54 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24525 55 ;; | 1.5KB Boot Stack | ;;
pascal@24476 56 ;; +------------------------+ A0000H ;;
pascal@24476 57 ;; | Video RAM | ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; ;;
pascal@24476 60 ;; Boot Image Startup (register values): ;;
pascal@24476 61 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 62 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24945 63 ;; bx = cx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 64 ;; cs:ip = program entry point ;;
pascal@24476 65 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 66 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 67 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 68 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 69 ;; Magic numbers: ;;
pascal@24476 70 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 71 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 72 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 73 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 74 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 75 ;; metal and MS-DOS programs. ;;
pascal@24945 76 ;; The command line contains no arguments. ;;
pascal@24476 77 ;; ;;
pascal@24476 78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 79
pascal@24491 80 %define bx(label) bx+label-boot
pascal@24491 81
pascal@24476 82 [BITS 16]
pascal@24476 83
pascal@24478 84 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@24525 85 StackSize equ 1536
pascal@24476 86
pascal@24476 87 [SECTION .text]
pascal@24476 88 [ORG 0]
pascal@24476 89
pascal@24476 90 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 91 ;; Boot sector starts here ;;
pascal@24476 92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 93
pascal@24491 94 boot:
pascal@24491 95 HiLBA equ boot+0
pascal@24476 96 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 97 nop
pascal@24476 98 bsOemName DB "BootProg" ; 0x03
pascal@24476 99
pascal@24476 100 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 101 ;; BPB1 starts here ;;
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103
pascal@24479 104 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 105 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 106 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 107 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 108 bpbRootEntries DW 0 ; 0x11
pascal@24479 109 bpbTotalSectors DW 0 ; 0x13
pascal@24479 110 bpbMedia DB 0 ; 0x15
pascal@24479 111 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 112 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 113 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 114 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 115 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 116
pascal@24476 117 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 118 ;; BPB1 ends here ;;
pascal@24476 119 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 120
pascal@24476 121 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 122 ;; BPB2 starts here ;;
pascal@24476 123 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 124
pascal@24479 125 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 126 bsExtendedFlags DW 0 ; 0x28
pascal@24479 127 bsFSVersion DW 0 ; 0x2A
pascal@24479 128 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 129 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 130 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 131 bsreserved times 12 DB 0 ; 0x34
pascal@24479 132 bsDriveNumber DB 0 ; 0x40
pascal@24479 133 bsreserved1 DB 0 ; 0x41
pascal@24479 134 bsExtendedBootSignature DB 0 ; 0x42
pascal@24479 135 bsVolumeSerialNumber DD 0 ; 0x43
pascal@24476 136 bsVolumeLabel DB "NO NAME " ; 0x47
pascal@24476 137 bsFileSystemName DB "FAT32 " ; 0x52
pascal@24476 138
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 140 ;; BPB2 ends here ;;
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 142
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 144 ;; Boot sector code starts here ;;
pascal@24476 145 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 146
pascal@24476 147 start:
pascal@24476 148 cld
pascal@24476 149
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 151 ;; How much RAM is there? ;;
pascal@24476 152 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 153
pascal@24476 154 int 12h ; get conventional memory size (in KBs)
pascal@24525 155 dec ax
pascal@24525 156 dec ax ; reserve 2K bytes for the code and the stack
pascal@24525 157 mov cx, 106h
pascal@24525 158 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 159
pascal@24476 160 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 161 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 162 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 163
pascal@24525 164 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24525 165 mov ss, ax
pascal@24525 166 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 167
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169 ;; Copy ourselves to top of memory ;;
pascal@24476 170 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 171
pascal@24476 172 mov si, 7C00h
pascal@24476 173 xor di, di
pascal@24476 174 mov ds, di
pascal@24478 175 rep movsw
pascal@24476 176
pascal@24476 177 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 178 ;; Jump to the copy ;;
pascal@24476 179 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 180
pascal@24476 181 push es
pascal@24478 182 push byte main
pascal@24476 183 retf
pascal@24476 184
pascal@24476 185 main:
pascal@24476 186 push cs
pascal@24476 187 pop ds
pascal@24476 188
pascal@24491 189 xor bx, bx
pascal@24491 190 mov [bx(bsDriveNumber)], dx ; store BIOS boot drive number
pascal@24476 191
pascal@24491 192 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@24491 193 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 194
pascal@24476 195 RootDirReadContinue:
pascal@24478 196 push byte ImageLoadSeg
pascal@24478 197 pop es
pascal@24478 198 call ReadCluster ; read one cluster of root dir
pascal@24478 199 pushf ; save carry="not last cluster" flag
pascal@24476 200
pascal@24476 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 202 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 204
pascal@24476 205 xor di, di ; es:di -> root entries array
pascal@24476 206
pascal@24476 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 208 ;; Looks for a file/dir by its name ;;
pascal@24476 209 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 210 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 211 ;; ES:DI -> root directory array ;;
pascal@24478 212 ;; DX = number of root entries ;;
pascal@24525 213 ;; BP = paragraphs in sector ;;
pascal@24476 214 ;; Output: ESI = cluster number ;;
pascal@24476 215 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 216
pascal@24478 217 FindName:
pascal@24476 218 FindNameCycle:
pascal@24525 219 cmp byte [es:di], bh
pascal@24478 220 je ErrFind ; end of root directory (NULL entry found)
pascal@24478 221 FindNameNotEnd:
pascal@24478 222 pusha
pascal@24525 223 mov cl, 11
pascal@24525 224 mov si, ProgramName ; ds:si -> program name
pascal@24476 225 repe cmpsb
pascal@24525 226 je FindNameFound
pascal@24478 227 popa
pascal@24525 228 add di, byte 32
pascal@24476 229 dec bp
pascal@24476 230 dec bp
pascal@24476 231 jnz FindNameCycle ; next root entry
pascal@24478 232 popf ; restore carry="not last cluster" flag
pascal@24476 233 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 234 ErrFind:
pascal@24478 235 call Error ; end of root directory (dir end reached)
pascal@24476 236 db "File not found."
pascal@24476 237 FindNameFound:
pascal@24525 238 push word [es:di+14h-11]
pascal@24525 239 push word [es:di+1Ah-11]
pascal@24478 240 pop esi ; esi = cluster no. cx = 0
pascal@24476 241
pascal@24525 242 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 243 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 244
pascal@24476 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 246 ;; Load the entire file ;;
pascal@24476 247 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 248
pascal@24476 249 push es
pascal@24476 250 FileReadContinue:
pascal@24476 251 push di
pascal@24478 252 call ReadCluster ; read one cluster of root dir
pascal@24476 253 mov di, es
pascal@24478 254 add di, bp
pascal@24478 255 mov es, di ; es:bx updated
pascal@24476 256 pop di
pascal@24478 257
pascal@24476 258 sub di, bp
pascal@24476 259 jae FileReadContinue
pascal@24943 260 xor ax, ax
pascal@24476 261 pop bp
pascal@24476 262
pascal@24476 263 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 264 ;; Type detection, .COM or .EXE? ;;
pascal@24476 265 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 266
pascal@24476 267 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 268
pascal@24476 269 add bp, [bx+08h] ; bp = image base
pascal@24476 270 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 271
pascal@24476 272 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 273 je RelocateEXE ; yes, it's an EXE program
pascal@24476 274
pascal@24476 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 276 ;; Setup and run a .COM program ;;
pascal@24535 277 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24535 278 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24942 279 ;; and cmdline=void ;;
pascal@24476 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 281
pascal@24535 282 mov di, 100h ; ip
pascal@24476 283 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 284 mov ss, bp
pascal@24476 285 xor sp, sp
pascal@24476 286 push bp ; cs, ds and es
pascal@24476 287 jmp short Run
pascal@24476 288
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 291 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 292 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24942 293 ;; AX=0ffffh BX=0 CX=0 DX=drive cmdline=void ;;
pascal@24476 294 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 295
pascal@24476 296 ReloCycle:
pascal@24476 297 add [di+2], bp ; item seg (abs)
pascal@24476 298 les si, [di] ; si = item ofs, es = item seg
pascal@24476 299 add [es:si], bp ; fixup
pascal@24525 300 scasw ; di += 2
pascal@24525 301 scasw ; point to next entry
pascal@24476 302
pascal@24476 303 RelocateEXE:
pascal@24942 304 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 305 jns ReloCycle
pascal@24942 306
pascal@24945 307 les si, [bx+0Eh]
pascal@24945 308 add si, bp
pascal@24945 309 mov ss, si ; ss for EXE
pascal@24945 310 mov sp, es ; sp for EXE
pascal@24476 311
pascal@24476 312 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 313 push si ; containing the PSP structure
pascal@24476 314
pascal@24476 315 add bp, [bx+16h] ; cs for EXE
pascal@24535 316 mov di, [bx+14h] ; ip for EXE
pascal@24476 317 Run:
pascal@24476 318 pop ds
pascal@24476 319 push bp
pascal@24535 320 push di
pascal@24476 321 push ds
pascal@24476 322 pop es
pascal@24942 323 mov [80h], ax ; clear cmdline
pascal@24942 324 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 325
pascal@24476 326 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 327 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 328 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 330 mov si, 16381 ; prime number 2**14-3
pascal@24476 331 mov di, 32749 ; prime number 2**15-19
pascal@24476 332 mov bp, 65521 ; prime number 2**16-15
pascal@24476 333
pascal@24476 334 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 335 ;; All done, transfer control to the program now ;;
pascal@24476 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 337 retf
pascal@24476 338
pascal@24525 339 ReadCluster:
pascal@24525 340 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 341 shr bp, 4 ; bp = paragraphs per sector
pascal@24945 342 add eax, byte 1 ; adjust LBA for next sector
pascal@24525 343 inc cx
pascal@24525 344 loop ReadSectorLBA
pascal@24525 345
pascal@24478 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 347 ;; Reads a FAT32 cluster ;;
pascal@24478 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 349 ;; Inout: ES:BX -> buffer ;;
pascal@24478 350 ;; ESI = cluster no ;;
pascal@24478 351 ;; Output: ESI = next cluster ;;
pascal@24525 352 ;; BP -> para / sector ;;
pascal@24478 353 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 354
pascal@24945 355 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@24478 356 cwde
pascal@24525 357 lea edi, [esi-2] ; esi=cluster #
pascal@24476 358 xchg eax, esi
pascal@24476 359 cdq
pascal@24478 360 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 361
pascal@24525 362 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@24491 363 mov word [bx(HiLBA)], bx
pascal@24478 364 call ReadSectorLBAabsolute ; read 1 FAT32 sector
pascal@24476 365
pascal@24478 366 and byte [es:si+3], 0Fh ; mask cluster value
pascal@24478 367 mov esi, [es:si] ; esi=next cluster #
pascal@24476 368
pascal@24525 369 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 370 mul dword [bx(bsSectorsPerFAT32)]
pascal@24525 371 mov word [bx(HiLBA)], dx
pascal@24525 372
pascal@24525 373 xchg eax, edi
pascal@24491 374 movzx ecx, byte [bx(bpbSectorsPerCluster)]
pascal@24945 375 mul ecx ; edx:eax=sector number in data area
pascal@24476 376
pascal@24525 377 add eax, edi
pascal@24491 378 adc word [bx(HiLBA)], dx
pascal@24476 379
pascal@24478 380 ReadSectorLBAabsolute:
pascal@24525 381 mov dx, word [bx(bpbReservedSectors)]
pascal@24478 382 add eax, edx
pascal@24491 383 adc word [bx(HiLBA)], bx
pascal@24491 384 add eax, [bx(bpbHiddenSectors)]
pascal@24476 385
pascal@24478 386 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 387 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 389 ;; Input: EAX = LBA ;;
pascal@24478 390 ;; CX = sector count ;;
pascal@24478 391 ;; ES:BX -> buffer address ;;
pascal@24478 392 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 393 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 394
pascal@24476 395 ReadSectorLBA:
pascal@24535 396 adc word [bx(HiLBA)], bx
pascal@24535 397 mov dx, [bx(bsDriveNumber)] ; restore BIOS boot drive number
pascal@24476 398 pusha
pascal@24476 399
pascal@24478 400 push bx
pascal@24491 401 push word [bx(HiLBA)] ; 48-bit LBA
pascal@24478 402 push eax
pascal@24476 403 push es
pascal@24476 404 push bx
pascal@24478 405 push byte 1 ; sector count word = 1
pascal@24525 406 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 407
pascal@24525 408 ReadSectorLBARetry:
pascal@24525 409 mov si, sp
pascal@24478 410 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 411 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 412 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 413
pascal@24945 414 xor ax, ax ; ah = 0 = reset function
pascal@24476 415 int 13h ; reset drive (DL)
pascal@24476 416
pascal@24525 417 dec bp
pascal@24525 418 jnz ReadSectorLBARetry
pascal@24525 419
pascal@24476 420 call Error
pascal@24476 421 db "Read error."
pascal@24476 422
pascal@24478 423 ReadSuccess:
pascal@24476 424
pascal@24476 425 popa ; sp += 16
pascal@24478 426
pascal@24478 427 popa
pascal@24478 428
pascal@24476 429 stc
pascal@24478 430 loop ReadSectorNext
pascal@24476 431
pascal@24478 432 cmp esi, 0FFFFFF8h ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 433
pascal@24478 434 ReadSectorNext:
pascal@24476 435 ret
pascal@24476 436
pascal@24942 437 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 438 ;; Fill free space with zeroes ;;
pascal@24942 439 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 440
pascal@24942 441 times (512-13-20-($-$$)) db 0
pascal@24942 442
pascal@24476 443 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 444 ;; Error Messaging Code ;;
pascal@24476 445 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 446
pascal@24476 447 Error:
pascal@24476 448 pop si
pascal@24478 449 puts:
pascal@24476 450 mov ah, 0Eh
pascal@24476 451 mov bl, 7
pascal@24476 452 lodsb
pascal@24476 453 int 10h
pascal@24478 454 cmp al, '.'
pascal@24478 455 jne puts
pascal@24476 456 cbw
pascal@24535 457 int 16h ; wait for a key...
pascal@24535 458 int 19h ; bootstrap
pascal@24525 459
pascal@24525 460 Stop:
pascal@24525 461 hlt
pascal@24525 462 jmp short Stop
pascal@24476 463
pascal@24476 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 465 ;; Name of the file to load and run ;;
pascal@24476 466 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 467
pascal@24476 468 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@24476 469 ; padded with spaces (11 bytes total)
pascal@24476 470
pascal@24476 471 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 472 ;; End of the sector ID ;;
pascal@24476 473 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 474
pascal@24476 475 dw 0AA55h ; BIOS checks for this ID