wok-current annotate BootProg/stuff/bootex.asm @ rev 25458

Update some web_site
author Pascal Bellard <pascal.bellard@slitaz.org>
date Tue Sep 27 16:21:52 2022 +0000 (21 months ago)
parents ad0bc3efbf37
children 7dd01dedad38
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@24476 51 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@24476 53 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24476 54 ;; | 1.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 61 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 62 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 63 ;; cs:ip = program entry point ;;
pascal@24476 64 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 65 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 66 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24945 75 ;; The command line contains no arguments. ;;
pascal@24476 76 ;; ;;
pascal@24476 77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 78
pascal@24476 79 %define bx(label) bx+label-boot
pascal@25450 80 %define si(label) si+label-boot
pascal@25450 81 NullEntryCheck equ 1 ; +3 bytes
pascal@25450 82 ReadRetry equ 1 ; +8 bytes
pascal@25458 83 SectorOf512Bytes equ 1 ; -13 bytes
pascal@24476 84
pascal@24476 85 [BITS 16]
pascal@24476 86 [CPU 386]
pascal@24476 87
pascal@24476 88 ImageLoadSeg equ 60h
pascal@24476 89 StackSize equ 1536
pascal@24476 90
pascal@24476 91 [SECTION .text]
pascal@24476 92 [ORG 0]
pascal@24476 93
pascal@24476 94 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 95 ;; Boot sector starts here ;;
pascal@24476 96 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 97
pascal@24476 98 boot:
pascal@25450 99 DriveNumber:
pascal@24476 100 jmp short start ; Windows checks for this jump
pascal@24476 101 nop
pascal@25458 102 bsOemName times 8 db " " ; 0x03 "EXFAT "
pascal@24476 103 times 53 db 0 ; 0x0B
pascal@24476 104
pascal@24476 105 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 106 ;; BPB starts here ;;
pascal@24476 107 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 108
pascal@24479 109 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 110 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 111 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 112 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 113 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 114 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 115 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 116 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 117 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 118 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 119 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 120 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 121 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 122 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 123 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 124 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 125
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;
pascal@24476 127 ;; BPB ends here ;;
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;
pascal@24476 129
pascal@24476 130 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 131 ;; Boot sector code starts here ;;
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133
pascal@24476 134 start:
pascal@24476 135 cld
pascal@24476 136
pascal@24476 137 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 138 ;; How much RAM is there? ;;
pascal@24476 139 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 140
pascal@24476 141 int 12h ; get conventional memory size (in KBs)
pascal@24476 142 mov cx, 106h
pascal@24476 143 dec ax
pascal@24476 144 dec ax ; reserve 2K bytes for the code and the stack
pascal@24476 145 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 152 mov ss, ax
pascal@24476 153 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 154
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156 ;; Copy ourselves to top of memory ;;
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158
pascal@24476 159 mov si, 7C00h
pascal@24476 160 xor di, di
pascal@24476 161 mov ds, di
pascal@25450 162 push es
pascal@25450 163 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 164 rep movsw ; move 512 bytes (+ 12)
pascal@24476 165
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167 ;; Jump to the copy ;;
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169
pascal@24942 170 push word main
pascal@24476 171 retf
pascal@24476 172
pascal@24476 173 main:
pascal@24476 174 push cs
pascal@24476 175 pop ds
pascal@24476 176
pascal@24476 177 xor ebx, ebx
pascal@24476 178
pascal@24476 179 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 180
pascal@24479 181 push byte ImageLoadSeg
pascal@24942 182 pop es ; cx = 0
pascal@24476 183
pascal@24476 184 RootDirReadContinue:
pascal@24476 185 call ReadCluster ; read one sector of root dir
pascal@24476 186
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190
pascal@25454 191 ; es:di -> root entries array
pascal@24476 192
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194 ;; Looks for the file/dir ProgramName ;;
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196 ;; Input: ES:DI -> root directory array ;;
pascal@24476 197 ;; Output: ESI = cluster number ;;
pascal@24476 198 ;; dword [bx+FileSize] file size ;;
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200
pascal@25450 201 CurNameSize equ 3 ; 1 byte
pascal@25450 202 StartCluster equ 14h ; 4 bytes
pascal@25450 203 FileSize equ 18h ; 8 bytes
pascal@24476 204
pascal@24476 205 FindNameCycle:
pascal@24476 206 pusha
pascal@24476 207
pascal@25450 208 %if NullEntryCheck != 0
pascal@24476 209 xor ax, ax
pascal@24476 210 or al, [es:di]
pascal@24476 211 je FindNameFailed
pascal@25450 212 %else
pascal@25450 213 movzx ax, byte [es:di]
pascal@25450 214 %endif
pascal@24476 215
pascal@24476 216 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@24476 217 jne NotFileInfo
pascal@24476 218
pascal@24942 219 mov bl, 31
pascal@24476 220 CopyInfo:
pascal@24942 221 mov al, [es:di+bx]
pascal@24942 222 mov [bx], al
pascal@24476 223 dec bx
pascal@25450 224 jnz CopyInfo ; keep BIOS boot drive number
pascal@24476 225
pascal@24476 226 NotFileInfo:
pascal@24476 227 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@24476 228 mov cx, NameLength+1
pascal@24476 229 mov si, ProgramName ; ds:si -> program name
pascal@24476 230 CheckName:
pascal@24476 231 scasw ; compare UTF-16
pascal@24476 232 lodsb ; with ASCII
pascal@24476 233 loope CheckName
pascal@24476 234 je FindNameFound ; cx = 0
pascal@24476 235 popa ; restore ax, cx, si, di
pascal@24476 236
pascal@24479 237 add di, byte 32
pascal@24945 238 cmp di, bp
pascal@24945 239 jne FindNameCycle ; next root entry
pascal@25458 240 loop RootDirReadContinue ; continue to the next root dir sector
pascal@25458 241 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 242 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 243 FindNameFailed: ; end of root directory (dir end reached)
pascal@25454 244 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 245 call Error
pascal@24476 246 db "File not found."
pascal@24476 247 FindNameFound:
pascal@24476 248 mov esi, [bx+StartCluster]
pascal@24476 249
pascal@24476 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 251 ;; Load the entire file ;;
pascal@24476 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 253
pascal@24476 254 push es
pascal@25458 255 %if SectorOf512Bytes == 0
pascal@24945 256 xor bp, bp
pascal@24476 257 FileReadContinue:
pascal@24476 258 shr bp, 4 ; bytes to paragraphs
pascal@24476 259 mov di, es
pascal@24476 260 add di, bp ; adjust segment for next sector
pascal@24476 261 mov es, di ; es:0 updated
pascal@25458 262 %else
pascal@25458 263 FileReadContinue:
pascal@25458 264 %endif
pascal@24943 265 call ReadCluster ; read one more sector of the boot file
pascal@25458 266 dec cx
pascal@25450 267 sub [bx+FileSize], ebp ; max FileSize is < 640KB : check low 32 bits only
pascal@25458 268 %if SectorOf512Bytes != 0
pascal@25458 269 mov bp, es
pascal@25458 270 lea bp, [bp+32]
pascal@25458 271 mov es, bp ; es:0 updated
pascal@25458 272 %endif
pascal@24476 273 ja FileReadContinue
pascal@25450 274 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25454 275 xchg ax, di
pascal@24476 276 pop bp
pascal@24476 277
pascal@24476 278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 279 ;; Type detection, .COM or .EXE? ;;
pascal@24476 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 281
pascal@24476 282 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 283
pascal@24476 284 add bp, [bx+08h] ; bp = image base
pascal@24476 285 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 286
pascal@24476 287 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 288 je RelocateEXE ; yes, it's an EXE program
pascal@24476 289
pascal@24476 290 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 291 ;; Setup and run a .COM program ;;
pascal@24476 292 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 293 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 294 ;; cmdline=void ;;
pascal@24476 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 296
pascal@24525 297 mov di, 100h ; ip
pascal@24476 298 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 299 mov ss, bp
pascal@24476 300 xor sp, sp
pascal@24476 301 push bp ; cs, ds and es
pascal@24476 302 jmp short Run
pascal@24476 303
pascal@24476 304 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 305 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 306 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 307 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 308 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 309 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 310
pascal@24476 311 ReloCycle:
pascal@24476 312 add [di+2], bp ; item seg (abs)
pascal@24476 313 les si, [di] ; si = item ofs, es = item seg
pascal@24476 314 add [es:si], bp ; fixup
pascal@24476 315 scasw ; di += 2
pascal@24476 316 scasw ; point to next entry
pascal@24476 317
pascal@24476 318 RelocateEXE:
pascal@24942 319 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 320 jns ReloCycle
pascal@24942 321
pascal@24945 322 les si, [bx+0Eh]
pascal@24945 323 add si, bp
pascal@24945 324 mov ss, si ; ss for EXE
pascal@24945 325 mov sp, es ; sp for EXE
pascal@24476 326
pascal@24476 327 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 328 push si ; containing the PSP structure
pascal@24476 329
pascal@24476 330 add bp, [bx+16h] ; cs for EXE
pascal@24525 331 mov di, [bx+14h] ; ip for EXE
pascal@24476 332 Run:
pascal@24476 333 pop ds
pascal@24476 334 push bp
pascal@24525 335 push di
pascal@24476 336 push ds
pascal@24476 337 pop es
pascal@24942 338 mov [80h], ax ; clear cmdline
pascal@24942 339 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 340
pascal@24476 341 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 342 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 343 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 345 mov si, 16381 ; prime number 2**14-3
pascal@24476 346 mov di, 32749 ; prime number 2**15-19
pascal@24476 347 mov bp, 65521 ; prime number 2**16-15
pascal@24476 348
pascal@24476 349 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 350 ;; All done, transfer control to the program now ;;
pascal@24476 351 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 352 retf
pascal@24476 353
pascal@25458 354 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 355 ;; Error Messaging Code ;;
pascal@25458 356 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 357
pascal@25458 358 Error:
pascal@25458 359 pop si
pascal@25458 360
pascal@25458 361 PutStr:
pascal@25458 362 mov ah, 0Eh
pascal@25458 363 mov bl, 7
pascal@25458 364 lodsb
pascal@25458 365 int 10h
pascal@25458 366 cmp al, "."
pascal@25458 367 jne PutStr
pascal@25458 368
pascal@25458 369 cbw
pascal@25458 370 int 16h ; wait for a key...
pascal@25458 371 int 19h ; bootstrap
pascal@25458 372
pascal@25458 373 Stop:
pascal@25458 374 hlt
pascal@25458 375 jmp short Stop
pascal@25458 376
pascal@24476 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 378 ;; Reads a exFAT cluster ;;
pascal@24476 379 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 380 ;; Input: EDX:EAX = LBA ;;
pascal@24476 381 ;; EBX = 0 ;;
pascal@24476 382 ;; CX = sector cnt ;;
pascal@24476 383 ;; ESI = cluster no ;;
pascal@24476 384 ;; ES:0 -> buffer adrs ;;
pascal@24476 385 ;; Output: EBX = 0 ;;
pascal@24476 386 ;; CX = next cnt ;;
pascal@24476 387 ;; EBP = bytes/sector;;
pascal@24476 388 ;; ES:0 -> next adrs ;;
pascal@24476 389 ;; C=0 for last sector ;;
pascal@24476 390 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 391
pascal@24476 392 ReadCluster:
pascal@24945 393 add eax, byte 1
pascal@24945 394
pascal@24476 395 inc cx ; jcxnz
pascal@24476 396 loop ReadSectorC
pascal@24476 397
pascal@24945 398 mul ebx ; edx:eax = 0
pascal@25458 399 %if SectorOf512Bytes != 0
pascal@25458 400 mov al, 128
pascal@25458 401 %else
pascal@25452 402 mov cl, -2
pascal@25450 403 add cl, [bx(bpbSectorSizeBits)]
pascal@25450 404 bts ax, cx ; eax=# of exFAT entries per sector
pascal@25458 405 %endif
pascal@24476 406 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 407 xchg eax, esi
pascal@24476 408 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 409
pascal@24525 410 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 411
pascal@24476 412 cdq
pascal@25452 413 add eax, [bx(bpbFatSectorStart)] ; sector # relative to exFAT
pascal@25454 414 call ReadSectorFAT ; read 1 exFAT sector, keep edx=0, set C
pascal@24476 415
pascal@24476 416 mov esi, [es:si] ; esi=next cluster #
pascal@24476 417
pascal@25450 418 mov dl, [bx(bpbSectorPerClusterBits)]
pascal@25452 419 xor ecx, ecx
pascal@25450 420 bts ecx, edx ; 10000h max (32MB cluster)
pascal@24476 421 xchg eax, edi ; get cluster #-2
pascal@24476 422 mul ecx
pascal@24476 423
pascal@24476 424 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 425 ReadSectorC:
pascal@25454 426 mov di, bx
pascal@25454 427 ReadSectorFAT:
pascal@24476 428 adc edx, ebx
pascal@24476 429
pascal@24476 430 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 431 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 433 ;; Input: EDX:EAX = LBA ;;
pascal@24476 434 ;; BX = 0 ;;
pascal@24476 435 ;; CX = sector count ;;
pascal@24476 436 ;; ES:0 -> buffer address ;;
pascal@24476 437 ;; Output: BX = 0 ;;
pascal@24476 438 ;; CX = next count ;;
pascal@24476 439 ;; EBP = bytes/sector ;;
pascal@24476 440 ;; ES:0 -> next address ;;
pascal@24476 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 442
pascal@25458 443 %if SectorOf512Bytes != 0
pascal@25458 444 lea ebp, [bx+512]
pascal@25458 445 %else
pascal@25458 446 lea ebp, [bx+1]
pascal@25458 447 %endif
pascal@24476 448
pascal@24476 449 pushad
pascal@24476 450
pascal@24476 451 add eax, [bx(bpbSectorStart)]
pascal@24476 452 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 453
pascal@24476 454 push edx
pascal@24476 455 push eax
pascal@24476 456 push es
pascal@24476 457 push bx
pascal@25458 458 %if SectorOf512Bytes != 0
pascal@25458 459 push byte 1 ; sector count word = 1
pascal@25458 460 %else
pascal@24476 461 push bp ; sector count word = 1
pascal@25458 462 %endif
pascal@25454 463 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 464 ReadSectorRetry:
pascal@24476 465 mov si, sp
pascal@24476 466 mov ah, 42h ; ah = 42h = extended read function no.
pascal@25450 467 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 468 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 469
pascal@24476 470 jnc ReadSuccess
pascal@24476 471
pascal@25450 472 %if ReadRetry != 0
pascal@24476 473 xor ax, ax
pascal@24476 474 int 13h ; reset drive (DL)
pascal@25457 475 dec bp
pascal@25458 476 %if SectorOf512Bytes != 0
pascal@25458 477 jne ReadSectorRetry ; up to 511 tries
pascal@25458 478 %else
pascal@25457 479 jpe ReadSectorRetry ; up to 3 tries
pascal@25458 480 %endif
pascal@25450 481 %endif
pascal@24476 482
pascal@24476 483 call Error
pascal@24476 484 db "Read error."
pascal@24476 485
pascal@24476 486 ReadSuccess:
pascal@25458 487 %if SectorOf512Bytes == 0
pascal@24476 488 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 489 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@25458 490 %endif
pascal@24476 491 popa ; sp += 16
pascal@24476 492 popad ; real registers
pascal@24476 493 ret
pascal@24476 494
pascal@24942 495 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 496 ;; Fill free space with zeroes ;;
pascal@24942 497 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 498
pascal@25458 499 times (512-13-($-$$)) db 0
pascal@24476 500
pascal@24476 501 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 502 ;; Name of the file to load and run ;;
pascal@24476 503 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 504
pascal@24476 505 ProgramName db "startup.bin" ; name and extension
pascal@24476 506 NameLength equ $-ProgramName
pascal@24476 507
pascal@24476 508 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 509 ;; End of the sector ID ;;
pascal@24476 510 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 511
pascal@24476 512 dw 0AA55h ; BIOS checks for this ID