wok annotate BootProg/stuff/boot16.asm @ rev 25698

Up beep (1.4.12), gsoap (2.8.134), perl-test-warnings (0.033)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Sun May 26 08:12:35 2024 +0000 (4 weeks ago)
parents 9d807f162a22
children 65c2646b484d
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@25569 14 ;; - FAT12 and/or FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@25572 26 ;; - cpu 8088 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@25564 29 ;; Known Limitation: ;;
pascal@25564 30 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 31 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 32 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 33 ;; ;;
pascal@25572 34 ;; - Partition must fit in the first 8GB of the disk for CHS reads. ;;
pascal@25569 35 ;; (or 2TB for LBA reads). ;;
pascal@25564 36 ;; ;;
pascal@25564 37 ;; ;;
pascal@24476 38 ;; Known Bugs: ;;
pascal@24476 39 ;; ~~~~~~~~~~~ ;;
pascal@24476 40 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 41 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 42 ;; - 360KB 5"25 ;;
pascal@24476 43 ;; - 1.2MB 5"25 ;;
pascal@24476 44 ;; - 1.44MB 3"5 ;;
pascal@24476 45 ;; on my HDD (FAT16). ;;
pascal@24476 46 ;; ;;
pascal@24476 47 ;; ;;
pascal@24476 48 ;; Memory Layout: ;;
pascal@24476 49 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 50 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 51 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 52 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 53 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 54 ;; ;;
pascal@24476 55 ;; physical address ;;
pascal@24476 56 ;; +------------------------+ 00000H ;;
pascal@24476 57 ;; | Interrupt Vector Table | ;;
pascal@24476 58 ;; +------------------------+ 00400H ;;
pascal@24476 59 ;; | BIOS Data Area | ;;
pascal@24476 60 ;; +------------------------+ 00500H ;;
pascal@24476 61 ;; | PrtScr Status / Unused | ;;
pascal@24476 62 ;; +------------------------+ 00600H ;;
pascal@24476 63 ;; | Loaded Image | ;;
pascal@24476 64 ;; +------------------------+ nnnnnH ;;
pascal@24476 65 ;; | Available Memory | ;;
pascal@24476 66 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 67 ;; | Boot Sector | ;;
pascal@24476 68 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 69 ;; | 3KB Boot Stack | ;;
pascal@24476 70 ;; +------------------------+ A0000H ;;
pascal@24476 71 ;; | Video RAM | ;;
pascal@24476 72 ;; ;;
pascal@24476 73 ;; ;;
pascal@24476 74 ;; Boot Image Startup (register values): ;;
pascal@24476 75 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 76 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 77 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 78 ;; cs:ip = program entry point ;;
pascal@24476 79 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 80 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 81 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 82 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 83 ;; Magic numbers: ;;
pascal@24476 84 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 85 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 86 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 87 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 88 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 89 ;; metal and MS-DOS programs. ;;
pascal@24945 90 ;; The command line contains no arguments. ;;
pascal@24476 91 ;; ;;
pascal@24476 92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 93
pascal@24476 94 %define bx(label) bx+label-boot
pascal@25450 95 %define si(label) si+label-boot
pascal@25458 96 NullEntryCheck equ 1 ; +2 bytes
pascal@25569 97 ReadRetry equ 1 ; +9/+13 bytes
pascal@25569 98 LBAsupport equ 1 ; +18 bytes
pascal@25578 99 CHSsanityCheck equ 1 ; +9/+13 bytes
pascal@25569 100 GeometryCheck equ 1 ; +20 bytes
pascal@25564 101 CheckAttrib equ 0 ; +6 bytes
pascal@25564 102 WaitForKey equ 0 ; +5 bytes
pascal@25550 103 SectorOf512Bytes equ 0 ; -4/-6 bytes
pascal@25564 104 Always2FATs equ 0 ; -1 bytes
pascal@25698 105 AnyWhere equ 1 ; +4 bytes
pascal@24476 106
pascal@24476 107 [BITS 16]
pascal@24476 108 [CPU 8086]
pascal@24476 109
pascal@24476 110 ImageLoadSeg equ 60h
pascal@24476 111 StackSize equ 3072 ; Stack + cluster list
pascal@24476 112
pascal@24476 113 [SECTION .text]
pascal@24476 114 [ORG 0]
pascal@24476 115
pascal@24476 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 117 ;; Boot sector starts here ;;
pascal@24476 118 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 119
pascal@24476 120 boot:
pascal@25450 121 DriveNumber:
pascal@24476 122 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 123 nop
pascal@24476 124 bsOemName DB "BootProg" ; 0x03
pascal@24476 125
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 127 ;; BPB starts here ;;
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 129
pascal@25564 130 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 131 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32 or 64
pascal@25564 132 bpbReservedSectors DW 0 ; 0x0E 1
pascal@25564 133 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@24479 134 bpbRootEntries DW 0 ; 0x11
pascal@24479 135 bpbTotalSectors DW 0 ; 0x13
pascal@24479 136 bpbMedia DB 0 ; 0x15
pascal@24479 137 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 138 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 139 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 140 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 141 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 142
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;
pascal@24476 144 ;; BPB ends here ;;
pascal@24476 145 ;;;;;;;;;;;;;;;;;;;
pascal@24476 146
pascal@24479 147 bsDriveNumber DB 0 ; 0x24
pascal@24479 148 bsUnused DB 0 ; 0x25
pascal@25564 149 bsExtBootSignature DB 0 ; 0x26 29
pascal@24479 150 bsSerialNumber DD 0 ; 0x27
pascal@25458 151 bsVolumeLabel times 11 DB " " ; 0x2B "NO NAME "
pascal@25458 152 bsFileSystem times 8 DB " " ; 0x36 "FAT12 " or "FAT16 "
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Boot sector code starts here ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 start:
pascal@24476 159
pascal@24476 160 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 161 ;; How much RAM is there? ;;
pascal@24476 162 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 163
pascal@24476 164 int 12h ; get conventional memory size (in KBs)
pascal@25698 165 %if AnyWhere
pascal@25698 166 call here
pascal@25698 167 here:
pascal@25698 168 pop si
pascal@25698 169 sub si, here - boot
pascal@25698 170 push cs
pascal@25698 171 pop ds
pascal@25698 172 %endif
pascal@24476 173 mov cx, 106h
pascal@24476 174 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 175
pascal@24476 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 177 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 179
pascal@24476 180 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 181 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 182 mov ss, ax
pascal@24476 183 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 184
pascal@24476 185 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 186 ;; Copy ourselves to top of memory ;;
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188
pascal@25698 189 xor di, di
pascal@25698 190 %if AnyWhere == 0
pascal@24476 191 mov si, 7C00h
pascal@24476 192 mov ds, di
pascal@25698 193 %endif
pascal@25450 194 push es
pascal@25450 195 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@25698 196 cld
pascal@24476 197 rep movsw ; move 512 bytes (+ 12)
pascal@24476 198
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200 ;; Jump to the copy ;;
pascal@24476 201 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 202
pascal@24476 203 mov cl, byte main
pascal@24476 204 push cx
pascal@24476 205 retf
pascal@24476 206
pascal@24476 207 main:
pascal@24476 208 %if ImageLoadSeg != main-boot
pascal@24476 209 %if ImageLoadSeg >= 100h
pascal@24476 210 mov cx, ImageLoadSeg
pascal@24476 211 %else
pascal@24476 212 mov cl, ImageLoadSeg
pascal@24476 213 %endif
pascal@24476 214 %endif
pascal@24476 215 push cx
pascal@24476 216
pascal@24476 217 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 218 ;; Get drive parameters ;;
pascal@24476 219 ;; Update heads count ;;
pascal@24476 220 ;; for current BIOS ;;
pascal@24476 221 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 222
pascal@25450 223 %if GeometryCheck != 0
pascal@25564 224 %if ((main-boot) & 3Fh) != 0
pascal@25569 225 xor cx, cx
pascal@25564 226 %endif
pascal@25564 227 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 228 int 13h ; may destroy SI,BP, and DS registers
pascal@25450 229 %endif
pascal@24476 230 push cs
pascal@24476 231 pop ds
pascal@24476 232 xor bx, bx
pascal@24476 233
pascal@25450 234 %if GeometryCheck != 0
pascal@24479 235 and cx, byte 3Fh
pascal@25564 236 je BadParams ; verify updated and validity
pascal@25564 237 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 238 mov cl, dh
pascal@25564 239 inc cx
pascal@25564 240 mov [bx(bpbHeadsPerCylinder)], cx
pascal@24476 241 BadParams:
pascal@25450 242 %endif
pascal@24476 243
pascal@24476 244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 245 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 246 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 247
pascal@24476 248 pop es ; ImageLoadSeg
pascal@24476 249 push es
pascal@24476 250
pascal@24476 251 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@25458 252 mov di, word [bx(bpbSectorsPerFAT)]
pascal@24476 253
pascal@25458 254 call ReadDISectors ; read fat; clear ax, cx, di; bp = SectorsPerFAT
pascal@24476 255
pascal@24476 256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 257 ;; load the root directory in ;;
pascal@24476 258 ;; its entirety (16KB max) ;;
pascal@24476 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 260
pascal@25458 261 %if SectorOf512Bytes != 0
pascal@25458 262 mov di, word [bx(bpbRootEntries)]
pascal@25458 263 mov cl, 4
pascal@25458 264 shr di, cl ; di = root directory size in sectors
pascal@25458 265 %else
pascal@24942 266 mov al, 32
pascal@24476 267
pascal@24476 268 mul word [bx(bpbRootEntries)]
pascal@24476 269 div word [bx(bpbBytesPerSector)]
pascal@25458 270 xchg ax, di ; di = root directory size in sectors, clear ah
pascal@25458 271 %endif
pascal@24476 272
pascal@25564 273 %if Always2FATs != 0
pascal@25564 274 mov al, 2
pascal@25564 275 %else
pascal@24476 276 mov al, [bpbNumberOfFATs]
pascal@25564 277 %endif
pascal@25458 278 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadDISectors
pascal@24476 279
pascal@25457 280 push es ; read root directory
pascal@25458 281 call ReadDISectors ; clear ax, cx, di; bp = first data sector
pascal@24476 282 pop es
pascal@24476 283
pascal@24476 284 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 285 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 286 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 287
pascal@24476 288 ; es:di -> root entries array
pascal@24476 289
pascal@24476 290 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 291 ;; Looks for the file/dir ProgramName ;;
pascal@24476 292 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 293 ;; Input: ES:DI -> root directory array ;;
pascal@24476 294 ;; Output: SI = cluster number ;;
pascal@24476 295 ;; AX = file sector count ;;
pascal@24476 296 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 297
pascal@24476 298 FindNameCycle:
pascal@24476 299 push di
pascal@25454 300 mov cl, NameLength
pascal@24476 301 mov si, ProgramName ; ds:si -> program name
pascal@24476 302 repe cmpsb
pascal@25467 303 %if CheckAttrib != 0
pascal@25467 304 VolumeLabel equ 8
pascal@25467 305 SubDirectory equ 10h
pascal@25467 306 jnz SkipFindName
pascal@25467 307 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 308 SkipFindName:
pascal@25467 309 %endif
pascal@24476 310 pop di
pascal@24476 311 je FindNameFound
pascal@25450 312 %if NullEntryCheck != 0
pascal@25564 313 scasb ; Z == NC
pascal@25458 314 cmc
pascal@25458 315 lea di, [di+31]
pascal@25458 316 dec word [bx(bpbRootEntries)]
pascal@25458 317 ja FindNameCycle ; next root entry
pascal@25450 318 %else
pascal@25450 319 add di, byte 32
pascal@24476 320 dec word [bx(bpbRootEntries)]
pascal@24476 321 jnz FindNameCycle ; next root entry
pascal@25458 322 %endif
pascal@24476 323
pascal@24476 324 FindNameFailed:
pascal@24476 325 call Error
pascal@24476 326 db "File not found."
pascal@24476 327
pascal@24476 328 FindNameFound:
pascal@24476 329 push si
pascal@24476 330 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 331 les ax, [es:di+1Ch] ; file size
pascal@24476 332 mov dx, es
pascal@24476 333 div word [bx(bpbBytesPerSector)]
pascal@24476 334 cmp bx, dx ; sector aligned ?
pascal@24476 335 adc ax, bx ; file last sector
pascal@24476 336 pop di ; di = ClusterList
pascal@24476 337
pascal@24476 338 pop es ; ImageLoadSeg
pascal@24476 339 push ax
pascal@24476 340
pascal@24476 341 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 342 ;; build cluster list ;;
pascal@24476 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 344 ;; Input: ES:0 -> FAT ;;
pascal@24476 345 ;; SI = first cluster ;;
pascal@24476 346 ;; DI = cluster list :;
pascal@24476 347 ;; CH = 0 ;;
pascal@24476 348 ;; Output: SI = cluster list ;;
pascal@24476 349 ;; CH = 0 ;;
pascal@24476 350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 351
pascal@25458 352 FAT12 equ 1
pascal@25458 353 FAT16 equ 1
pascal@25550 354 TINYFAT16 equ 1 ; < 4072 clusters fat16 support
pascal@25453 355 push di ; up to 2 * 635K / BytesPerCluster = 2540 bytes
pascal@25572 356 %if FAT12 != 1 && FAT16 != 1
pascal@25572 357 %error "FAT12 and/or FAT16 must be set"
pascal@25572 358 %endif
pascal@25450 359 %if FAT12 == 1
pascal@25454 360 mov cl, 12
pascal@25564 361 %else
pascal@25564 362 nop
pascal@25564 363 nop
pascal@25450 364 %endif
pascal@24476 365 ClusterLoop:
pascal@24476 366 mov [di], si
pascal@25450 367 add si, si ; si = cluster * 2
pascal@25450 368 %if FAT16 == 1
pascal@24476 369 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@25094 370 jnc First64k
pascal@24476 371 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 372 First64k:
pascal@25453 373 %if FAT12 == 1
pascal@25457 374 mov dx, 0FFF6h
pascal@25454 375 %if TINYFAT16 == 1
pascal@25550 376 test [bx(bsFileSystem+4)], cl ; FAT12 or FAT16 ? clear C (bit 2)
pascal@25458 377 jne ReadClusterFat16
pascal@25454 378 %else
pascal@25454 379 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@25458 380 ja ReadClusterFat16
pascal@25454 381 %endif
pascal@24942 382 mov dh, 0Fh
pascal@25453 383 %endif
pascal@25450 384 %endif
pascal@25450 385 %if FAT12 == 1
pascal@25087 386 add si, [di]
pascal@24476 387 shr si, 1 ; si = cluster * 3 / 2
pascal@25564 388 %else
pascal@25564 389 nop
pascal@25564 390 nop
pascal@25450 391 %endif
pascal@25450 392 %if FAT16 == 1
pascal@24942 393 ReadClusterFat16:
pascal@25094 394 push ds
pascal@25087 395 mov ds, ax
pascal@24476 396 lodsw ; ax = next cluster
pascal@25094 397 pop ds
pascal@25450 398 %else
pascal@25453 399 es lodsw
pascal@25450 400 %endif
pascal@25450 401 %if FAT12 == 1
pascal@24476 402 jnc ReadClusterEven
pascal@25454 403 rol ax, cl
pascal@24476 404 ReadClusterEven:
pascal@25094 405 scasw ; di += 2
pascal@25454 406 %if FAT16 == 1
pascal@24942 407 and ah, dh ; mask cluster value
pascal@24942 408 cmp ax, dx
pascal@25454 409 %else
pascal@25453 410 and ah, 0Fh ; mask cluster value
pascal@25457 411 cmp ax, 0FF6h
pascal@25454 412 %endif
pascal@25454 413 %else
pascal@25454 414 scasw ; di += 2
pascal@25457 415 cmp ax, 0FFF6h
pascal@25453 416 %endif
pascal@24476 417 xchg ax, si
pascal@24476 418 jc ClusterLoop
pascal@24476 419 pop si
pascal@24476 420 pop di ; file size in sectors
pascal@24476 421
pascal@24476 422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 423 ;; Load the entire file ;;
pascal@24476 424 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 425 ;; Input: ES:0 -> buffer ;;
pascal@24476 426 ;; SI = cluster list ;;
pascal@24476 427 ;; DI = file sectors ;;
pascal@24476 428 ;; CH = 0 ;;
pascal@24945 429 ;; BP = 1st data sec ;;
pascal@24476 430 ;; Output: BP:0 -> buffer ;;
pascal@24476 431 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 432
pascal@24476 433 push es
pascal@24476 434
pascal@24476 435 ReadClusters:
pascal@24476 436 lodsw
pascal@24476 437 dec ax
pascal@24476 438 dec ax
pascal@24476 439
pascal@25454 440 mov cl, [bx(bpbSectorsPerCluster)] ; 1..128
pascal@24476 441 mul cx ; cx = sector count (ch = 0)
pascal@24476 442
pascal@24476 443 add ax, bp ; LBA for cluster data
pascal@24476 444 adc dx, bx ; dx:ax = LBA
pascal@24476 445
pascal@25458 446 call ReadSectors ; clear ax, restore dx
pascal@24476 447
pascal@25458 448 jne ReadClusters ; until end of file
pascal@24476 449
pascal@24476 450 pop bp ; ImageLoadSeg
pascal@24476 451
pascal@24476 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 453 ;; Type detection, .COM or .EXE? ;;
pascal@24476 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 455
pascal@24476 456 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 457
pascal@24476 458 add bp, [bx+08h] ; bp = image base
pascal@24476 459 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 460
pascal@24476 461 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 462 je RelocateEXE ; yes, it's an EXE program
pascal@24476 463
pascal@24476 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 465 ;; Setup and run a .COM program ;;
pascal@24476 466 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 467 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 468 ;; cmdline=void ;;
pascal@24476 469 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 470
pascal@24942 471 mov di, 100h ; ip
pascal@24476 472 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 473 mov ss, bp
pascal@24476 474 xor sp, sp
pascal@24476 475 push bp ; cs, ds and es
pascal@24476 476 jmp short Run
pascal@24476 477
pascal@24476 478 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 479 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 480 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 481 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 482 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 483 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 484
pascal@24476 485 ReloCycle:
pascal@24476 486 add [di+2], bp ; item seg (abs)
pascal@24476 487 les si, [di] ; si = item ofs, es = item seg
pascal@24476 488 add [es:si], bp ; fixup
pascal@24476 489 scasw ; di += 2
pascal@24476 490 scasw ; point to next entry
pascal@24476 491
pascal@24476 492 RelocateEXE:
pascal@24942 493 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 494 jns ReloCycle
pascal@24476 495 ; PSP don't have a valid drive identifier
pascal@24476 496 les si, [bx+0Eh]
pascal@24476 497 add si, bp
pascal@24476 498 mov ss, si ; ss for EXE
pascal@24476 499 mov sp, es ; sp for EXE
pascal@24476 500
pascal@24476 501 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 502 push si ; containing the PSP structure
pascal@24476 503
pascal@24476 504 add bp, [bx+16h] ; cs for EXE
pascal@24942 505 mov di, [bx+14h] ; ip for EXE
pascal@24476 506 Run:
pascal@24476 507 pop ds
pascal@24476 508 push bp
pascal@24942 509 push di
pascal@24476 510 push ds
pascal@24476 511 pop es
pascal@24942 512 mov [80h], ax ; clear cmdline
pascal@24942 513 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 514
pascal@24476 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 516 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 517 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 519 mov si, 16381 ; prime number 2**14-3
pascal@24476 520 mov di, 32749 ; prime number 2**15-19
pascal@24476 521 mov bp, 65521 ; prime number 2**16-15
pascal@24476 522
pascal@24476 523 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 524 ;; All done, transfer control to the program now ;;
pascal@24476 525 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 526 retf
pascal@24476 527
pascal@25458 528 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 529 ;; Error Messaging Code ;;
pascal@25458 530 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 531
pascal@25458 532 Error:
pascal@25458 533 pop si
pascal@25458 534
pascal@25458 535 PutStr:
pascal@25458 536 mov ah, 0Eh
pascal@25458 537 mov bl, 7
pascal@25458 538 lodsb
pascal@25458 539 int 10h
pascal@25458 540 cmp al, "."
pascal@25458 541 jne PutStr
pascal@25564 542 %if WaitForKey != 0
pascal@25458 543 cbw
pascal@25458 544 int 16h ; wait for a key...
pascal@25458 545 int 19h ; bootstrap
pascal@25564 546 %endif
pascal@25458 547 Stop:
pascal@25458 548 hlt
pascal@25458 549 jmp short Stop
pascal@25458 550
pascal@25458 551 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 552 ;; Read sectors using BIOS Int 13h ;;
pascal@25458 553 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 554 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@25458 555 ;; BX = 0 ;;
pascal@25458 556 ;; DI = sector count ;;
pascal@25458 557 ;; ES:BX -> buffer address ;;
pascal@25458 558 ;; Output: ES:BX -> next address ;;
pascal@25458 559 ;; BX = 0 ;;
pascal@25458 560 ;; CX = 0 ;;
pascal@25458 561 ;; DI = 0 ;;
pascal@25458 562 ;; DL = drive number ;;
pascal@25564 563 ;; 0:BP = next LBA from FAT ;;
pascal@25458 564 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 565
pascal@25458 566 ReadDISectors:
pascal@25458 567 mov bp, di
pascal@24476 568 add bp, ax ; adjust LBA for cluster data
pascal@24476 569
pascal@25458 570 mov cx, di ; no cluster size limit
pascal@24476 571
pascal@24476 572 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 573 ;; Read sectors using BIOS Int 13h ;;
pascal@24476 574 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 575 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 576 ;; BX = 0 ;;
pascal@24476 577 ;; CX = sector count ;;
pascal@24476 578 ;; DI = file sectors ;;
pascal@24476 579 ;; ES:BX -> buffer address ;;
pascal@24476 580 ;; Output: ES:BX -> next address ;;
pascal@24476 581 ;; BX = 0 ;;
pascal@24476 582 ;; CX or DI = 0 ;;
pascal@24476 583 ;; DL = drive number ;;
pascal@25564 584 ;; Keep: BP, SI ;;
pascal@24476 585 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 586
pascal@25458 587 ReadSectors:
pascal@24476 588 add ax, [bx(bpbHiddenSectors)]
pascal@24476 589 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 590 add ax, [bx(bpbReservedSectors)]
pascal@24476 591
pascal@24476 592 push si
pascal@24476 593 ReadSectorNext:
pascal@24476 594 adc dx, bx
pascal@24476 595 push di
pascal@24476 596 push cx
pascal@24476 597
pascal@25450 598 %if LBAsupport != 0
pascal@24476 599 push bx
pascal@24476 600 push bx
pascal@25450 601 %endif
pascal@24476 602 push dx ; 32-bit LBA: up to 2TB
pascal@24476 603 push ax
pascal@24476 604 push es
pascal@25450 605 %if ReadRetry != 0 || LBAsupport != 0
pascal@25450 606 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 607 %endif
pascal@25450 608 %if LBAsupport != 0
pascal@24476 609 push bx
pascal@24476 610 inc bx ; sector count word = 1
pascal@24476 611 push bx
pascal@24476 612 dec bx
pascal@24476 613 push di
pascal@25450 614 %endif
pascal@24476 615
pascal@24476 616 xchg ax, cx ; save low LBA
pascal@24476 617 xchg ax, dx ; get high LBA
pascal@25452 618 cwd ; clear dx (LBA offset <1TB)
pascal@25450 619 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 620
pascal@25569 621 %if CHSsanityCheck != 0
pascal@25564 622 cmp ax, [bx(bpbHeadsPerCylinder)]
pascal@25578 623 jns CHSoverflow
pascal@25569 624 %endif
pascal@24476 625 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25450 626 idiv word [bx(bpbSectorsPerTrack)]
pascal@24476 627 ; ax = LBA / SPT
pascal@24476 628 ; dx = LBA % SPT = sector - 1
pascal@24476 629 inc dx
pascal@24476 630
pascal@24476 631 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25564 632 idiv word [bx(bpbHeadsPerCylinder)] ; may overflow if SectorsPerTrack * HeadsPerCylinder < 256 or disk > 8GB
pascal@24476 633 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 634 ; dx = (LBA / SPT) % HPC = head
pascal@25458 635
pascal@25578 636 xchg ch, al ; clear al, save cylinder no.
pascal@24476 637 ; ch = LSB 0...7 of cylinder no.
pascal@25458 638 shr ax, 1
pascal@25458 639 shr ax, 1
pascal@24476 640 or cl, al
pascal@24476 641 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 642 mov dh, dl
pascal@24476 643 ; dh = head no.
pascal@24476 644
pascal@25564 645 %if CHSsanityCheck != 0
pascal@25578 646 dec ah ; set S if cylinder < 1024 (8GB max)
pascal@25572 647 CHSoverflow:
pascal@25564 648 %endif
pascal@25572 649 mov si, sp
pascal@25569 650 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 651 pushf
pascal@25564 652 %endif
pascal@25564 653
pascal@25564 654 ReadSectorRetry:
pascal@25569 655 mov dl, [bx(DriveNumber)]
pascal@25569 656 ; dl = drive no.
pascal@25450 657 %if LBAsupport != 0
pascal@24476 658 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 659 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 660 jnc ReadSectorNextSegment
pascal@25450 661 %endif
pascal@25572 662 mov ax, 201h ; al = sector count = 1
pascal@25572 663 ; ah = 2 = read function no.
pascal@25564 664 %if CHSsanityCheck != 0
pascal@25564 665 %if ReadRetry != 0 || LBAsupport != 0
pascal@25564 666 popf
pascal@25564 667 pushf
pascal@25564 668 %endif
pascal@25578 669 jns SkipCHS
pascal@25564 670 %endif
pascal@24476 671 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 672 jnc ReadSectorNextSegment
pascal@25564 673 SkipCHS:
pascal@25450 674 %if ReadRetry != 0
pascal@24476 675 cbw ; ah = 0 = reset function
pascal@24476 676 int 13h ; reset drive (DL)
pascal@24476 677 dec di
pascal@25457 678 jnz ReadSectorRetry ; up to 15 extra attempt
pascal@25450 679 %endif
pascal@24476 680
pascal@25564 681 ReadError:
pascal@24476 682 call Error
pascal@24476 683 db "Read error."
pascal@24476 684
pascal@24476 685 ReadSectorNextSegment:
pascal@25564 686 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 687 popf
pascal@25564 688 %endif
pascal@25564 689
pascal@25564 690 %macro adjust_es 2
pascal@25564 691 %if SectorOf512Bytes != 0
pascal@25564 692 add word %1, byte 32 ; adjust segment for next sector
pascal@25564 693 %else
pascal@25564 694 %if %2 != 0
pascal@25564 695 mov al, %2
pascal@25564 696 %endif
pascal@25564 697 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25564 698 add %1, ax ; adjust segment for next sector
pascal@25564 699 %endif
pascal@25564 700 %endmacro
pascal@24476 701
pascal@25450 702 %if LBAsupport != 0
pascal@24476 703 pop ax ; al = 16
pascal@25564 704 adjust_es [si+6], 0
pascal@24476 705 pop cx ; sector count = 1
pascal@24476 706 pop bx
pascal@25450 707 %else
pascal@25564 708 adjust_es [si], 16
pascal@25450 709 %endif
pascal@24476 710 pop es ; es:0 updated
pascal@24476 711 pop ax
pascal@24476 712 pop dx
pascal@25450 713 %if LBAsupport != 0
pascal@24476 714 pop di
pascal@24476 715 pop di
pascal@24476 716 add ax, cx ; adjust LBA for next sector
pascal@25450 717 %else
pascal@25450 718 add ax, 1 ; adjust LBA for next sector
pascal@25450 719 %endif
pascal@24476 720
pascal@24476 721 pop cx ; cluster sectors to read
pascal@24476 722 pop di ; file sectors to read
pascal@24476 723 dec di ; keep C
pascal@25457 724 loopne ReadSectorNext ; until cluster sector count or file sector count
pascal@24476 725 pop si
pascal@24942 726 mov ax, bx ; clear ax
pascal@25450 727 mov dx, [bx(DriveNumber)] ; pass the BIOS boot drive to Run or Error
pascal@24476 728
pascal@24476 729 ret
pascal@24476 730
pascal@24942 731 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 732 ;; Fill free space with zeroes ;;
pascal@24942 733 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 734
pascal@25458 735 times (512-13-($-$$)) db 0
pascal@24476 736
pascal@24476 737 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 738 ;; Name of the file to load and run ;;
pascal@24476 739 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 740
pascal@25463 741 NameLength equ 11
pascal@25463 742 ProgramName times NameLength db 0 ; name and extension
pascal@24476 743
pascal@24476 744 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 745 ;; End of the sector ID ;;
pascal@24476 746 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 747
pascal@24476 748 ClusterList dw 0AA55h ; BIOS checks for this ID