wok-current annotate BootProg/stuff/bootex.asm @ rev 25467

Up gnumeric (1.12.53)
author Pascal Bellard <pascal.bellard@slitaz.org>
date Mon Oct 03 08:28:51 2022 +0000 (21 months ago)
parents 81fc994927a6
children b0069c845544
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 19 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@25460 51 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@25460 53 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 54 ;; | 0.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 61 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 62 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 63 ;; cs:ip = program entry point ;;
pascal@24476 64 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 65 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 66 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24945 75 ;; The command line contains no arguments. ;;
pascal@24476 76 ;; ;;
pascal@24476 77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 78
pascal@24476 79 %define bx(label) bx+label-boot
pascal@25450 80 %define si(label) si+label-boot
pascal@25450 81 NullEntryCheck equ 1 ; +3 bytes
pascal@25450 82 ReadRetry equ 1 ; +8 bytes
pascal@25458 83 SectorOf512Bytes equ 1 ; -13 bytes
pascal@25467 84 CheckAttrib equ 0 ; +6 bytes
pascal@24476 85
pascal@24476 86 [BITS 16]
pascal@24476 87 [CPU 386]
pascal@24476 88
pascal@24476 89 ImageLoadSeg equ 60h
pascal@25460 90 StackSize equ 512
pascal@24476 91
pascal@24476 92 [SECTION .text]
pascal@24476 93 [ORG 0]
pascal@24476 94
pascal@24476 95 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 96 ;; Boot sector starts here ;;
pascal@24476 97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 98
pascal@24476 99 boot:
pascal@25450 100 DriveNumber:
pascal@24476 101 jmp short start ; Windows checks for this jump
pascal@24476 102 nop
pascal@25458 103 bsOemName times 8 db " " ; 0x03 "EXFAT "
pascal@24476 104 times 53 db 0 ; 0x0B
pascal@24476 105
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107 ;; BPB starts here ;;
pascal@24476 108 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 109
pascal@24479 110 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 111 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 112 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 113 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 114 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 115 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 116 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 117 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 118 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 119 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 120 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 121 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 122 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 123 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 124 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 125 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 126
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;
pascal@24476 128 ;; BPB ends here ;;
pascal@24476 129 ;;;;;;;;;;;;;;;;;;;
pascal@24476 130
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 132 ;; Boot sector code starts here ;;
pascal@24476 133 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 134
pascal@24476 135 start:
pascal@24476 136 cld
pascal@24476 137
pascal@24476 138 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 139 ;; How much RAM is there? ;;
pascal@24476 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 141
pascal@24476 142 int 12h ; get conventional memory size (in KBs)
pascal@24476 143 mov cx, 106h
pascal@25460 144 dec ax ; reserve 1K bytes for the code and the stack
pascal@24476 145 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 152 mov ss, ax
pascal@24476 153 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 154
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156 ;; Copy ourselves to top of memory ;;
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158
pascal@24476 159 mov si, 7C00h
pascal@24476 160 xor di, di
pascal@24476 161 mov ds, di
pascal@25450 162 push es
pascal@25450 163 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 164 rep movsw ; move 512 bytes (+ 12)
pascal@24476 165
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167 ;; Jump to the copy ;;
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169
pascal@24942 170 push word main
pascal@24476 171 retf
pascal@24476 172
pascal@24476 173 main:
pascal@24476 174 push cs
pascal@24476 175 pop ds
pascal@24476 176
pascal@24476 177 xor ebx, ebx
pascal@24476 178
pascal@24476 179 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 180
pascal@24479 181 push byte ImageLoadSeg
pascal@24942 182 pop es ; cx = 0
pascal@24476 183
pascal@24476 184 RootDirReadContinue:
pascal@24476 185 call ReadCluster ; read one sector of root dir
pascal@24476 186
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190
pascal@25454 191 ; es:di -> root entries array
pascal@24476 192
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194 ;; Looks for the file/dir ProgramName ;;
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196 ;; Input: ES:DI -> root directory array ;;
pascal@24476 197 ;; Output: ESI = cluster number ;;
pascal@24476 198 ;; dword [bx+FileSize] file size ;;
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200
pascal@25467 201 CurNameSize equ 03h ; 1 byte
pascal@25467 202 Attributes equ 0Bh ; 1 byte
pascal@25450 203 StartCluster equ 14h ; 4 bytes
pascal@25450 204 FileSize equ 18h ; 8 bytes
pascal@24476 205
pascal@24476 206 FindNameCycle:
pascal@24476 207 pusha
pascal@24476 208
pascal@25450 209 %if NullEntryCheck != 0
pascal@24476 210 xor ax, ax
pascal@24476 211 or al, [es:di]
pascal@24476 212 je FindNameFailed
pascal@25467 213 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@25450 214 %else
pascal@25467 215 cmp byte [es:di], 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@25450 216 %endif
pascal@24476 217 jne NotFileInfo
pascal@24476 218
pascal@24942 219 mov bl, 31
pascal@24476 220 CopyInfo:
pascal@24942 221 mov al, [es:di+bx]
pascal@24942 222 mov [bx], al
pascal@24476 223 dec bx
pascal@25450 224 jnz CopyInfo ; keep BIOS boot drive number
pascal@24476 225
pascal@24476 226 NotFileInfo:
pascal@25467 227 %if NullEntryCheck != 0
pascal@24476 228 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@25467 229 %else
pascal@25467 230 mov ax, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@25467 231 %endif
pascal@24476 232 mov cx, NameLength+1
pascal@24476 233 mov si, ProgramName ; ds:si -> program name
pascal@24476 234 CheckName:
pascal@24476 235 scasw ; compare UTF-16
pascal@24476 236 lodsb ; with ASCII
pascal@24476 237 loope CheckName
pascal@25467 238 %if CheckAttrib != 0
pascal@25467 239 VolumeLabel equ 8
pascal@25467 240 SubDirectory equ 10h
pascal@25467 241 jnz SkipFindName
pascal@25467 242 test byte [bx+Attributes], VolumeLabel+SubDirectory
pascal@25467 243 SkipFindName:
pascal@25467 244 %endif
pascal@24476 245 je FindNameFound ; cx = 0
pascal@24476 246 popa ; restore ax, cx, si, di
pascal@24476 247
pascal@24479 248 add di, byte 32
pascal@24945 249 cmp di, bp
pascal@24945 250 jne FindNameCycle ; next root entry
pascal@25458 251 loop RootDirReadContinue ; continue to the next root dir sector
pascal@25458 252 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 253 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 254 FindNameFailed: ; end of root directory (dir end reached)
pascal@25454 255 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 256 call Error
pascal@24476 257 db "File not found."
pascal@24476 258 FindNameFound:
pascal@24476 259 mov esi, [bx+StartCluster]
pascal@24476 260
pascal@24476 261 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 262 ;; Load the entire file ;;
pascal@24476 263 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 264
pascal@24476 265 push es
pascal@25458 266 %if SectorOf512Bytes == 0
pascal@24945 267 xor bp, bp
pascal@24476 268 FileReadContinue:
pascal@24476 269 shr bp, 4 ; bytes to paragraphs
pascal@24476 270 mov di, es
pascal@24476 271 add di, bp ; adjust segment for next sector
pascal@24476 272 mov es, di ; es:0 updated
pascal@25458 273 %else
pascal@25458 274 FileReadContinue:
pascal@25458 275 %endif
pascal@24943 276 call ReadCluster ; read one more sector of the boot file
pascal@25458 277 dec cx
pascal@25450 278 sub [bx+FileSize], ebp ; max FileSize is < 640KB : check low 32 bits only
pascal@25458 279 %if SectorOf512Bytes != 0
pascal@25458 280 mov bp, es
pascal@25458 281 lea bp, [bp+32]
pascal@25458 282 mov es, bp ; es:0 updated
pascal@25458 283 %endif
pascal@24476 284 ja FileReadContinue
pascal@25450 285 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25454 286 xchg ax, di
pascal@24476 287 pop bp
pascal@24476 288
pascal@24476 289 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 290 ;; Type detection, .COM or .EXE? ;;
pascal@24476 291 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 292
pascal@24476 293 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 294
pascal@24476 295 add bp, [bx+08h] ; bp = image base
pascal@24476 296 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 297
pascal@24476 298 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 299 je RelocateEXE ; yes, it's an EXE program
pascal@24476 300
pascal@24476 301 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 302 ;; Setup and run a .COM program ;;
pascal@24476 303 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 304 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 305 ;; cmdline=void ;;
pascal@24476 306 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 307
pascal@24525 308 mov di, 100h ; ip
pascal@24476 309 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 310 mov ss, bp
pascal@24476 311 xor sp, sp
pascal@24476 312 push bp ; cs, ds and es
pascal@24476 313 jmp short Run
pascal@24476 314
pascal@24476 315 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 316 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 317 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 318 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 319 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 320 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 321
pascal@24476 322 ReloCycle:
pascal@24476 323 add [di+2], bp ; item seg (abs)
pascal@24476 324 les si, [di] ; si = item ofs, es = item seg
pascal@24476 325 add [es:si], bp ; fixup
pascal@24476 326 scasw ; di += 2
pascal@24476 327 scasw ; point to next entry
pascal@24476 328
pascal@24476 329 RelocateEXE:
pascal@24942 330 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 331 jns ReloCycle
pascal@24942 332
pascal@24945 333 les si, [bx+0Eh]
pascal@24945 334 add si, bp
pascal@24945 335 mov ss, si ; ss for EXE
pascal@24945 336 mov sp, es ; sp for EXE
pascal@24476 337
pascal@24476 338 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 339 push si ; containing the PSP structure
pascal@24476 340
pascal@24476 341 add bp, [bx+16h] ; cs for EXE
pascal@24525 342 mov di, [bx+14h] ; ip for EXE
pascal@24476 343 Run:
pascal@24476 344 pop ds
pascal@24476 345 push bp
pascal@24525 346 push di
pascal@24476 347 push ds
pascal@24476 348 pop es
pascal@24942 349 mov [80h], ax ; clear cmdline
pascal@24942 350 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 351
pascal@24476 352 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 353 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 354 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 355 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 356 mov si, 16381 ; prime number 2**14-3
pascal@24476 357 mov di, 32749 ; prime number 2**15-19
pascal@24476 358 mov bp, 65521 ; prime number 2**16-15
pascal@24476 359
pascal@24476 360 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 361 ;; All done, transfer control to the program now ;;
pascal@24476 362 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 363 retf
pascal@24476 364
pascal@25458 365 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 366 ;; Error Messaging Code ;;
pascal@25458 367 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 368
pascal@25458 369 Error:
pascal@25458 370 pop si
pascal@25458 371
pascal@25458 372 PutStr:
pascal@25458 373 mov ah, 0Eh
pascal@25458 374 mov bl, 7
pascal@25458 375 lodsb
pascal@25458 376 int 10h
pascal@25458 377 cmp al, "."
pascal@25458 378 jne PutStr
pascal@25458 379
pascal@25458 380 cbw
pascal@25458 381 int 16h ; wait for a key...
pascal@25458 382 int 19h ; bootstrap
pascal@25458 383
pascal@25458 384 Stop:
pascal@25458 385 hlt
pascal@25458 386 jmp short Stop
pascal@25458 387
pascal@24476 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 389 ;; Reads a exFAT cluster ;;
pascal@24476 390 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 391 ;; Input: EDX:EAX = LBA ;;
pascal@24476 392 ;; EBX = 0 ;;
pascal@24476 393 ;; CX = sector cnt ;;
pascal@24476 394 ;; ESI = cluster no ;;
pascal@24476 395 ;; ES:0 -> buffer adrs ;;
pascal@24476 396 ;; Output: EBX = 0 ;;
pascal@24476 397 ;; CX = next cnt ;;
pascal@24476 398 ;; EBP = bytes/sector;;
pascal@24476 399 ;; ES:0 -> next adrs ;;
pascal@24476 400 ;; C=0 for last sector ;;
pascal@24476 401 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 402
pascal@24476 403 ReadCluster:
pascal@24945 404 add eax, byte 1
pascal@24945 405
pascal@24476 406 inc cx ; jcxnz
pascal@24476 407 loop ReadSectorC
pascal@24476 408
pascal@24945 409 mul ebx ; edx:eax = 0
pascal@25458 410 %if SectorOf512Bytes != 0
pascal@25458 411 mov al, 128
pascal@25458 412 %else
pascal@25452 413 mov cl, -2
pascal@25450 414 add cl, [bx(bpbSectorSizeBits)]
pascal@25450 415 bts ax, cx ; eax=# of exFAT entries per sector
pascal@25458 416 %endif
pascal@24476 417 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 418 xchg eax, esi
pascal@24476 419 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 420
pascal@24525 421 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 422
pascal@24476 423 cdq
pascal@25452 424 add eax, [bx(bpbFatSectorStart)] ; sector # relative to exFAT
pascal@25454 425 call ReadSectorFAT ; read 1 exFAT sector, keep edx=0, set C
pascal@24476 426
pascal@24476 427 mov esi, [es:si] ; esi=next cluster #
pascal@24476 428
pascal@25450 429 mov dl, [bx(bpbSectorPerClusterBits)]
pascal@25452 430 xor ecx, ecx
pascal@25450 431 bts ecx, edx ; 10000h max (32MB cluster)
pascal@24476 432 xchg eax, edi ; get cluster #-2
pascal@24476 433 mul ecx
pascal@24476 434
pascal@24476 435 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 436 ReadSectorC:
pascal@25454 437 mov di, bx
pascal@25454 438 ReadSectorFAT:
pascal@24476 439 adc edx, ebx
pascal@24476 440
pascal@24476 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 442 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 443 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 444 ;; Input: EDX:EAX = LBA ;;
pascal@24476 445 ;; BX = 0 ;;
pascal@24476 446 ;; CX = sector count ;;
pascal@24476 447 ;; ES:0 -> buffer address ;;
pascal@24476 448 ;; Output: BX = 0 ;;
pascal@24476 449 ;; CX = next count ;;
pascal@24476 450 ;; EBP = bytes/sector ;;
pascal@24476 451 ;; ES:0 -> next address ;;
pascal@24476 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 453
pascal@25458 454 %if SectorOf512Bytes != 0
pascal@25458 455 lea ebp, [bx+512]
pascal@25458 456 %else
pascal@25458 457 lea ebp, [bx+1]
pascal@25458 458 %endif
pascal@24476 459
pascal@24476 460 pushad
pascal@24476 461
pascal@24476 462 add eax, [bx(bpbSectorStart)]
pascal@24476 463 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 464
pascal@24476 465 push edx
pascal@24476 466 push eax
pascal@24476 467 push es
pascal@24476 468 push bx
pascal@25458 469 %if SectorOf512Bytes != 0
pascal@25458 470 push byte 1 ; sector count word = 1
pascal@25458 471 %else
pascal@24476 472 push bp ; sector count word = 1
pascal@25458 473 %endif
pascal@25454 474 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 475 ReadSectorRetry:
pascal@24476 476 mov si, sp
pascal@24476 477 mov ah, 42h ; ah = 42h = extended read function no.
pascal@25450 478 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 479 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 480
pascal@24476 481 jnc ReadSuccess
pascal@24476 482
pascal@25450 483 %if ReadRetry != 0
pascal@24476 484 xor ax, ax
pascal@24476 485 int 13h ; reset drive (DL)
pascal@25457 486 dec bp
pascal@25458 487 %if SectorOf512Bytes != 0
pascal@25458 488 jne ReadSectorRetry ; up to 511 tries
pascal@25458 489 %else
pascal@25457 490 jpe ReadSectorRetry ; up to 3 tries
pascal@25458 491 %endif
pascal@25450 492 %endif
pascal@24476 493
pascal@24476 494 call Error
pascal@24476 495 db "Read error."
pascal@24476 496
pascal@24476 497 ReadSuccess:
pascal@25458 498 %if SectorOf512Bytes == 0
pascal@24476 499 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 500 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@25458 501 %endif
pascal@24476 502 popa ; sp += 16
pascal@24476 503 popad ; real registers
pascal@24476 504 ret
pascal@24476 505
pascal@24942 506 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 507 ;; Fill free space with zeroes ;;
pascal@24942 508 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 509
pascal@25458 510 times (512-13-($-$$)) db 0
pascal@24476 511
pascal@24476 512 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 513 ;; Name of the file to load and run ;;
pascal@24476 514 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 515
pascal@25463 516 NameLength equ 11
pascal@25463 517 ProgramName times NameLength db 0 ; name and extension
pascal@24476 518
pascal@24476 519 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 520 ;; End of the sector ID ;;
pascal@24476 521 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 522
pascal@24476 523 dw 0AA55h ; BIOS checks for this ID