wok annotate BootProg/stuff/boot16.asm @ rev 25569

BootProg: fix boot16.asm
author Pascal Bellard <pascal.bellard@slitaz.org>
date Fri May 12 21:35:09 2023 +0000 (13 months ago)
parents 3c71bb4367c3
children 82f370bad6b5
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@25569 14 ;; - FAT12 and/or FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; - cpu 8086 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@25564 29 ;; Known Limitation: ;;
pascal@25564 30 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 31 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 32 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 33 ;; ;;
pascal@25569 34 ;; - Partition must fit in the first 8GB disk of the for CHS reads. ;;
pascal@25569 35 ;; (or 2TB for LBA reads). ;;
pascal@25564 36 ;; ;;
pascal@25564 37 ;; ;;
pascal@24476 38 ;; Known Bugs: ;;
pascal@24476 39 ;; ~~~~~~~~~~~ ;;
pascal@24476 40 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 41 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 42 ;; - 360KB 5"25 ;;
pascal@24476 43 ;; - 1.2MB 5"25 ;;
pascal@24476 44 ;; - 1.44MB 3"5 ;;
pascal@24476 45 ;; on my HDD (FAT16). ;;
pascal@24476 46 ;; ;;
pascal@24476 47 ;; ;;
pascal@24476 48 ;; Memory Layout: ;;
pascal@24476 49 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 50 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 51 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 52 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 53 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 54 ;; ;;
pascal@24476 55 ;; physical address ;;
pascal@24476 56 ;; +------------------------+ 00000H ;;
pascal@24476 57 ;; | Interrupt Vector Table | ;;
pascal@24476 58 ;; +------------------------+ 00400H ;;
pascal@24476 59 ;; | BIOS Data Area | ;;
pascal@24476 60 ;; +------------------------+ 00500H ;;
pascal@24476 61 ;; | PrtScr Status / Unused | ;;
pascal@24476 62 ;; +------------------------+ 00600H ;;
pascal@24476 63 ;; | Loaded Image | ;;
pascal@24476 64 ;; +------------------------+ nnnnnH ;;
pascal@24476 65 ;; | Available Memory | ;;
pascal@24476 66 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 67 ;; | Boot Sector | ;;
pascal@24476 68 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 69 ;; | 3KB Boot Stack | ;;
pascal@24476 70 ;; +------------------------+ A0000H ;;
pascal@24476 71 ;; | Video RAM | ;;
pascal@24476 72 ;; ;;
pascal@24476 73 ;; ;;
pascal@24476 74 ;; Boot Image Startup (register values): ;;
pascal@24476 75 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 76 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 77 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 78 ;; cs:ip = program entry point ;;
pascal@24476 79 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 80 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 81 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 82 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 83 ;; Magic numbers: ;;
pascal@24476 84 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 85 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 86 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 87 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 88 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 89 ;; metal and MS-DOS programs. ;;
pascal@24945 90 ;; The command line contains no arguments. ;;
pascal@24476 91 ;; ;;
pascal@24476 92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 93
pascal@24476 94 %define bx(label) bx+label-boot
pascal@25450 95 %define si(label) si+label-boot
pascal@25458 96 NullEntryCheck equ 1 ; +2 bytes
pascal@25569 97 ReadRetry equ 1 ; +9/+13 bytes
pascal@25569 98 LBAsupport equ 1 ; +18 bytes
pascal@25564 99 CHSsanityCheck equ 1 ; +12/+16 bytes
pascal@25569 100 GeometryCheck equ 1 ; +20 bytes
pascal@25564 101 CheckAttrib equ 0 ; +6 bytes
pascal@25564 102 WaitForKey equ 0 ; +5 bytes
pascal@25550 103 SectorOf512Bytes equ 0 ; -4/-6 bytes
pascal@25564 104 Always2FATs equ 0 ; -1 bytes
pascal@24476 105
pascal@24476 106 [BITS 16]
pascal@24476 107 [CPU 8086]
pascal@24476 108
pascal@24476 109 ImageLoadSeg equ 60h
pascal@24476 110 StackSize equ 3072 ; Stack + cluster list
pascal@24476 111
pascal@24476 112 [SECTION .text]
pascal@24476 113 [ORG 0]
pascal@24476 114
pascal@24476 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 116 ;; Boot sector starts here ;;
pascal@24476 117 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 118
pascal@24476 119 boot:
pascal@25450 120 DriveNumber:
pascal@24476 121 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 122 nop
pascal@24476 123 bsOemName DB "BootProg" ; 0x03
pascal@24476 124
pascal@24476 125 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 126 ;; BPB starts here ;;
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 128
pascal@25564 129 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 130 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32 or 64
pascal@25564 131 bpbReservedSectors DW 0 ; 0x0E 1
pascal@25564 132 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@24479 133 bpbRootEntries DW 0 ; 0x11
pascal@24479 134 bpbTotalSectors DW 0 ; 0x13
pascal@24479 135 bpbMedia DB 0 ; 0x15
pascal@24479 136 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 137 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 138 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 139 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 140 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 141
pascal@24476 142 ;;;;;;;;;;;;;;;;;;;
pascal@24476 143 ;; BPB ends here ;;
pascal@24476 144 ;;;;;;;;;;;;;;;;;;;
pascal@24476 145
pascal@24479 146 bsDriveNumber DB 0 ; 0x24
pascal@24479 147 bsUnused DB 0 ; 0x25
pascal@25564 148 bsExtBootSignature DB 0 ; 0x26 29
pascal@24479 149 bsSerialNumber DD 0 ; 0x27
pascal@25458 150 bsVolumeLabel times 11 DB " " ; 0x2B "NO NAME "
pascal@25458 151 bsFileSystem times 8 DB " " ; 0x36 "FAT12 " or "FAT16 "
pascal@24476 152
pascal@24476 153 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 154 ;; Boot sector code starts here ;;
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156
pascal@24476 157 start:
pascal@24476 158 cld
pascal@24476 159
pascal@24476 160 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 161 ;; How much RAM is there? ;;
pascal@24476 162 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 163
pascal@24476 164 int 12h ; get conventional memory size (in KBs)
pascal@24476 165 mov cx, 106h
pascal@24476 166 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 167
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 170 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 171
pascal@24476 172 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 173 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 174 mov ss, ax
pascal@24476 175 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 176
pascal@24476 177 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 178 ;; Copy ourselves to top of memory ;;
pascal@24476 179 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 180
pascal@24476 181 mov si, 7C00h
pascal@24476 182 xor di, di
pascal@24476 183 mov ds, di
pascal@25450 184 push es
pascal@25450 185 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 186 rep movsw ; move 512 bytes (+ 12)
pascal@24476 187
pascal@24476 188 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 189 ;; Jump to the copy ;;
pascal@24476 190 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 191
pascal@24476 192 mov cl, byte main
pascal@24476 193 push cx
pascal@24476 194 retf
pascal@24476 195
pascal@24476 196 main:
pascal@24476 197 %if ImageLoadSeg != main-boot
pascal@24476 198 %if ImageLoadSeg >= 100h
pascal@24476 199 mov cx, ImageLoadSeg
pascal@24476 200 %else
pascal@24476 201 mov cl, ImageLoadSeg
pascal@24476 202 %endif
pascal@24476 203 %endif
pascal@24476 204 push cx
pascal@24476 205
pascal@24476 206 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 207 ;; Get drive parameters ;;
pascal@24476 208 ;; Update heads count ;;
pascal@24476 209 ;; for current BIOS ;;
pascal@24476 210 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 211
pascal@25450 212 %if GeometryCheck != 0
pascal@25564 213 %if ((main-boot) & 3Fh) != 0
pascal@25569 214 xor cx, cx
pascal@25564 215 %endif
pascal@25564 216 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 217 int 13h ; may destroy SI,BP, and DS registers
pascal@25450 218 %endif
pascal@24476 219 push cs
pascal@24476 220 pop ds
pascal@24476 221 xor bx, bx
pascal@24476 222
pascal@25450 223 %if GeometryCheck != 0
pascal@24479 224 and cx, byte 3Fh
pascal@25564 225 je BadParams ; verify updated and validity
pascal@25564 226 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 227 mov cl, dh
pascal@25564 228 inc cx
pascal@25564 229 mov [bx(bpbHeadsPerCylinder)], cx
pascal@24476 230 BadParams:
pascal@25450 231 %endif
pascal@24476 232
pascal@24476 233 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 234 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 235 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 236
pascal@24476 237 pop es ; ImageLoadSeg
pascal@24476 238 push es
pascal@24476 239
pascal@24476 240 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@25458 241 mov di, word [bx(bpbSectorsPerFAT)]
pascal@24476 242
pascal@25458 243 call ReadDISectors ; read fat; clear ax, cx, di; bp = SectorsPerFAT
pascal@24476 244
pascal@24476 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 246 ;; load the root directory in ;;
pascal@24476 247 ;; its entirety (16KB max) ;;
pascal@24476 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 249
pascal@25458 250 %if SectorOf512Bytes != 0
pascal@25458 251 mov di, word [bx(bpbRootEntries)]
pascal@25458 252 mov cl, 4
pascal@25458 253 shr di, cl ; di = root directory size in sectors
pascal@25458 254 %else
pascal@24942 255 mov al, 32
pascal@24476 256
pascal@24476 257 mul word [bx(bpbRootEntries)]
pascal@24476 258 div word [bx(bpbBytesPerSector)]
pascal@25458 259 xchg ax, di ; di = root directory size in sectors, clear ah
pascal@25458 260 %endif
pascal@24476 261
pascal@25564 262 %if Always2FATs != 0
pascal@25564 263 mov al, 2
pascal@25564 264 %else
pascal@24476 265 mov al, [bpbNumberOfFATs]
pascal@25564 266 %endif
pascal@25458 267 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadDISectors
pascal@24476 268
pascal@25457 269 push es ; read root directory
pascal@25458 270 call ReadDISectors ; clear ax, cx, di; bp = first data sector
pascal@24476 271 pop es
pascal@24476 272
pascal@24476 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 274 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 276
pascal@24476 277 ; es:di -> root entries array
pascal@24476 278
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280 ;; Looks for the file/dir ProgramName ;;
pascal@24476 281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 282 ;; Input: ES:DI -> root directory array ;;
pascal@24476 283 ;; Output: SI = cluster number ;;
pascal@24476 284 ;; AX = file sector count ;;
pascal@24476 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 286
pascal@24476 287 FindNameCycle:
pascal@24476 288 push di
pascal@25454 289 mov cl, NameLength
pascal@24476 290 mov si, ProgramName ; ds:si -> program name
pascal@24476 291 repe cmpsb
pascal@25467 292 %if CheckAttrib != 0
pascal@25467 293 VolumeLabel equ 8
pascal@25467 294 SubDirectory equ 10h
pascal@25467 295 jnz SkipFindName
pascal@25467 296 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 297 SkipFindName:
pascal@25467 298 %endif
pascal@24476 299 pop di
pascal@24476 300 je FindNameFound
pascal@25450 301 %if NullEntryCheck != 0
pascal@25564 302 scasb ; Z == NC
pascal@25458 303 cmc
pascal@25458 304 lea di, [di+31]
pascal@25458 305 dec word [bx(bpbRootEntries)]
pascal@25458 306 ja FindNameCycle ; next root entry
pascal@25450 307 %else
pascal@25450 308 add di, byte 32
pascal@24476 309 dec word [bx(bpbRootEntries)]
pascal@24476 310 jnz FindNameCycle ; next root entry
pascal@25458 311 %endif
pascal@24476 312
pascal@24476 313 FindNameFailed:
pascal@24476 314 call Error
pascal@24476 315 db "File not found."
pascal@24476 316
pascal@24476 317 FindNameFound:
pascal@24476 318 push si
pascal@24476 319 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 320 les ax, [es:di+1Ch] ; file size
pascal@24476 321 mov dx, es
pascal@24476 322 div word [bx(bpbBytesPerSector)]
pascal@24476 323 cmp bx, dx ; sector aligned ?
pascal@24476 324 adc ax, bx ; file last sector
pascal@24476 325 pop di ; di = ClusterList
pascal@24476 326
pascal@24476 327 pop es ; ImageLoadSeg
pascal@24476 328 push ax
pascal@24476 329
pascal@24476 330 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 331 ;; build cluster list ;;
pascal@24476 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 333 ;; Input: ES:0 -> FAT ;;
pascal@24476 334 ;; SI = first cluster ;;
pascal@24476 335 ;; DI = cluster list :;
pascal@24476 336 ;; CH = 0 ;;
pascal@24476 337 ;; Output: SI = cluster list ;;
pascal@24476 338 ;; CH = 0 ;;
pascal@24476 339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 340
pascal@25458 341 FAT12 equ 1
pascal@25458 342 FAT16 equ 1
pascal@25550 343 TINYFAT16 equ 1 ; < 4072 clusters fat16 support
pascal@25453 344 push di ; up to 2 * 635K / BytesPerCluster = 2540 bytes
pascal@25450 345 %if FAT12 == 1
pascal@25454 346 mov cl, 12
pascal@25564 347 %else
pascal@25564 348 nop
pascal@25564 349 nop
pascal@25450 350 %endif
pascal@24476 351 ClusterLoop:
pascal@24476 352 mov [di], si
pascal@25450 353 add si, si ; si = cluster * 2
pascal@25450 354 %if FAT16 == 1
pascal@24476 355 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@25094 356 jnc First64k
pascal@24476 357 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 358 First64k:
pascal@25453 359 %if FAT12 == 1
pascal@25457 360 mov dx, 0FFF6h
pascal@25454 361 %if TINYFAT16 == 1
pascal@25550 362 test [bx(bsFileSystem+4)], cl ; FAT12 or FAT16 ? clear C (bit 2)
pascal@25458 363 jne ReadClusterFat16
pascal@25454 364 %else
pascal@25454 365 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@25458 366 ja ReadClusterFat16
pascal@25454 367 %endif
pascal@24942 368 mov dh, 0Fh
pascal@25453 369 %endif
pascal@25450 370 %endif
pascal@25450 371 %if FAT12 == 1
pascal@25087 372 add si, [di]
pascal@24476 373 shr si, 1 ; si = cluster * 3 / 2
pascal@25564 374 %else
pascal@25564 375 nop
pascal@25564 376 nop
pascal@25450 377 %endif
pascal@25450 378 %if FAT16 == 1
pascal@24942 379 ReadClusterFat16:
pascal@25094 380 push ds
pascal@25087 381 mov ds, ax
pascal@24476 382 lodsw ; ax = next cluster
pascal@25094 383 pop ds
pascal@25450 384 %else
pascal@25453 385 es lodsw
pascal@25450 386 %endif
pascal@25450 387 %if FAT12 == 1
pascal@24476 388 jnc ReadClusterEven
pascal@25454 389 rol ax, cl
pascal@24476 390 ReadClusterEven:
pascal@25094 391 scasw ; di += 2
pascal@25454 392 %if FAT16 == 1
pascal@24942 393 and ah, dh ; mask cluster value
pascal@24942 394 cmp ax, dx
pascal@25454 395 %else
pascal@25453 396 and ah, 0Fh ; mask cluster value
pascal@25457 397 cmp ax, 0FF6h
pascal@25454 398 %endif
pascal@25454 399 %else
pascal@25454 400 scasw ; di += 2
pascal@25457 401 cmp ax, 0FFF6h
pascal@25453 402 %endif
pascal@24476 403 xchg ax, si
pascal@24476 404 jc ClusterLoop
pascal@24476 405 pop si
pascal@24476 406 pop di ; file size in sectors
pascal@24476 407
pascal@24476 408 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 409 ;; Load the entire file ;;
pascal@24476 410 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 411 ;; Input: ES:0 -> buffer ;;
pascal@24476 412 ;; SI = cluster list ;;
pascal@24476 413 ;; DI = file sectors ;;
pascal@24476 414 ;; CH = 0 ;;
pascal@24945 415 ;; BP = 1st data sec ;;
pascal@24476 416 ;; Output: BP:0 -> buffer ;;
pascal@24476 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 418
pascal@24476 419 push es
pascal@24476 420
pascal@24476 421 ReadClusters:
pascal@24476 422 lodsw
pascal@24476 423 dec ax
pascal@24476 424 dec ax
pascal@24476 425
pascal@25454 426 mov cl, [bx(bpbSectorsPerCluster)] ; 1..128
pascal@24476 427 mul cx ; cx = sector count (ch = 0)
pascal@24476 428
pascal@24476 429 add ax, bp ; LBA for cluster data
pascal@24476 430 adc dx, bx ; dx:ax = LBA
pascal@24476 431
pascal@25458 432 call ReadSectors ; clear ax, restore dx
pascal@24476 433
pascal@25458 434 jne ReadClusters ; until end of file
pascal@24476 435
pascal@24476 436 pop bp ; ImageLoadSeg
pascal@24476 437
pascal@24476 438 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 439 ;; Type detection, .COM or .EXE? ;;
pascal@24476 440 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 441
pascal@24476 442 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 443
pascal@24476 444 add bp, [bx+08h] ; bp = image base
pascal@24476 445 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 446
pascal@24476 447 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 448 je RelocateEXE ; yes, it's an EXE program
pascal@24476 449
pascal@24476 450 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 451 ;; Setup and run a .COM program ;;
pascal@24476 452 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 453 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 454 ;; cmdline=void ;;
pascal@24476 455 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 456
pascal@24942 457 mov di, 100h ; ip
pascal@24476 458 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 459 mov ss, bp
pascal@24476 460 xor sp, sp
pascal@24476 461 push bp ; cs, ds and es
pascal@24476 462 jmp short Run
pascal@24476 463
pascal@24476 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 465 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 466 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 467 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 468 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 470
pascal@24476 471 ReloCycle:
pascal@24476 472 add [di+2], bp ; item seg (abs)
pascal@24476 473 les si, [di] ; si = item ofs, es = item seg
pascal@24476 474 add [es:si], bp ; fixup
pascal@24476 475 scasw ; di += 2
pascal@24476 476 scasw ; point to next entry
pascal@24476 477
pascal@24476 478 RelocateEXE:
pascal@24942 479 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 480 jns ReloCycle
pascal@24476 481 ; PSP don't have a valid drive identifier
pascal@24476 482 les si, [bx+0Eh]
pascal@24476 483 add si, bp
pascal@24476 484 mov ss, si ; ss for EXE
pascal@24476 485 mov sp, es ; sp for EXE
pascal@24476 486
pascal@24476 487 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 488 push si ; containing the PSP structure
pascal@24476 489
pascal@24476 490 add bp, [bx+16h] ; cs for EXE
pascal@24942 491 mov di, [bx+14h] ; ip for EXE
pascal@24476 492 Run:
pascal@24476 493 pop ds
pascal@24476 494 push bp
pascal@24942 495 push di
pascal@24476 496 push ds
pascal@24476 497 pop es
pascal@24942 498 mov [80h], ax ; clear cmdline
pascal@24942 499 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 500
pascal@24476 501 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 502 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 503 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 504 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 505 mov si, 16381 ; prime number 2**14-3
pascal@24476 506 mov di, 32749 ; prime number 2**15-19
pascal@24476 507 mov bp, 65521 ; prime number 2**16-15
pascal@24476 508
pascal@24476 509 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 510 ;; All done, transfer control to the program now ;;
pascal@24476 511 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 512 retf
pascal@24476 513
pascal@25458 514 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 515 ;; Error Messaging Code ;;
pascal@25458 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 517
pascal@25458 518 Error:
pascal@25458 519 pop si
pascal@25458 520
pascal@25458 521 PutStr:
pascal@25458 522 mov ah, 0Eh
pascal@25458 523 mov bl, 7
pascal@25458 524 lodsb
pascal@25458 525 int 10h
pascal@25458 526 cmp al, "."
pascal@25458 527 jne PutStr
pascal@25564 528 %if WaitForKey != 0
pascal@25458 529 cbw
pascal@25458 530 int 16h ; wait for a key...
pascal@25458 531 int 19h ; bootstrap
pascal@25564 532 %endif
pascal@25458 533 Stop:
pascal@25458 534 hlt
pascal@25458 535 jmp short Stop
pascal@25458 536
pascal@25458 537 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 538 ;; Read sectors using BIOS Int 13h ;;
pascal@25458 539 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 540 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@25458 541 ;; BX = 0 ;;
pascal@25458 542 ;; DI = sector count ;;
pascal@25458 543 ;; ES:BX -> buffer address ;;
pascal@25458 544 ;; Output: ES:BX -> next address ;;
pascal@25458 545 ;; BX = 0 ;;
pascal@25458 546 ;; CX = 0 ;;
pascal@25458 547 ;; DI = 0 ;;
pascal@25458 548 ;; DL = drive number ;;
pascal@25564 549 ;; 0:BP = next LBA from FAT ;;
pascal@25458 550 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 551
pascal@25458 552 ReadDISectors:
pascal@25458 553 mov bp, di
pascal@24476 554 add bp, ax ; adjust LBA for cluster data
pascal@24476 555
pascal@25458 556 mov cx, di ; no cluster size limit
pascal@24476 557
pascal@24476 558 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 559 ;; Read sectors using BIOS Int 13h ;;
pascal@24476 560 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 561 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 562 ;; BX = 0 ;;
pascal@24476 563 ;; CX = sector count ;;
pascal@24476 564 ;; DI = file sectors ;;
pascal@24476 565 ;; ES:BX -> buffer address ;;
pascal@24476 566 ;; Output: ES:BX -> next address ;;
pascal@24476 567 ;; BX = 0 ;;
pascal@24476 568 ;; CX or DI = 0 ;;
pascal@24476 569 ;; DL = drive number ;;
pascal@25564 570 ;; Keep: BP, SI ;;
pascal@24476 571 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 572
pascal@25458 573 ReadSectors:
pascal@24476 574 add ax, [bx(bpbHiddenSectors)]
pascal@24476 575 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 576 add ax, [bx(bpbReservedSectors)]
pascal@24476 577
pascal@24476 578 push si
pascal@24476 579 ReadSectorNext:
pascal@24476 580 adc dx, bx
pascal@24476 581 push di
pascal@24476 582 push cx
pascal@24476 583
pascal@25450 584 %if LBAsupport != 0
pascal@24476 585 push bx
pascal@24476 586 push bx
pascal@25450 587 %endif
pascal@24476 588 push dx ; 32-bit LBA: up to 2TB
pascal@24476 589 push ax
pascal@24476 590 push es
pascal@25450 591 %if ReadRetry != 0 || LBAsupport != 0
pascal@25450 592 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 593 %endif
pascal@25450 594 %if LBAsupport != 0
pascal@24476 595 push bx
pascal@24476 596 inc bx ; sector count word = 1
pascal@24476 597 push bx
pascal@24476 598 dec bx
pascal@24476 599 push di
pascal@25450 600 %endif
pascal@25569 601 mov si, sp
pascal@24476 602
pascal@24476 603 xchg ax, cx ; save low LBA
pascal@24476 604 xchg ax, dx ; get high LBA
pascal@25452 605 cwd ; clear dx (LBA offset <1TB)
pascal@25450 606 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 607
pascal@25569 608 %if CHSsanityCheck != 0
pascal@25564 609 inc ax
pascal@25564 610 cmp ax, [bx(bpbHeadsPerCylinder)]
pascal@25564 611 ja CHSoverflow
pascal@25564 612 dec ax
pascal@25569 613 %endif
pascal@24476 614 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25450 615 idiv word [bx(bpbSectorsPerTrack)]
pascal@24476 616 ; ax = LBA / SPT
pascal@24476 617 ; dx = LBA % SPT = sector - 1
pascal@24476 618 inc dx
pascal@24476 619
pascal@24476 620 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25564 621 idiv word [bx(bpbHeadsPerCylinder)] ; may overflow if SectorsPerTrack * HeadsPerCylinder < 256 or disk > 8GB
pascal@24476 622 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 623 ; dx = (LBA / SPT) % HPC = head
pascal@25458 624
pascal@25458 625 xchg ch, al ; clear al
pascal@24476 626 ; ch = LSB 0...7 of cylinder no.
pascal@25458 627 shr ax, 1
pascal@25458 628 shr ax, 1
pascal@24476 629 or cl, al
pascal@24476 630 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 631 mov dh, dl
pascal@24476 632 ; dh = head no.
pascal@24476 633
pascal@25564 634 %if CHSsanityCheck != 0
pascal@25564 635 %if LBAsupport != 0
pascal@25564 636 or ah, [si+8+3] ; 8GB max, last cylinder 1023
pascal@25564 637 %else
pascal@25564 638 or ah, [si+2+3] ; 8GB max, last cylinder 1023
pascal@25564 639 %endif
pascal@25564 640 %endif
pascal@25564 641 CHSoverflow:
pascal@25569 642 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 643 pushf
pascal@25564 644 %endif
pascal@25564 645
pascal@25564 646 ReadSectorRetry:
pascal@25569 647 mov dl, [bx(DriveNumber)]
pascal@25569 648 ; dl = drive no.
pascal@25450 649 %if LBAsupport != 0
pascal@24476 650 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 651 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 652 jnc ReadSectorNextSegment
pascal@25450 653 %endif
pascal@25564 654 %if CHSsanityCheck != 0
pascal@25564 655 %if ReadRetry != 0 || LBAsupport != 0
pascal@25564 656 popf
pascal@25564 657 pushf
pascal@25564 658 %endif
pascal@25564 659 jne SkipCHS
pascal@25564 660 %endif
pascal@24476 661
pascal@24476 662 mov ax, 201h ; al = sector count = 1
pascal@24476 663 ; ah = 2 = read function no.
pascal@24476 664 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 665
pascal@24476 666 jnc ReadSectorNextSegment
pascal@25564 667 SkipCHS:
pascal@25450 668 %if ReadRetry != 0
pascal@24476 669 cbw ; ah = 0 = reset function
pascal@24476 670 int 13h ; reset drive (DL)
pascal@24476 671
pascal@24476 672 dec di
pascal@25457 673 jnz ReadSectorRetry ; up to 15 extra attempt
pascal@25450 674 %endif
pascal@24476 675
pascal@25564 676 ReadError:
pascal@24476 677 call Error
pascal@24476 678 db "Read error."
pascal@24476 679
pascal@24476 680 ReadSectorNextSegment:
pascal@25564 681 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 682 popf
pascal@25564 683 %endif
pascal@25564 684
pascal@25564 685 %macro adjust_es 2
pascal@25564 686 %if SectorOf512Bytes != 0
pascal@25564 687 add word %1, byte 32 ; adjust segment for next sector
pascal@25564 688 %else
pascal@25564 689 %if %2 != 0
pascal@25564 690 mov al, %2
pascal@25564 691 %endif
pascal@25564 692 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25564 693 add %1, ax ; adjust segment for next sector
pascal@25564 694 %endif
pascal@25564 695 %endmacro
pascal@24476 696
pascal@25450 697 %if LBAsupport != 0
pascal@24476 698 pop ax ; al = 16
pascal@25564 699 adjust_es [si+6], 0
pascal@24476 700 pop cx ; sector count = 1
pascal@24476 701 pop bx
pascal@25450 702 %else
pascal@25564 703 adjust_es [si], 16
pascal@25450 704 %endif
pascal@24476 705 pop es ; es:0 updated
pascal@24476 706 pop ax
pascal@24476 707 pop dx
pascal@25450 708 %if LBAsupport != 0
pascal@24476 709 pop di
pascal@24476 710 pop di
pascal@24476 711 add ax, cx ; adjust LBA for next sector
pascal@25450 712 %else
pascal@25450 713 add ax, 1 ; adjust LBA for next sector
pascal@25450 714 %endif
pascal@24476 715
pascal@24476 716 pop cx ; cluster sectors to read
pascal@24476 717 pop di ; file sectors to read
pascal@24476 718 dec di ; keep C
pascal@25457 719 loopne ReadSectorNext ; until cluster sector count or file sector count
pascal@24476 720 pop si
pascal@24942 721 mov ax, bx ; clear ax
pascal@25450 722 mov dx, [bx(DriveNumber)] ; pass the BIOS boot drive to Run or Error
pascal@24476 723
pascal@24476 724 ret
pascal@24476 725
pascal@24942 726 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 727 ;; Fill free space with zeroes ;;
pascal@24942 728 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 729
pascal@25458 730 times (512-13-($-$$)) db 0
pascal@24476 731
pascal@24476 732 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 733 ;; Name of the file to load and run ;;
pascal@24476 734 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 735
pascal@25463 736 NameLength equ 11
pascal@25463 737 ProgramName times NameLength db 0 ; name and extension
pascal@24476 738
pascal@24476 739 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 740 ;; End of the sector ID ;;
pascal@24476 741 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 742
pascal@24476 743 ClusterList dw 0AA55h ; BIOS checks for this ID