wok annotate BootProg/stuff/boot16.asm @ rev 25705

fusecloop/extract_compressed_fs: can convert to v0.68 or v1.0
author Pascal Bellard <pascal.bellard@slitaz.org>
date Sat Jun 22 12:48:49 2024 +0000 (3 months ago)
parents 0af8df0b46fc
children
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot16.asm -f bin -o boot16.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@25569 14 ;; - FAT12 and/or FAT16 supported using BIOS int 13h function 42h or 02h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@24476 19 ;; Its maximum size can be up to 635KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@25705 22 ;; ("No bootfile" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@25572 26 ;; - cpu 8088 is supported ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; ;;
pascal@25564 29 ;; Known Limitation: ;;
pascal@25564 30 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 31 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 32 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 33 ;; ;;
pascal@25572 34 ;; - Partition must fit in the first 8GB of the disk for CHS reads. ;;
pascal@25569 35 ;; (or 2TB for LBA reads). ;;
pascal@25564 36 ;; ;;
pascal@25564 37 ;; ;;
pascal@24476 38 ;; Known Bugs: ;;
pascal@24476 39 ;; ~~~~~~~~~~~ ;;
pascal@24476 40 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 41 ;; on the following types of diskettes (FAT12): ;;
pascal@24476 42 ;; - 360KB 5"25 ;;
pascal@24476 43 ;; - 1.2MB 5"25 ;;
pascal@24476 44 ;; - 1.44MB 3"5 ;;
pascal@24476 45 ;; on my HDD (FAT16). ;;
pascal@24476 46 ;; ;;
pascal@24476 47 ;; ;;
pascal@24476 48 ;; Memory Layout: ;;
pascal@24476 49 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 50 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 51 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 52 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 53 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 54 ;; ;;
pascal@24476 55 ;; physical address ;;
pascal@24476 56 ;; +------------------------+ 00000H ;;
pascal@24476 57 ;; | Interrupt Vector Table | ;;
pascal@24476 58 ;; +------------------------+ 00400H ;;
pascal@24476 59 ;; | BIOS Data Area | ;;
pascal@24476 60 ;; +------------------------+ 00500H ;;
pascal@24476 61 ;; | PrtScr Status / Unused | ;;
pascal@24476 62 ;; +------------------------+ 00600H ;;
pascal@24476 63 ;; | Loaded Image | ;;
pascal@24476 64 ;; +------------------------+ nnnnnH ;;
pascal@24476 65 ;; | Available Memory | ;;
pascal@24476 66 ;; +------------------------+ A0000H - 512 - 3KB ;;
pascal@24476 67 ;; | Boot Sector | ;;
pascal@24476 68 ;; +------------------------+ A0000H - 3KB ;;
pascal@24476 69 ;; | 3KB Boot Stack | ;;
pascal@24476 70 ;; +------------------------+ A0000H ;;
pascal@24476 71 ;; | Video RAM | ;;
pascal@24476 72 ;; ;;
pascal@24476 73 ;; ;;
pascal@24476 74 ;; Boot Image Startup (register values): ;;
pascal@24476 75 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 76 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 77 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 78 ;; cs:ip = program entry point ;;
pascal@24476 79 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 80 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 81 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 82 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 83 ;; Magic numbers: ;;
pascal@24476 84 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 85 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 86 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 87 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 88 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 89 ;; metal and MS-DOS programs. ;;
pascal@24945 90 ;; The command line contains no arguments. ;;
pascal@24476 91 ;; ;;
pascal@24476 92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 93
pascal@24476 94 %define bx(label) bx+label-boot
pascal@25450 95 %define si(label) si+label-boot
pascal@25458 96 NullEntryCheck equ 1 ; +2 bytes
pascal@25569 97 ReadRetry equ 1 ; +9/+13 bytes
pascal@25569 98 LBAsupport equ 1 ; +18 bytes
pascal@25578 99 CHSsanityCheck equ 1 ; +9/+13 bytes
pascal@25569 100 GeometryCheck equ 1 ; +20 bytes
pascal@25564 101 CheckAttrib equ 0 ; +6 bytes
pascal@25564 102 WaitForKey equ 0 ; +5 bytes
pascal@25550 103 SectorOf512Bytes equ 0 ; -4/-6 bytes
pascal@25564 104 Always2FATs equ 0 ; -1 bytes
pascal@25698 105 AnyWhere equ 1 ; +4 bytes
pascal@24476 106
pascal@24476 107 [BITS 16]
pascal@24476 108 [CPU 8086]
pascal@24476 109
pascal@24476 110 ImageLoadSeg equ 60h
pascal@24476 111 StackSize equ 3072 ; Stack + cluster list
pascal@24476 112
pascal@24476 113 [SECTION .text]
pascal@24476 114 [ORG 0]
pascal@24476 115
pascal@24476 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 117 ;; Boot sector starts here ;;
pascal@24476 118 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 119
pascal@24476 120 boot:
pascal@25450 121 DriveNumber:
pascal@24476 122 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 123 nop
pascal@24476 124 bsOemName DB "BootProg" ; 0x03
pascal@24476 125
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 127 ;; BPB starts here ;;
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 129
pascal@25564 130 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 131 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32 or 64
pascal@25564 132 bpbReservedSectors DW 0 ; 0x0E 1
pascal@25564 133 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@24479 134 bpbRootEntries DW 0 ; 0x11
pascal@24479 135 bpbTotalSectors DW 0 ; 0x13
pascal@24479 136 bpbMedia DB 0 ; 0x15
pascal@24479 137 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 138 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 139 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 140 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 141 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 142
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;
pascal@24476 144 ;; BPB ends here ;;
pascal@24476 145 ;;;;;;;;;;;;;;;;;;;
pascal@24476 146
pascal@24479 147 bsDriveNumber DB 0 ; 0x24
pascal@24479 148 bsUnused DB 0 ; 0x25
pascal@25564 149 bsExtBootSignature DB 0 ; 0x26 29
pascal@24479 150 bsSerialNumber DD 0 ; 0x27
pascal@25458 151 bsVolumeLabel times 11 DB " " ; 0x2B "NO NAME "
pascal@25458 152 bsFileSystem times 8 DB " " ; 0x36 "FAT12 " or "FAT16 "
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Boot sector code starts here ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 start:
pascal@24476 159
pascal@24476 160 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 161 ;; How much RAM is there? ;;
pascal@24476 162 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 163
pascal@25699 164 int 12h ; get conventional memory size (in KBs)
pascal@25698 165 %if AnyWhere
pascal@25698 166 call here
pascal@25698 167 here:
pascal@25698 168 pop si
pascal@25703 169 sub si, here - boot - 2
pascal@25698 170 push cs
pascal@25698 171 pop ds
pascal@25698 172 %endif
pascal@24476 173 mov cx, 106h
pascal@25699 174 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 175
pascal@24476 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 177 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 179
pascal@24476 180 sub ax, (512+StackSize) /16 ; reserve bytes for the code and the stack
pascal@24476 181 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 182 mov ss, ax
pascal@24476 183 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 184
pascal@24476 185 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 186 ;; Copy ourselves to top of memory ;;
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188
pascal@25698 189 xor di, di
pascal@25698 190 %if AnyWhere == 0
pascal@25699 191 mov si, 7C02h ; exclude DriveNumber
pascal@24476 192 mov ds, di
pascal@25698 193 %endif
pascal@25450 194 push es
pascal@25698 195 cld
pascal@25699 196 xchg ax, dx
pascal@25699 197 stosw ; store BIOS boot drive number
pascal@25699 198 rep movsw ; move 512 bytes (+ 12), no double prefix: 8088 bug
pascal@24476 199
pascal@24476 200 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 201 ;; Jump to the copy ;;
pascal@24476 202 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 203
pascal@24476 204 mov cl, byte main
pascal@24476 205 push cx
pascal@24476 206 retf
pascal@24476 207
pascal@24476 208 main:
pascal@24476 209 %if ImageLoadSeg != main-boot
pascal@24476 210 %if ImageLoadSeg >= 100h
pascal@24476 211 mov cx, ImageLoadSeg
pascal@24476 212 %else
pascal@24476 213 mov cl, ImageLoadSeg
pascal@24476 214 %endif
pascal@24476 215 %endif
pascal@24476 216 push cx
pascal@24476 217
pascal@24476 218 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 219 ;; Get drive parameters ;;
pascal@24476 220 ;; Update heads count ;;
pascal@24476 221 ;; for current BIOS ;;
pascal@24476 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 223
pascal@25450 224 %if GeometryCheck != 0
pascal@25564 225 %if ((main-boot) & 3Fh) != 0
pascal@25569 226 xor cx, cx
pascal@25564 227 %endif
pascal@25564 228 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@24476 229 int 13h ; may destroy SI,BP, and DS registers
pascal@25450 230 %endif
pascal@24476 231 push cs
pascal@24476 232 pop ds
pascal@24476 233 xor bx, bx
pascal@24476 234
pascal@25450 235 %if GeometryCheck != 0
pascal@24479 236 and cx, byte 3Fh
pascal@25564 237 je BadParams ; verify updated and validity
pascal@25564 238 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 239 mov cl, dh
pascal@25564 240 inc cx
pascal@25564 241 mov [bx(bpbHeadsPerCylinder)], cx
pascal@24476 242 BadParams:
pascal@25450 243 %endif
pascal@24476 244
pascal@24476 245 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 246 ;; Load FAT (FAT12: 6KB max, FAT16: 128KB max) ;;
pascal@24476 247 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 248
pascal@24476 249 pop es ; ImageLoadSeg
pascal@24476 250 push es
pascal@24476 251
pascal@24476 252 mul bx ; dx:ax = 0 = LBA (LBA are relative to FAT)
pascal@25458 253 mov di, word [bx(bpbSectorsPerFAT)]
pascal@24476 254
pascal@25458 255 call ReadDISectors ; read fat; clear ax, cx, di; bp = SectorsPerFAT
pascal@24476 256
pascal@24476 257 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 258 ;; load the root directory in ;;
pascal@24476 259 ;; its entirety (16KB max) ;;
pascal@24476 260 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 261
pascal@25458 262 %if SectorOf512Bytes != 0
pascal@25458 263 mov di, word [bx(bpbRootEntries)]
pascal@25458 264 mov cl, 4
pascal@25458 265 shr di, cl ; di = root directory size in sectors
pascal@25458 266 %else
pascal@24942 267 mov al, 32
pascal@24476 268
pascal@24476 269 mul word [bx(bpbRootEntries)]
pascal@24476 270 div word [bx(bpbBytesPerSector)]
pascal@25458 271 xchg ax, di ; di = root directory size in sectors, clear ah
pascal@25458 272 %endif
pascal@24476 273
pascal@25564 274 %if Always2FATs != 0
pascal@25564 275 mov al, 2
pascal@25564 276 %else
pascal@24476 277 mov al, [bpbNumberOfFATs]
pascal@25564 278 %endif
pascal@25458 279 mul bp ; [bx(bpbSectorsPerFAT)], set by ReadDISectors
pascal@24476 280
pascal@25457 281 push es ; read root directory
pascal@25458 282 call ReadDISectors ; clear ax, cx, di; bp = first data sector
pascal@24476 283 pop es
pascal@24476 284
pascal@24476 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 286 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 287 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 288
pascal@24476 289 ; es:di -> root entries array
pascal@24476 290
pascal@24476 291 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 292 ;; Looks for the file/dir ProgramName ;;
pascal@24476 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 294 ;; Input: ES:DI -> root directory array ;;
pascal@24476 295 ;; Output: SI = cluster number ;;
pascal@24476 296 ;; AX = file sector count ;;
pascal@24476 297 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 298
pascal@24476 299 FindNameCycle:
pascal@24476 300 push di
pascal@25454 301 mov cl, NameLength
pascal@24476 302 mov si, ProgramName ; ds:si -> program name
pascal@24476 303 repe cmpsb
pascal@25467 304 %if CheckAttrib != 0
pascal@25467 305 VolumeLabel equ 8
pascal@25467 306 SubDirectory equ 10h
pascal@25467 307 jnz SkipFindName
pascal@25467 308 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 309 SkipFindName:
pascal@25467 310 %endif
pascal@24476 311 pop di
pascal@24476 312 je FindNameFound
pascal@25450 313 %if NullEntryCheck != 0
pascal@25564 314 scasb ; Z == NC
pascal@25458 315 cmc
pascal@25458 316 lea di, [di+31]
pascal@25458 317 dec word [bx(bpbRootEntries)]
pascal@25458 318 ja FindNameCycle ; next root entry
pascal@25450 319 %else
pascal@25450 320 add di, byte 32
pascal@24476 321 dec word [bx(bpbRootEntries)]
pascal@24476 322 jnz FindNameCycle ; next root entry
pascal@25458 323 %endif
pascal@24476 324
pascal@24476 325 FindNameFailed:
pascal@24476 326 call Error
pascal@25705 327 db "No bootfile."
pascal@24476 328
pascal@24476 329 FindNameFound:
pascal@24476 330 push si
pascal@24476 331 mov si, [es:di+1Ah] ; si = cluster no.
pascal@24476 332 les ax, [es:di+1Ch] ; file size
pascal@24476 333 mov dx, es
pascal@24476 334 div word [bx(bpbBytesPerSector)]
pascal@24476 335 cmp bx, dx ; sector aligned ?
pascal@24476 336 adc ax, bx ; file last sector
pascal@24476 337 pop di ; di = ClusterList
pascal@24476 338
pascal@24476 339 pop es ; ImageLoadSeg
pascal@24476 340 push ax
pascal@24476 341
pascal@24476 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 343 ;; build cluster list ;;
pascal@24476 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 345 ;; Input: ES:0 -> FAT ;;
pascal@24476 346 ;; SI = first cluster ;;
pascal@24476 347 ;; DI = cluster list :;
pascal@24476 348 ;; CH = 0 ;;
pascal@24476 349 ;; Output: SI = cluster list ;;
pascal@24476 350 ;; CH = 0 ;;
pascal@24476 351 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 352
pascal@25458 353 FAT12 equ 1
pascal@25458 354 FAT16 equ 1
pascal@25550 355 TINYFAT16 equ 1 ; < 4072 clusters fat16 support
pascal@25453 356 push di ; up to 2 * 635K / BytesPerCluster = 2540 bytes
pascal@25572 357 %if FAT12 != 1 && FAT16 != 1
pascal@25572 358 %error "FAT12 and/or FAT16 must be set"
pascal@25572 359 %endif
pascal@25450 360 %if FAT12 == 1
pascal@25454 361 mov cl, 12
pascal@25564 362 %else
pascal@25564 363 nop
pascal@25564 364 nop
pascal@25450 365 %endif
pascal@24476 366 ClusterLoop:
pascal@24476 367 mov [di], si
pascal@25450 368 add si, si ; si = cluster * 2
pascal@25450 369 %if FAT16 == 1
pascal@24476 370 mov ax, es ; ax = FAT segment = ImageLoadSeg
pascal@25094 371 jnc First64k
pascal@24476 372 mov ah, (1000h+ImageLoadSeg)>>8 ; adjust segment for 2nd part of FAT16
pascal@25094 373 First64k:
pascal@25453 374 %if FAT12 == 1
pascal@25457 375 mov dx, 0FFF6h
pascal@25454 376 %if TINYFAT16 == 1
pascal@25550 377 test [bx(bsFileSystem+4)], cl ; FAT12 or FAT16 ? clear C (bit 2)
pascal@25458 378 jne ReadClusterFat16
pascal@25454 379 %else
pascal@25454 380 cmp [bx(bpbSectorsPerFAT)], cx ; 1..12 = FAT12, 16..256 = FAT16
pascal@25458 381 ja ReadClusterFat16
pascal@25454 382 %endif
pascal@24942 383 mov dh, 0Fh
pascal@25453 384 %endif
pascal@25450 385 %endif
pascal@25450 386 %if FAT12 == 1
pascal@25087 387 add si, [di]
pascal@24476 388 shr si, 1 ; si = cluster * 3 / 2
pascal@25564 389 %else
pascal@25564 390 nop
pascal@25564 391 nop
pascal@25450 392 %endif
pascal@25450 393 %if FAT16 == 1
pascal@24942 394 ReadClusterFat16:
pascal@25094 395 push ds
pascal@25087 396 mov ds, ax
pascal@24476 397 lodsw ; ax = next cluster
pascal@25094 398 pop ds
pascal@25450 399 %else
pascal@25453 400 es lodsw
pascal@25450 401 %endif
pascal@25450 402 %if FAT12 == 1
pascal@24476 403 jnc ReadClusterEven
pascal@25454 404 rol ax, cl
pascal@24476 405 ReadClusterEven:
pascal@25094 406 scasw ; di += 2
pascal@25454 407 %if FAT16 == 1
pascal@24942 408 and ah, dh ; mask cluster value
pascal@24942 409 cmp ax, dx
pascal@25454 410 %else
pascal@25453 411 and ah, 0Fh ; mask cluster value
pascal@25457 412 cmp ax, 0FF6h
pascal@25454 413 %endif
pascal@25454 414 %else
pascal@25454 415 scasw ; di += 2
pascal@25457 416 cmp ax, 0FFF6h
pascal@25453 417 %endif
pascal@24476 418 xchg ax, si
pascal@24476 419 jc ClusterLoop
pascal@24476 420 pop si
pascal@24476 421 pop di ; file size in sectors
pascal@24476 422
pascal@24476 423 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 424 ;; Load the entire file ;;
pascal@24476 425 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 426 ;; Input: ES:0 -> buffer ;;
pascal@24476 427 ;; SI = cluster list ;;
pascal@24476 428 ;; DI = file sectors ;;
pascal@24476 429 ;; CH = 0 ;;
pascal@24945 430 ;; BP = 1st data sec ;;
pascal@24476 431 ;; Output: BP:0 -> buffer ;;
pascal@24476 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 433
pascal@24476 434 push es
pascal@24476 435
pascal@24476 436 ReadClusters:
pascal@24476 437 lodsw
pascal@24476 438 dec ax
pascal@24476 439 dec ax
pascal@24476 440
pascal@25454 441 mov cl, [bx(bpbSectorsPerCluster)] ; 1..128
pascal@24476 442 mul cx ; cx = sector count (ch = 0)
pascal@24476 443
pascal@24476 444 add ax, bp ; LBA for cluster data
pascal@24476 445 adc dx, bx ; dx:ax = LBA
pascal@24476 446
pascal@25458 447 call ReadSectors ; clear ax, restore dx
pascal@24476 448
pascal@25458 449 jne ReadClusters ; until end of file
pascal@24476 450
pascal@24476 451 pop bp ; ImageLoadSeg
pascal@24476 452
pascal@24476 453 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 454 ;; Type detection, .COM or .EXE? ;;
pascal@24476 455 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 456
pascal@24476 457 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 458
pascal@24476 459 add bp, [bx+08h] ; bp = image base
pascal@24476 460 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 461
pascal@24476 462 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 463 je RelocateEXE ; yes, it's an EXE program
pascal@24476 464
pascal@24476 465 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 466 ;; Setup and run a .COM program ;;
pascal@24476 467 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 468 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 469 ;; cmdline=void ;;
pascal@24476 470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 471
pascal@24942 472 mov di, 100h ; ip
pascal@24476 473 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 474 mov ss, bp
pascal@24476 475 xor sp, sp
pascal@24476 476 push bp ; cs, ds and es
pascal@24476 477 jmp short Run
pascal@24476 478
pascal@24476 479 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 480 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 481 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 482 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 483 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 484 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 485
pascal@24476 486 ReloCycle:
pascal@24476 487 add [di+2], bp ; item seg (abs)
pascal@24476 488 les si, [di] ; si = item ofs, es = item seg
pascal@24476 489 add [es:si], bp ; fixup
pascal@24476 490 scasw ; di += 2
pascal@24476 491 scasw ; point to next entry
pascal@24476 492
pascal@24476 493 RelocateEXE:
pascal@24942 494 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 495 jns ReloCycle
pascal@24476 496 ; PSP don't have a valid drive identifier
pascal@24476 497 les si, [bx+0Eh]
pascal@24476 498 add si, bp
pascal@24476 499 mov ss, si ; ss for EXE
pascal@24476 500 mov sp, es ; sp for EXE
pascal@24476 501
pascal@24476 502 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 503 push si ; containing the PSP structure
pascal@24476 504
pascal@24476 505 add bp, [bx+16h] ; cs for EXE
pascal@24942 506 mov di, [bx+14h] ; ip for EXE
pascal@24476 507 Run:
pascal@24476 508 pop ds
pascal@24476 509 push bp
pascal@24942 510 push di
pascal@24476 511 push ds
pascal@24476 512 pop es
pascal@24942 513 mov [80h], ax ; clear cmdline
pascal@24942 514 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 515
pascal@24476 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 517 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 518 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 519 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 520 mov si, 16381 ; prime number 2**14-3
pascal@24476 521 mov di, 32749 ; prime number 2**15-19
pascal@24476 522 mov bp, 65521 ; prime number 2**16-15
pascal@24476 523
pascal@24476 524 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 525 ;; All done, transfer control to the program now ;;
pascal@24476 526 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 527 retf
pascal@24476 528
pascal@25458 529 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 530 ;; Error Messaging Code ;;
pascal@25458 531 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 532
pascal@25458 533 Error:
pascal@25458 534 pop si
pascal@25458 535
pascal@25458 536 PutStr:
pascal@25458 537 mov ah, 0Eh
pascal@25458 538 mov bl, 7
pascal@25458 539 lodsb
pascal@25458 540 int 10h
pascal@25458 541 cmp al, "."
pascal@25458 542 jne PutStr
pascal@25564 543 %if WaitForKey != 0
pascal@25458 544 cbw
pascal@25458 545 int 16h ; wait for a key...
pascal@25458 546 int 19h ; bootstrap
pascal@25564 547 %endif
pascal@25458 548 Stop:
pascal@25458 549 hlt
pascal@25458 550 jmp short Stop
pascal@25458 551
pascal@25458 552 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 553 ;; Read sectors using BIOS Int 13h ;;
pascal@25458 554 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 555 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@25458 556 ;; BX = 0 ;;
pascal@25458 557 ;; DI = sector count ;;
pascal@25458 558 ;; ES:BX -> buffer address ;;
pascal@25458 559 ;; Output: ES:BX -> next address ;;
pascal@25458 560 ;; BX = 0 ;;
pascal@25458 561 ;; CX = 0 ;;
pascal@25458 562 ;; DI = 0 ;;
pascal@25458 563 ;; DL = drive number ;;
pascal@25564 564 ;; 0:BP = next LBA from FAT ;;
pascal@25458 565 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 566
pascal@25458 567 ReadDISectors:
pascal@25458 568 mov bp, di
pascal@24476 569 add bp, ax ; adjust LBA for cluster data
pascal@24476 570
pascal@25458 571 mov cx, di ; no cluster size limit
pascal@24476 572
pascal@24476 573 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 574 ;; Read sectors using BIOS Int 13h ;;
pascal@24476 575 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 576 ;; Input: DX:AX = LBA relative to FAT ;;
pascal@24476 577 ;; BX = 0 ;;
pascal@24476 578 ;; CX = sector count ;;
pascal@24476 579 ;; DI = file sectors ;;
pascal@24476 580 ;; ES:BX -> buffer address ;;
pascal@24476 581 ;; Output: ES:BX -> next address ;;
pascal@24476 582 ;; BX = 0 ;;
pascal@24476 583 ;; CX or DI = 0 ;;
pascal@24476 584 ;; DL = drive number ;;
pascal@25564 585 ;; Keep: BP, SI ;;
pascal@24476 586 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 587
pascal@25458 588 ReadSectors:
pascal@24476 589 add ax, [bx(bpbHiddenSectors)]
pascal@24476 590 adc dx, [bx(bpbHiddenSectors)+2]
pascal@24476 591 add ax, [bx(bpbReservedSectors)]
pascal@24476 592
pascal@24476 593 push si
pascal@24476 594 ReadSectorNext:
pascal@24476 595 adc dx, bx
pascal@24476 596 push di
pascal@24476 597 push cx
pascal@24476 598
pascal@25450 599 %if LBAsupport != 0
pascal@24476 600 push bx
pascal@24476 601 push bx
pascal@25450 602 %endif
pascal@24476 603 push dx ; 32-bit LBA: up to 2TB
pascal@24476 604 push ax
pascal@24476 605 push es
pascal@25450 606 %if ReadRetry != 0 || LBAsupport != 0
pascal@25450 607 mov di, 16 ; packet size byte = 16, reserved byte = 0
pascal@25450 608 %endif
pascal@25450 609 %if LBAsupport != 0
pascal@24476 610 push bx
pascal@24476 611 inc bx ; sector count word = 1
pascal@24476 612 push bx
pascal@24476 613 dec bx
pascal@24476 614 push di
pascal@25450 615 %endif
pascal@24476 616
pascal@24476 617 xchg ax, cx ; save low LBA
pascal@24476 618 xchg ax, dx ; get high LBA
pascal@25452 619 cwd ; clear dx (LBA offset <1TB)
pascal@25450 620 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks
pascal@24476 621
pascal@25569 622 %if CHSsanityCheck != 0
pascal@25564 623 cmp ax, [bx(bpbHeadsPerCylinder)]
pascal@25578 624 jns CHSoverflow
pascal@25569 625 %endif
pascal@24476 626 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25450 627 idiv word [bx(bpbSectorsPerTrack)]
pascal@24476 628 ; ax = LBA / SPT
pascal@24476 629 ; dx = LBA % SPT = sector - 1
pascal@24476 630 inc dx
pascal@24476 631
pascal@24476 632 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25564 633 idiv word [bx(bpbHeadsPerCylinder)] ; may overflow if SectorsPerTrack * HeadsPerCylinder < 256 or disk > 8GB
pascal@24476 634 ; ax = (LBA / SPT) / HPC = cylinder
pascal@24476 635 ; dx = (LBA / SPT) % HPC = head
pascal@25458 636
pascal@25578 637 xchg ch, al ; clear al, save cylinder no.
pascal@24476 638 ; ch = LSB 0...7 of cylinder no.
pascal@25458 639 shr ax, 1
pascal@25458 640 shr ax, 1
pascal@24476 641 or cl, al
pascal@24476 642 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@24476 643 mov dh, dl
pascal@24476 644 ; dh = head no.
pascal@24476 645
pascal@25564 646 %if CHSsanityCheck != 0
pascal@25578 647 dec ah ; set S if cylinder < 1024 (8GB max)
pascal@25572 648 CHSoverflow:
pascal@25564 649 %endif
pascal@25572 650 mov si, sp
pascal@25569 651 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 652 pushf
pascal@25564 653 %endif
pascal@25564 654
pascal@25564 655 ReadSectorRetry:
pascal@25569 656 mov dl, [bx(DriveNumber)]
pascal@25569 657 ; dl = drive no.
pascal@25450 658 %if LBAsupport != 0
pascal@24476 659 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24476 660 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 661 jnc ReadSectorNextSegment
pascal@25450 662 %endif
pascal@25572 663 mov ax, 201h ; al = sector count = 1
pascal@25572 664 ; ah = 2 = read function no.
pascal@25564 665 %if CHSsanityCheck != 0
pascal@25564 666 %if ReadRetry != 0 || LBAsupport != 0
pascal@25564 667 popf
pascal@25564 668 pushf
pascal@25564 669 %endif
pascal@25578 670 jns SkipCHS
pascal@25564 671 %endif
pascal@24476 672 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@24476 673 jnc ReadSectorNextSegment
pascal@25564 674 SkipCHS:
pascal@25450 675 %if ReadRetry != 0
pascal@24476 676 cbw ; ah = 0 = reset function
pascal@24476 677 int 13h ; reset drive (DL)
pascal@24476 678 dec di
pascal@25457 679 jnz ReadSectorRetry ; up to 15 extra attempt
pascal@25450 680 %endif
pascal@24476 681
pascal@25564 682 ReadError:
pascal@24476 683 call Error
pascal@24476 684 db "Read error."
pascal@24476 685
pascal@24476 686 ReadSectorNextSegment:
pascal@25564 687 %if CHSsanityCheck != 0 && (ReadRetry != 0 || LBAsupport != 0)
pascal@25564 688 popf
pascal@25564 689 %endif
pascal@25564 690
pascal@25564 691 %macro adjust_es 2
pascal@25564 692 %if SectorOf512Bytes != 0
pascal@25564 693 add word %1, byte 32 ; adjust segment for next sector
pascal@25564 694 %else
pascal@25564 695 %if %2 != 0
pascal@25564 696 mov al, %2
pascal@25564 697 %endif
pascal@25564 698 mul byte [bx(bpbBytesPerSector)+1] ; = (bpbBytesPerSector/256)*16
pascal@25564 699 add %1, ax ; adjust segment for next sector
pascal@25564 700 %endif
pascal@25564 701 %endmacro
pascal@24476 702
pascal@25450 703 %if LBAsupport != 0
pascal@24476 704 pop ax ; al = 16
pascal@25564 705 adjust_es [si+6], 0
pascal@24476 706 pop cx ; sector count = 1
pascal@24476 707 pop bx
pascal@25450 708 %else
pascal@25564 709 adjust_es [si], 16
pascal@25450 710 %endif
pascal@24476 711 pop es ; es:0 updated
pascal@24476 712 pop ax
pascal@24476 713 pop dx
pascal@25450 714 %if LBAsupport != 0
pascal@24476 715 pop di
pascal@24476 716 pop di
pascal@24476 717 add ax, cx ; adjust LBA for next sector
pascal@25450 718 %else
pascal@25450 719 add ax, 1 ; adjust LBA for next sector
pascal@25450 720 %endif
pascal@24476 721
pascal@24476 722 pop cx ; cluster sectors to read
pascal@24476 723 pop di ; file sectors to read
pascal@24476 724 dec di ; keep C
pascal@25457 725 loopne ReadSectorNext ; until cluster sector count or file sector count
pascal@24476 726 pop si
pascal@24942 727 mov ax, bx ; clear ax
pascal@25450 728 mov dx, [bx(DriveNumber)] ; pass the BIOS boot drive to Run or Error
pascal@24476 729
pascal@24476 730 ret
pascal@24476 731
pascal@24942 732 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 733 ;; Fill free space with zeroes ;;
pascal@24942 734 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 735
pascal@25458 736 times (512-13-($-$$)) db 0
pascal@24476 737
pascal@24476 738 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 739 ;; Name of the file to load and run ;;
pascal@24476 740 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 741
pascal@25463 742 NameLength equ 11
pascal@25463 743 ProgramName times NameLength db 0 ; name and extension
pascal@24476 744
pascal@24476 745 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 746 ;; End of the sector ID ;;
pascal@24476 747 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 748
pascal@24476 749 ClusterList dw 0AA55h ; BIOS checks for this ID