wok annotate BootProg/stuff/boot32.asm @ rev 25450

BootProg: avoid divide errors
author Pascal Bellard <pascal.bellard@slitaz.org>
date Wed Sep 14 18:33:54 2022 +0000 (21 months ago)
parents 6023b31d568c
children 78727b04c002
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24525 20 ;; Its maximum size can be up to 636KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 23 ;; ("File not found" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; Known Bugs: ;;
pascal@24476 29 ;; ~~~~~~~~~~~ ;;
pascal@24476 30 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 31 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; ;;
pascal@24476 34 ;; Memory Layout: ;;
pascal@24476 35 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 36 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 37 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 38 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 39 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; physical address ;;
pascal@24476 42 ;; +------------------------+ 00000H ;;
pascal@24476 43 ;; | Interrupt Vector Table | ;;
pascal@24476 44 ;; +------------------------+ 00400H ;;
pascal@24476 45 ;; | BIOS Data Area | ;;
pascal@24476 46 ;; +------------------------+ 00500H ;;
pascal@24476 47 ;; | PrtScr Status / Unused | ;;
pascal@24476 48 ;; +------------------------+ 00600H ;;
pascal@24476 49 ;; | Loaded Image | ;;
pascal@24476 50 ;; +------------------------+ nnnnnH ;;
pascal@24476 51 ;; | Available Memory | ;;
pascal@24525 52 ;; +------------------------+ A0000H - 2KB ;;
pascal@24476 53 ;; | Boot Sector | ;;
pascal@24525 54 ;; +------------------------+ A0000H - 1.5KB ;;
pascal@24525 55 ;; | 1.5KB Boot Stack | ;;
pascal@24476 56 ;; +------------------------+ A0000H ;;
pascal@24476 57 ;; | Video RAM | ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; ;;
pascal@24476 60 ;; Boot Image Startup (register values): ;;
pascal@24476 61 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 62 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@24945 63 ;; bx = cx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 64 ;; cs:ip = program entry point ;;
pascal@24476 65 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 66 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 67 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 68 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 69 ;; Magic numbers: ;;
pascal@24476 70 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 71 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 72 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 73 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 74 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 75 ;; metal and MS-DOS programs. ;;
pascal@24945 76 ;; The command line contains no arguments. ;;
pascal@24476 77 ;; ;;
pascal@24476 78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 79
pascal@24491 80 %define bx(label) bx+label-boot
pascal@25449 81 %define si(label) si+label-boot
pascal@25449 82 ClusterMask equ 1 ; +9 bytes
pascal@25449 83 NullEntryCheck equ 1 ; +5 bytes
pascal@25449 84 ReadRetry equ 1 ; +7 bytes
pascal@25449 85 LBA48bits equ 1 ; +13 bytes
pascal@25449 86 CHSsupport equ 1 ; +27 bytes
pascal@25449 87 CHShardDisk equ 0 ; +11 bytes
pascal@24491 88
pascal@24476 89 [BITS 16]
pascal@24476 90
pascal@24478 91 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@24525 92 StackSize equ 1536
pascal@24476 93
pascal@24476 94 [SECTION .text]
pascal@24476 95 [ORG 0]
pascal@24476 96
pascal@24476 97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 98 ;; Boot sector starts here ;;
pascal@24476 99 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 100
pascal@24491 101 boot:
pascal@24476 102 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 103 nop
pascal@24476 104 bsOemName DB "BootProg" ; 0x03
pascal@24476 105
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107 ;; BPB1 starts here ;;
pascal@24476 108 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 109
pascal@24479 110 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 111 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 112 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 113 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 114 bpbRootEntries DW 0 ; 0x11
pascal@24479 115 bpbTotalSectors DW 0 ; 0x13
pascal@24479 116 bpbMedia DB 0 ; 0x15
pascal@24479 117 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 118 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 119 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 120 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 121 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 122
pascal@24476 123 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 124 ;; BPB1 ends here ;;
pascal@24476 125 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 126
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 128 ;; BPB2 starts here ;;
pascal@24476 129 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 130
pascal@24479 131 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 132 bsExtendedFlags DW 0 ; 0x28
pascal@24479 133 bsFSVersion DW 0 ; 0x2A
pascal@24479 134 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 135 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 136 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 137 bsreserved times 12 DB 0 ; 0x34
pascal@24479 138 bsDriveNumber DB 0 ; 0x40
pascal@25449 139 %if LBA48bits != 0
pascal@25449 140 HiLBA equ boot+0
pascal@25449 141 DriveNumber equ bsDriveNumber+0
pascal@25449 142 %else
pascal@25449 143 DriveNumber equ boot+0
pascal@25449 144 %endif
pascal@24479 145 bsreserved1 DB 0 ; 0x41
pascal@24479 146 bsExtendedBootSignature DB 0 ; 0x42
pascal@24479 147 bsVolumeSerialNumber DD 0 ; 0x43
pascal@24476 148 bsVolumeLabel DB "NO NAME " ; 0x47
pascal@24476 149 bsFileSystemName DB "FAT32 " ; 0x52
pascal@24476 150
pascal@24476 151 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 152 ;; BPB2 ends here ;;
pascal@24476 153 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 154
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156 ;; Boot sector code starts here ;;
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158
pascal@24476 159 start:
pascal@24476 160 cld
pascal@24476 161
pascal@24476 162 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 163 ;; How much RAM is there? ;;
pascal@24476 164 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 165
pascal@24476 166 int 12h ; get conventional memory size (in KBs)
pascal@24525 167 dec ax
pascal@24525 168 dec ax ; reserve 2K bytes for the code and the stack
pascal@24525 169 mov cx, 106h
pascal@24525 170 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 171
pascal@24476 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 173 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 175
pascal@24525 176 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24525 177 mov ss, ax
pascal@24525 178 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 179
pascal@24476 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 181 ;; Copy ourselves to top of memory ;;
pascal@24476 182 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 183
pascal@24476 184 mov si, 7C00h
pascal@24476 185 xor di, di
pascal@24476 186 mov ds, di
pascal@25449 187 push es
pascal@25449 188 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24478 189 rep movsw
pascal@24476 190
pascal@24476 191 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 192 ;; Jump to the copy ;;
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194
pascal@25450 195 push byte main
pascal@24476 196 retf
pascal@24476 197
pascal@24476 198 main:
pascal@24476 199 push cs
pascal@24476 200 pop ds
pascal@24476 201
pascal@25449 202 xor ebx, ebx
pascal@24476 203
pascal@25449 204 %if ClusterMask != 0
pascal@24491 205 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@25449 206 %endif
pascal@24491 207 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 208
pascal@24478 209 push byte ImageLoadSeg
pascal@24478 210 pop es
pascal@25449 211
pascal@25449 212 RootDirReadContinue:
pascal@24478 213 call ReadCluster ; read one cluster of root dir
pascal@24478 214 pushf ; save carry="not last cluster" flag
pascal@24476 215
pascal@24476 216 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 217 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 218 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 219
pascal@24476 220 xor di, di ; es:di -> root entries array
pascal@24476 221
pascal@24476 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 223 ;; Looks for a file/dir by its name ;;
pascal@24476 224 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 225 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 226 ;; ES:DI -> root directory array ;;
pascal@24525 227 ;; BP = paragraphs in sector ;;
pascal@24476 228 ;; Output: ESI = cluster number ;;
pascal@24476 229 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 230
pascal@24476 231 FindNameCycle:
pascal@25449 232 %if NullEntryCheck != 0
pascal@24525 233 cmp byte [es:di], bh
pascal@24478 234 je ErrFind ; end of root directory (NULL entry found)
pascal@25449 235 %endif
pascal@24478 236 pusha
pascal@24525 237 mov cl, 11
pascal@24525 238 mov si, ProgramName ; ds:si -> program name
pascal@24476 239 repe cmpsb
pascal@24525 240 je FindNameFound
pascal@24478 241 popa
pascal@24525 242 add di, byte 32
pascal@24476 243 dec bp
pascal@24476 244 dec bp
pascal@24476 245 jnz FindNameCycle ; next root entry
pascal@24478 246 popf ; restore carry="not last cluster" flag
pascal@24476 247 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 248 ErrFind:
pascal@24478 249 call Error ; end of root directory (dir end reached)
pascal@24476 250 db "File not found."
pascal@24476 251 FindNameFound:
pascal@24525 252 push word [es:di+14h-11]
pascal@24525 253 push word [es:di+1Ah-11]
pascal@24478 254 pop esi ; esi = cluster no. cx = 0
pascal@24476 255
pascal@24525 256 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 257 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 258
pascal@24476 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 260 ;; Load the entire file ;;
pascal@24476 261 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 262
pascal@24476 263 push es
pascal@24476 264 FileReadContinue:
pascal@24476 265 push di
pascal@24478 266 call ReadCluster ; read one cluster of root dir
pascal@24476 267 mov di, es
pascal@24478 268 add di, bp
pascal@24478 269 mov es, di ; es:bx updated
pascal@24476 270 pop di
pascal@24478 271
pascal@24476 272 sub di, bp
pascal@24476 273 jae FileReadContinue
pascal@24943 274 xor ax, ax
pascal@24476 275 pop bp
pascal@24476 276
pascal@24476 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 278 ;; Type detection, .COM or .EXE? ;;
pascal@24476 279 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 280
pascal@24476 281 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 282
pascal@24476 283 add bp, [bx+08h] ; bp = image base
pascal@24476 284 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 285
pascal@24476 286 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 287 je RelocateEXE ; yes, it's an EXE program
pascal@24476 288
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Setup and run a .COM program ;;
pascal@24535 291 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@24535 292 ;; AX=0ffffh BX=0 CX=0 DX=drive ;;
pascal@24942 293 ;; and cmdline=void ;;
pascal@24476 294 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 295
pascal@24535 296 mov di, 100h ; ip
pascal@24476 297 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 298 mov ss, bp
pascal@24476 299 xor sp, sp
pascal@24476 300 push bp ; cs, ds and es
pascal@24476 301 jmp short Run
pascal@24476 302
pascal@24476 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 304 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 305 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 306 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@24942 307 ;; AX=0ffffh BX=0 CX=0 DX=drive cmdline=void ;;
pascal@24476 308 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 309
pascal@24476 310 ReloCycle:
pascal@24476 311 add [di+2], bp ; item seg (abs)
pascal@24476 312 les si, [di] ; si = item ofs, es = item seg
pascal@24476 313 add [es:si], bp ; fixup
pascal@24525 314 scasw ; di += 2
pascal@24525 315 scasw ; point to next entry
pascal@24476 316
pascal@24476 317 RelocateEXE:
pascal@24942 318 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 319 jns ReloCycle
pascal@24942 320
pascal@24945 321 les si, [bx+0Eh]
pascal@24945 322 add si, bp
pascal@24945 323 mov ss, si ; ss for EXE
pascal@24945 324 mov sp, es ; sp for EXE
pascal@24476 325
pascal@24476 326 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 327 push si ; containing the PSP structure
pascal@24476 328
pascal@24476 329 add bp, [bx+16h] ; cs for EXE
pascal@24535 330 mov di, [bx+14h] ; ip for EXE
pascal@24476 331 Run:
pascal@24476 332 pop ds
pascal@24476 333 push bp
pascal@24535 334 push di
pascal@24476 335 push ds
pascal@24476 336 pop es
pascal@24942 337 mov [80h], ax ; clear cmdline
pascal@24942 338 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 339
pascal@24476 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 341 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 342 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 344 mov si, 16381 ; prime number 2**14-3
pascal@24476 345 mov di, 32749 ; prime number 2**15-19
pascal@24476 346 mov bp, 65521 ; prime number 2**16-15
pascal@24476 347
pascal@24476 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 349 ;; All done, transfer control to the program now ;;
pascal@24476 350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 351 retf
pascal@24476 352
pascal@24525 353 ReadCluster:
pascal@24525 354 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 355 shr bp, 4 ; bp = paragraphs per sector
pascal@25449 356 mov dx, 1 ; adjust LBA for next sector
pascal@24525 357 inc cx
pascal@24525 358 loop ReadSectorLBA
pascal@24525 359
pascal@24478 360 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 361 ;; Reads a FAT32 cluster ;;
pascal@24478 362 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 363 ;; Inout: ES:BX -> buffer ;;
pascal@24478 364 ;; ESI = cluster no ;;
pascal@24478 365 ;; Output: ESI = next cluster ;;
pascal@24525 366 ;; BP -> para / sector ;;
pascal@24478 367 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 368
pascal@25449 369 mul ebx ; edx:eax = 0
pascal@24945 370 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@24525 371 lea edi, [esi-2] ; esi=cluster #
pascal@24476 372 xchg eax, esi
pascal@24478 373 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 374
pascal@24525 375 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@25449 376 %if LBA48bits != 0
pascal@25449 377 xor dx, dx ; clear C
pascal@25449 378 %endif
pascal@24478 379 call ReadSectorLBAabsolute ; read 1 FAT32 sector
pascal@24476 380
pascal@25449 381 %if ClusterMask != 0
pascal@24478 382 and byte [es:si+3], 0Fh ; mask cluster value
pascal@25449 383 %endif
pascal@24478 384 mov esi, [es:si] ; esi=next cluster #
pascal@24476 385
pascal@24525 386 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 387 mul dword [bx(bsSectorsPerFAT32)]
pascal@24525 388
pascal@24525 389 xchg eax, edi
pascal@24491 390 movzx ecx, byte [bx(bpbSectorsPerCluster)]
pascal@24945 391 mul ecx ; edx:eax=sector number in data area
pascal@24525 392 add eax, edi
pascal@24476 393
pascal@24478 394 ReadSectorLBAabsolute:
pascal@25449 395 %if LBA48bits != 0
pascal@25449 396 adc dx, bx
pascal@25449 397 mov word [bx(HiLBA)], dx
pascal@25449 398 %endif
pascal@25449 399 add eax, [bx(bpbHiddenSectors)]
pascal@25449 400 %if LBA48bits != 0
pascal@25449 401 adc word [bx(HiLBA)], bx
pascal@25449 402 %endif
pascal@24525 403 mov dx, word [bx(bpbReservedSectors)]
pascal@24476 404
pascal@24478 405 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 406 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 407 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 408 ;; Input: EAX = LBA ;;
pascal@24478 409 ;; CX = sector count ;;
pascal@24478 410 ;; ES:BX -> buffer address ;;
pascal@24478 411 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 412 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 413
pascal@24476 414 ReadSectorLBA:
pascal@25449 415 add eax, edx
pascal@25449 416 %if LBA48bits != 0
pascal@24535 417 adc word [bx(HiLBA)], bx
pascal@25449 418 %endif
pascal@25449 419 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 420 pusha
pascal@24476 421
pascal@24478 422 push bx
pascal@25449 423 %if LBA48bits != 0
pascal@24491 424 push word [bx(HiLBA)] ; 48-bit LBA
pascal@25449 425 %else
pascal@25449 426 push bx
pascal@25449 427 %endif
pascal@24478 428 push eax
pascal@24476 429 push es
pascal@24476 430 push bx
pascal@24478 431 push byte 1 ; sector count word = 1
pascal@24525 432 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 433
pascal@25449 434 %if CHSsupport != 0
pascal@25449 435 %if CHShardDisk != 0
pascal@25449 436 push eax
pascal@25449 437 pop cx ; save low LBA
pascal@25449 438 pop ax ; get high LBA
pascal@25449 439 cwd ; clear dx (assume LBA offset <1TB)
pascal@25449 440 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks, avoid divide error
pascal@25449 441
pascal@25449 442 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25449 443 %else
pascal@25449 444 ; Busybox mkdosfs creates fat32 for floppies.
pascal@25449 445 ; Floppies may support CHS only.
pascal@25449 446 cwd ; clear dx (LBA offset <16MB)
pascal@25450 447 xor cx, cx ; high LBA / SPT = 0
pascal@25450 448 %endif
pascal@25449 449 idiv word [bx(bpbSectorsPerTrack)]
pascal@25449 450 ; ax = LBA / SPT
pascal@25449 451 ; dx = LBA % SPT = sector - 1
pascal@25449 452 inc dx
pascal@25449 453
pascal@25449 454 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25450 455 idiv word [bx(bpbHeadsPerCylinder)]
pascal@25449 456 ; ax = (LBA / SPT) / HPC = cylinder
pascal@25449 457 ; dx = (LBA / SPT) % HPC = head
pascal@25449 458
pascal@25449 459 mov ch, al
pascal@25449 460 ; ch = LSB 0...7 of cylinder no.
pascal@25449 461 %if CHShardDisk != 0
pascal@25449 462 shl ah, 6
pascal@25449 463 or cl, ah
pascal@25449 464 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@25449 465 %endif
pascal@25449 466 mov dh, dl
pascal@25449 467 ; dh = head no.
pascal@25449 468 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25449 469 %endif
pascal@25449 470
pascal@24525 471 ReadSectorLBARetry:
pascal@24525 472 mov si, sp
pascal@24478 473 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 474 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 475 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 476
pascal@25449 477 %if CHSsupport != 0
pascal@25449 478 mov ax, 201h ; al = sector count = 1
pascal@25449 479 ; ah = 2 = read function no.
pascal@25449 480 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@25449 481
pascal@25449 482 jnc ReadSuccess ; CF = 0 if no error
pascal@25449 483 %endif
pascal@25449 484 %if ReadRetry != 0
pascal@25449 485 %if CHSsupport != 0
pascal@25449 486 cbw ; ah = 0 = reset function
pascal@25449 487 %else
pascal@24945 488 xor ax, ax ; ah = 0 = reset function
pascal@25449 489 %endif
pascal@24476 490 int 13h ; reset drive (DL)
pascal@24476 491
pascal@24525 492 dec bp
pascal@24525 493 jnz ReadSectorLBARetry
pascal@25449 494 %endif
pascal@24525 495
pascal@24476 496 call Error
pascal@24476 497 db "Read error."
pascal@24476 498
pascal@24478 499 ReadSuccess:
pascal@24476 500
pascal@24476 501 popa ; sp += 16
pascal@24478 502
pascal@24478 503 popa
pascal@24478 504
pascal@24476 505 stc
pascal@24478 506 loop ReadSectorNext
pascal@24476 507
pascal@24478 508 cmp esi, 0FFFFFF8h ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 509
pascal@24478 510 ReadSectorNext:
pascal@24476 511 ret
pascal@24476 512
pascal@24942 513 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 514 ;; Fill free space with zeroes ;;
pascal@24942 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 516
pascal@24942 517 times (512-13-20-($-$$)) db 0
pascal@24942 518
pascal@24476 519 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 520 ;; Error Messaging Code ;;
pascal@24476 521 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 522
pascal@24476 523 Error:
pascal@24476 524 pop si
pascal@24478 525 puts:
pascal@24476 526 mov ah, 0Eh
pascal@24476 527 mov bl, 7
pascal@24476 528 lodsb
pascal@24476 529 int 10h
pascal@24478 530 cmp al, '.'
pascal@24478 531 jne puts
pascal@24476 532 cbw
pascal@24535 533 int 16h ; wait for a key...
pascal@24535 534 int 19h ; bootstrap
pascal@24525 535
pascal@24525 536 Stop:
pascal@24525 537 hlt
pascal@24525 538 jmp short Stop
pascal@24476 539
pascal@24476 540 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 541 ;; Name of the file to load and run ;;
pascal@24476 542 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 543
pascal@24476 544 ProgramName db "STARTUP BIN" ; name and extension each must be
pascal@25449 545 times (510-($-$$)) db ' ' ; padded with spaces (11 bytes total)
pascal@24476 546
pascal@24476 547 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 548 ;; End of the sector ID ;;
pascal@24476 549 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 550
pascal@24476 551 dw 0AA55h ; BIOS checks for this ID