wok annotate BootProg/stuff/boot32.asm @ rev 25463

Up expat (2.4.9) fixes CVE-2022-40674
author Pascal Bellard <pascal.bellard@slitaz.org>
date Thu Sep 29 20:05:23 2022 +0000 (19 months ago)
parents 7dd01dedad38
children 4c101652eb90
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 20 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 23 ;; ("File not found" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@24476 28 ;; Known Bugs: ;;
pascal@24476 29 ;; ~~~~~~~~~~~ ;;
pascal@24476 30 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 31 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; ;;
pascal@24476 34 ;; Memory Layout: ;;
pascal@24476 35 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 36 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 37 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 38 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 39 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; physical address ;;
pascal@24476 42 ;; +------------------------+ 00000H ;;
pascal@24476 43 ;; | Interrupt Vector Table | ;;
pascal@24476 44 ;; +------------------------+ 00400H ;;
pascal@24476 45 ;; | BIOS Data Area | ;;
pascal@24476 46 ;; +------------------------+ 00500H ;;
pascal@24476 47 ;; | PrtScr Status / Unused | ;;
pascal@24476 48 ;; +------------------------+ 00600H ;;
pascal@24476 49 ;; | Loaded Image | ;;
pascal@24476 50 ;; +------------------------+ nnnnnH ;;
pascal@24476 51 ;; | Available Memory | ;;
pascal@25460 52 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 53 ;; | Boot Sector | ;;
pascal@25460 54 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 55 ;; | 0.5KB Boot Stack | ;;
pascal@24476 56 ;; +------------------------+ A0000H ;;
pascal@24476 57 ;; | Video RAM | ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; ;;
pascal@24476 60 ;; Boot Image Startup (register values): ;;
pascal@24476 61 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 62 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 63 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 64 ;; cs:ip = program entry point ;;
pascal@24476 65 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 66 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 67 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 68 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 69 ;; Magic numbers: ;;
pascal@24476 70 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 71 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 72 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 73 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 74 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 75 ;; metal and MS-DOS programs. ;;
pascal@24945 76 ;; The command line contains no arguments. ;;
pascal@24476 77 ;; ;;
pascal@24476 78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 79
pascal@24491 80 %define bx(label) bx+label-boot
pascal@25449 81 %define si(label) si+label-boot
pascal@25449 82 ClusterMask equ 1 ; +9 bytes
pascal@25460 83 NullEntryCheck equ 1 ; +5 bytes
pascal@25449 84 ReadRetry equ 1 ; +7 bytes
pascal@25458 85 LBA48bits equ 1 ; +15 bytes
pascal@25449 86 CHSsupport equ 1 ; +27 bytes
pascal@25458 87 CHSupTo8GB equ 1 ; +11 bytes
pascal@25458 88 CHSupTo32MB equ 1 ; +7 bytes
pascal@25458 89 SectorOf512Bytes equ 1 ; -5 bytes
pascal@25458 90 Always2FATs equ 0 ; -4 bytes
pascal@24491 91
pascal@24476 92 [BITS 16]
pascal@24476 93
pascal@24478 94 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@25460 95 StackSize equ 512
pascal@24476 96
pascal@24476 97 [SECTION .text]
pascal@24476 98 [ORG 0]
pascal@24476 99
pascal@24476 100 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 101 ;; Boot sector starts here ;;
pascal@24476 102 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 103
pascal@24491 104 boot:
pascal@25458 105 DriveNumber equ boot+0
pascal@25458 106 HiLBA equ boot+2
pascal@24476 107 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 108 nop
pascal@24476 109 bsOemName DB "BootProg" ; 0x03
pascal@24476 110
pascal@24476 111 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 112 ;; BPB1 starts here ;;
pascal@24476 113 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 114
pascal@24479 115 bpbBytesPerSector DW 0 ; 0x0B
pascal@24479 116 bpbSectorsPerCluster DB 0 ; 0x0D
pascal@24479 117 bpbReservedSectors DW 0 ; 0x0E
pascal@24479 118 bpbNumberOfFATs DB 0 ; 0x10
pascal@24479 119 bpbRootEntries DW 0 ; 0x11
pascal@24479 120 bpbTotalSectors DW 0 ; 0x13
pascal@24479 121 bpbMedia DB 0 ; 0x15
pascal@24479 122 bpbSectorsPerFAT DW 0 ; 0x16
pascal@24479 123 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 124 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 125 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 126 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 127
pascal@24476 128 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 129 ;; BPB1 ends here ;;
pascal@24476 130 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 131
pascal@24476 132 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 133 ;; BPB2 starts here ;;
pascal@24476 134 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 135
pascal@24479 136 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 137 bsExtendedFlags DW 0 ; 0x28
pascal@24479 138 bsFSVersion DW 0 ; 0x2A
pascal@24479 139 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 140 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 141 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 142 bsreserved times 12 DB 0 ; 0x34
pascal@24479 143 bsDriveNumber DB 0 ; 0x40
pascal@24479 144 bsreserved1 DB 0 ; 0x41
pascal@24479 145 bsExtendedBootSignature DB 0 ; 0x42
pascal@24479 146 bsVolumeSerialNumber DD 0 ; 0x43
pascal@25458 147 bsVolumeLabel times 11 DB " " ; 0x47 "NO NAME "
pascal@25458 148 bsFileSystemName times 8 DB " " ; 0x52 "FAT32 "
pascal@24476 149
pascal@24476 150 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 151 ;; BPB2 ends here ;;
pascal@24476 152 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 153
pascal@24476 154 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 155 ;; Boot sector code starts here ;;
pascal@24476 156 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 157
pascal@24476 158 start:
pascal@24476 159 cld
pascal@24476 160
pascal@24476 161 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 162 ;; How much RAM is there? ;;
pascal@24476 163 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 164
pascal@24476 165 int 12h ; get conventional memory size (in KBs)
pascal@25460 166 dec ax ; reserve 1K bytes for the code and the stack
pascal@24525 167 mov cx, 106h
pascal@24525 168 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 169
pascal@24476 170 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 171 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 173
pascal@24525 174 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24525 175 mov ss, ax
pascal@24525 176 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 177
pascal@24476 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 179 ;; Copy ourselves to top of memory ;;
pascal@24476 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 181
pascal@24476 182 mov si, 7C00h
pascal@24476 183 xor di, di
pascal@24476 184 mov ds, di
pascal@25449 185 push es
pascal@25449 186 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24478 187 rep movsw
pascal@24476 188
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190 ;; Jump to the copy ;;
pascal@24476 191 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 192
pascal@25450 193 push byte main
pascal@24476 194 retf
pascal@24476 195
pascal@24476 196 main:
pascal@24476 197 push cs
pascal@24476 198 pop ds
pascal@24476 199
pascal@25449 200 xor ebx, ebx
pascal@24476 201
pascal@25449 202 %if ClusterMask != 0
pascal@24491 203 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@25449 204 %endif
pascal@24491 205 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 206
pascal@24478 207 push byte ImageLoadSeg
pascal@24478 208 pop es
pascal@25449 209
pascal@25449 210 RootDirReadContinue:
pascal@25458 211 call ReadClusterSector ; read one sector of the root dir
pascal@24476 212
pascal@24476 213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 214 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 215 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 216
pascal@24476 217 xor di, di ; es:di -> root entries array
pascal@24476 218
pascal@24476 219 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 220 ;; Looks for a file/dir by its name ;;
pascal@24476 221 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 222 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 223 ;; ES:DI -> root directory array ;;
pascal@24525 224 ;; BP = paragraphs in sector ;;
pascal@24476 225 ;; Output: ESI = cluster number ;;
pascal@24476 226 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 227
pascal@24476 228 FindNameCycle:
pascal@25449 229 %if NullEntryCheck != 0
pascal@24525 230 cmp byte [es:di], bh
pascal@24478 231 je ErrFind ; end of root directory (NULL entry found)
pascal@25449 232 %endif
pascal@24478 233 pusha
pascal@25454 234 mov cl, NameLength
pascal@24525 235 mov si, ProgramName ; ds:si -> program name
pascal@24476 236 repe cmpsb
pascal@24525 237 je FindNameFound
pascal@24478 238 popa
pascal@24525 239 add di, byte 32
pascal@24476 240 dec bp
pascal@24476 241 dec bp
pascal@24476 242 jnz FindNameCycle ; next root entry
pascal@25458 243 loop RootDirReadContinue ; next sector in cluster
pascal@25458 244 cmp esi, 0FFFFFF6h ; carry=0 if last cluster, and carry=1 otherwise
pascal@25458 245 jnc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 246 ErrFind:
pascal@24478 247 call Error ; end of root directory (dir end reached)
pascal@24476 248 db "File not found."
pascal@24476 249 FindNameFound:
pascal@24525 250 push word [es:di+14h-11]
pascal@24525 251 push word [es:di+1Ah-11]
pascal@24478 252 pop esi ; esi = cluster no. cx = 0
pascal@24476 253
pascal@24525 254 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 255 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 256
pascal@24476 257 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 258 ;; Load the entire file ;;
pascal@24476 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 260
pascal@24476 261 push es
pascal@24476 262 FileReadContinue:
pascal@24476 263 push di
pascal@25458 264 call ReadClusterSector ; read one sector of the boot file
pascal@25458 265 dec cx
pascal@24476 266 mov di, es
pascal@24478 267 add di, bp
pascal@24478 268 mov es, di ; es:bx updated
pascal@24476 269 pop di
pascal@24478 270
pascal@24476 271 sub di, bp
pascal@24476 272 jae FileReadContinue
pascal@24943 273 xor ax, ax
pascal@24476 274 pop bp
pascal@24476 275
pascal@24476 276 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 277 ;; Type detection, .COM or .EXE? ;;
pascal@24476 278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 279
pascal@24476 280 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 281
pascal@24476 282 add bp, [bx+08h] ; bp = image base
pascal@24476 283 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 284
pascal@24476 285 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 286 je RelocateEXE ; yes, it's an EXE program
pascal@24476 287
pascal@24476 288 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 289 ;; Setup and run a .COM program ;;
pascal@24535 290 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 291 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 292 ;; cmdline=void ;;
pascal@24476 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 294
pascal@24535 295 mov di, 100h ; ip
pascal@24476 296 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 297 mov ss, bp
pascal@24476 298 xor sp, sp
pascal@24476 299 push bp ; cs, ds and es
pascal@24476 300 jmp short Run
pascal@24476 301
pascal@24476 302 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 303 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 304 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 305 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 306 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 307 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 308
pascal@24476 309 ReloCycle:
pascal@24476 310 add [di+2], bp ; item seg (abs)
pascal@24476 311 les si, [di] ; si = item ofs, es = item seg
pascal@24476 312 add [es:si], bp ; fixup
pascal@24525 313 scasw ; di += 2
pascal@24525 314 scasw ; point to next entry
pascal@24476 315
pascal@24476 316 RelocateEXE:
pascal@24942 317 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 318 jns ReloCycle
pascal@24942 319
pascal@24945 320 les si, [bx+0Eh]
pascal@24945 321 add si, bp
pascal@24945 322 mov ss, si ; ss for EXE
pascal@24945 323 mov sp, es ; sp for EXE
pascal@24476 324
pascal@24476 325 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 326 push si ; containing the PSP structure
pascal@24476 327
pascal@24476 328 add bp, [bx+16h] ; cs for EXE
pascal@24535 329 mov di, [bx+14h] ; ip for EXE
pascal@24476 330 Run:
pascal@24476 331 pop ds
pascal@24476 332 push bp
pascal@24535 333 push di
pascal@24476 334 push ds
pascal@24476 335 pop es
pascal@24942 336 mov [80h], ax ; clear cmdline
pascal@24942 337 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 338
pascal@24476 339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 340 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 341 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 343 mov si, 16381 ; prime number 2**14-3
pascal@24476 344 mov di, 32749 ; prime number 2**15-19
pascal@24476 345 mov bp, 65521 ; prime number 2**16-15
pascal@24476 346
pascal@24476 347 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 348 ;; All done, transfer control to the program now ;;
pascal@24476 349 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 350 retf
pascal@24476 351
pascal@25458 352 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 353 ;; Error Messaging Code ;;
pascal@25458 354 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 355
pascal@25458 356 Error:
pascal@25458 357 pop si
pascal@25458 358 puts:
pascal@25458 359 mov ah, 0Eh
pascal@25458 360 mov bl, 7
pascal@25458 361 lodsb
pascal@25458 362 int 10h
pascal@25458 363 cmp al, '.'
pascal@25458 364 jne puts
pascal@25458 365 cbw
pascal@25458 366 int 16h ; wait for a key...
pascal@25458 367 int 19h ; bootstrap
pascal@25458 368
pascal@25458 369 Stop:
pascal@25458 370 hlt
pascal@25458 371 jmp short Stop
pascal@25458 372
pascal@25458 373 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 374 ;; Reads a FAT32 sector ;;
pascal@25458 375 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 376 ;; Inout: ES:BX -> buffer ;;
pascal@25458 377 ;; EAX = prev sector ;;
pascal@25458 378 ;; CX = rem sectors in cluster ;;
pascal@25458 379 ;; ESI = next cluster ;;
pascal@25458 380 ;; Output: EAX = current sector ;;
pascal@25458 381 ;; CX = rem sectors in cluster ;;
pascal@25458 382 ;; ESI = next cluster ;;
pascal@25458 383 ;; BP -> para / sector ;;
pascal@25458 384 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 385
pascal@25458 386 ReadClusterSector:
pascal@25458 387 %if SectorOf512Bytes != 0
pascal@25458 388 mov bp, 32 ; bp = paragraphs per sector
pascal@25458 389 %else
pascal@24525 390 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 391 shr bp, 4 ; bp = paragraphs per sector
pascal@25458 392 %endif
pascal@25449 393 mov dx, 1 ; adjust LBA for next sector
pascal@24525 394 inc cx
pascal@24525 395 loop ReadSectorLBA
pascal@24525 396
pascal@25449 397 mul ebx ; edx:eax = 0
pascal@25458 398 %if SectorOf512Bytes != 0
pascal@25458 399 mov al, 128 ; ax=# of FAT32 entries per sector
pascal@25458 400 %else
pascal@24945 401 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@25458 402 %endif
pascal@24525 403 lea edi, [esi-2] ; esi=cluster #
pascal@24476 404 xchg eax, esi
pascal@24478 405 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 406
pascal@24525 407 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@25449 408 %if LBA48bits != 0
pascal@25458 409 xor dx, dx
pascal@25449 410 %endif
pascal@25458 411 call ReadSectorLBAfromFAT ; read 1 FAT32 sector
pascal@24476 412
pascal@25449 413 %if ClusterMask != 0
pascal@24478 414 and byte [es:si+3], 0Fh ; mask cluster value
pascal@25449 415 %endif
pascal@24478 416 mov esi, [es:si] ; esi=next cluster #
pascal@24476 417
pascal@25458 418 %if Always2FATs != 0
pascal@25458 419 imul eax, dword [bx(bsSectorsPerFAT32)], 2
pascal@25458 420 %else
pascal@24525 421 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 422 mul dword [bx(bsSectorsPerFAT32)]
pascal@25458 423 %endif
pascal@24525 424
pascal@24525 425 xchg eax, edi
pascal@25454 426 movzx ecx, byte [bx(bpbSectorsPerCluster)] ; 8..128
pascal@24945 427 mul ecx ; edx:eax=sector number in data area
pascal@24525 428 add eax, edi
pascal@25458 429 %if LBA48bits != 0
pascal@25458 430 adc dx, bx
pascal@25458 431 %endif
pascal@24476 432
pascal@25458 433 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 434 ;; Reads a sector form the start of FAT ;;
pascal@25458 435 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 436
pascal@25458 437 ReadSectorLBAfromFAT:
pascal@25458 438 add eax, [bx(bpbHiddenSectors)]
pascal@25449 439 %if LBA48bits != 0
pascal@25449 440 adc dx, bx
pascal@25449 441 mov word [bx(HiLBA)], dx
pascal@25449 442 %endif
pascal@25454 443 mov dx, [bx(bpbReservedSectors)]
pascal@24476 444
pascal@24478 445 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 446 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 447 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 448 ;; Input: EAX = LBA ;;
pascal@24478 449 ;; CX = sector count ;;
pascal@24478 450 ;; ES:BX -> buffer address ;;
pascal@24478 451 ;; Output: CF = 0 if no more sectors ;;
pascal@24478 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 453
pascal@24476 454 ReadSectorLBA:
pascal@25449 455 add eax, edx
pascal@25449 456 %if LBA48bits != 0
pascal@24535 457 adc word [bx(HiLBA)], bx
pascal@25449 458 %endif
pascal@25449 459 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 460 pusha
pascal@24476 461
pascal@24478 462 push bx
pascal@25449 463 %if LBA48bits != 0
pascal@24491 464 push word [bx(HiLBA)] ; 48-bit LBA
pascal@25449 465 %else
pascal@25449 466 push bx
pascal@25449 467 %endif
pascal@24478 468 push eax
pascal@24476 469 push es
pascal@24476 470 push bx
pascal@24478 471 push byte 1 ; sector count word = 1
pascal@24525 472 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 473
pascal@25449 474 %if CHSsupport != 0
pascal@25458 475 %if CHSupTo8GB != 0
pascal@25449 476 push eax
pascal@25449 477 pop cx ; save low LBA
pascal@25449 478 pop ax ; get high LBA
pascal@25449 479 cwd ; clear dx (assume LBA offset <1TB)
pascal@25449 480 idiv word [bx(bpbSectorsPerTrack)] ; up to 8GB disks, avoid divide error
pascal@25449 481
pascal@25449 482 xchg ax, cx ; restore low LBA, save high LBA / SPT
pascal@25458 483 %else
pascal@25449 484 ; Busybox mkdosfs creates fat32 for floppies.
pascal@25449 485 ; Floppies may support CHS only.
pascal@25458 486 %if CHSupTo32MB != 0
pascal@25458 487 xor dx, dx ; clear dx (LBA offset <32MB)
pascal@25458 488 %else
pascal@25449 489 cwd ; clear dx (LBA offset <16MB)
pascal@25458 490 %endif
pascal@25450 491 xor cx, cx ; high LBA / SPT = 0
pascal@25458 492 %endif
pascal@25449 493 idiv word [bx(bpbSectorsPerTrack)]
pascal@25449 494 ; ax = LBA / SPT
pascal@25449 495 ; dx = LBA % SPT = sector - 1
pascal@25449 496 inc dx
pascal@25449 497
pascal@25449 498 xchg cx, dx ; restore high LBA / SPT, save sector no.
pascal@25450 499 idiv word [bx(bpbHeadsPerCylinder)]
pascal@25449 500 ; ax = (LBA / SPT) / HPC = cylinder
pascal@25449 501 ; dx = (LBA / SPT) % HPC = head
pascal@25449 502
pascal@25458 503 xchg ch, al ; clear al
pascal@25449 504 ; ch = LSB 0...7 of cylinder no.
pascal@25458 505 %if CHSupTo8GB != 0 || CHSupTo32MB != 0
pascal@25458 506 shr ax, 2
pascal@25458 507 or cl, al
pascal@25449 508 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@25458 509 %endif
pascal@25449 510 mov dh, dl
pascal@25449 511 ; dh = head no.
pascal@25449 512 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25449 513 %endif
pascal@25449 514
pascal@25454 515 ReadSectorRetry:
pascal@24525 516 mov si, sp
pascal@24478 517 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 518 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 519 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 520
pascal@25449 521 %if CHSsupport != 0
pascal@25449 522 mov ax, 201h ; al = sector count = 1
pascal@25449 523 ; ah = 2 = read function no.
pascal@25449 524 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@25449 525
pascal@25449 526 jnc ReadSuccess ; CF = 0 if no error
pascal@25449 527 %endif
pascal@25449 528 %if ReadRetry != 0
pascal@25458 529 %if CHSsupport != 0
pascal@25449 530 cbw ; ah = 0 = reset function
pascal@25458 531 %else
pascal@24945 532 xor ax, ax ; ah = 0 = reset function
pascal@25458 533 %endif
pascal@24476 534 int 13h ; reset drive (DL)
pascal@24476 535
pascal@25457 536 dec bp ; up to 32 retries
pascal@25454 537 jnz ReadSectorRetry
pascal@25449 538 %endif
pascal@24525 539
pascal@24476 540 call Error
pascal@24476 541 db "Read error."
pascal@24476 542
pascal@24478 543 ReadSuccess:
pascal@24476 544
pascal@24476 545 popa ; sp += 16
pascal@24478 546 popa
pascal@24476 547 ret
pascal@24476 548
pascal@24942 549 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 550 ;; Fill free space with zeroes ;;
pascal@24942 551 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 552
pascal@25458 553 times (512-13-($-$$)) db 0
pascal@24476 554
pascal@24476 555 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 556 ;; Name of the file to load and run ;;
pascal@24476 557 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 558
pascal@25463 559 NameLength equ 11
pascal@25463 560 ProgramName times NameLength db 0 ; name and extension
pascal@24476 561
pascal@24476 562 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 563 ;; End of the sector ID ;;
pascal@24476 564 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 565
pascal@24476 566 dw 0AA55h ; BIOS checks for this ID