wok-current annotate BootProg/stuff/bootex.asm @ rev 25550

Add apachetop & mysqlsniffer
author Pascal Bellard <pascal.bellard@slitaz.org>
date Mon Apr 03 16:35:42 2023 +0000 (15 months ago)
parents b0069c845544
children 3c71bb4367c3
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm bootex.asm -f bin -o bootex.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24476 14 ;; - exFAT supported using BIOS int 13h function 42h. ;;
pascal@24476 15 ;; ;;
pascal@24476 16 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 17 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 18 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 19 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 20 ;; ;;
pascal@24476 21 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 22 ;; ("File not found" or "Read error") ;;
pascal@24476 23 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 24 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 25 ;; ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; Known Bugs: ;;
pascal@24476 28 ;; ~~~~~~~~~~~ ;;
pascal@24476 29 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 30 ;; on a 128MB qemu image. ;;
pascal@24476 31 ;; ;;
pascal@24476 32 ;; ;;
pascal@24476 33 ;; Memory Layout: ;;
pascal@24476 34 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 35 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 36 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 37 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 38 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 39 ;; ;;
pascal@24476 40 ;; physical address ;;
pascal@24476 41 ;; +------------------------+ 00000H ;;
pascal@24476 42 ;; | Interrupt Vector Table | ;;
pascal@24476 43 ;; +------------------------+ 00400H ;;
pascal@24476 44 ;; | BIOS Data Area | ;;
pascal@24476 45 ;; +------------------------+ 00500H ;;
pascal@24476 46 ;; | PrtScr Status / Unused | ;;
pascal@24476 47 ;; +------------------------+ 00600H ;;
pascal@24476 48 ;; | Loaded Image | ;;
pascal@24476 49 ;; +------------------------+ nnnnnH ;;
pascal@24476 50 ;; | Available Memory | ;;
pascal@25460 51 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 52 ;; | Boot Sector | ;;
pascal@25460 53 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 54 ;; | 0.5KB Boot Stack | ;;
pascal@24476 55 ;; +------------------------+ A0000H ;;
pascal@24476 56 ;; | Video RAM | ;;
pascal@24476 57 ;; ;;
pascal@24476 58 ;; ;;
pascal@24476 59 ;; Boot Image Startup (register values): ;;
pascal@24476 60 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 61 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 62 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 63 ;; cs:ip = program entry point ;;
pascal@24476 64 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 65 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 66 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 67 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 68 ;; Magic numbers: ;;
pascal@24476 69 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 70 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 71 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 72 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 73 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 74 ;; metal and MS-DOS programs. ;;
pascal@24945 75 ;; The command line contains no arguments. ;;
pascal@24476 76 ;; ;;
pascal@24476 77 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 78
pascal@24476 79 %define bx(label) bx+label-boot
pascal@25450 80 %define si(label) si+label-boot
pascal@25450 81 NullEntryCheck equ 1 ; +3 bytes
pascal@25450 82 ReadRetry equ 1 ; +8 bytes
pascal@25550 83 SectorOf512Bytes equ 0 ; -11 bytes
pascal@25550 84 CheckAttrib equ 0 ; +18 bytes
pascal@24476 85
pascal@24476 86 [BITS 16]
pascal@24476 87 [CPU 386]
pascal@24476 88
pascal@24476 89 ImageLoadSeg equ 60h
pascal@25460 90 StackSize equ 512
pascal@24476 91
pascal@24476 92 [SECTION .text]
pascal@24476 93 [ORG 0]
pascal@24476 94
pascal@24476 95 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 96 ;; Boot sector starts here ;;
pascal@24476 97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 98
pascal@24476 99 boot:
pascal@25450 100 DriveNumber:
pascal@24476 101 jmp short start ; Windows checks for this jump
pascal@24476 102 nop
pascal@25458 103 bsOemName times 8 db " " ; 0x03 "EXFAT "
pascal@24476 104 times 53 db 0 ; 0x0B
pascal@24476 105
pascal@24476 106 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 107 ;; BPB starts here ;;
pascal@24476 108 ;;;;;;;;;;;;;;;;;;;;;
pascal@24476 109
pascal@24479 110 bpbSectorStart DQ 0 ; 0x40 partition first sector
pascal@24479 111 bpbSectorCount DQ 0 ; 0x48 partition sectors count
pascal@24479 112 bpbFatSectorStart DD 0 ; 0x50 FAT first sector
pascal@24479 113 bpbFatSectorCount DD 0 ; 0x54 FAT sectors count
pascal@24479 114 bpbClusterSectorStart DD 0 ; 0x58 first cluster sector
pascal@24479 115 bpbClusterCount DD 0 ; 0x5C total clusters count
pascal@24479 116 bpbRootDirCluster DD 0 ; 0x60 first cluster of the root dir
pascal@24479 117 bpbVolumeSerial DD 0 ; 0x64 volume serial number
pascal@24479 118 bpbFSVersionMinor DB 0 ; 0x68
pascal@24479 119 bpbFSVersionMajor DB 0 ; 0x69
pascal@24479 120 bpbVolumeStateFlags DW 0 ; 0x6A
pascal@24479 121 bpbSectorSizeBits DB 0 ; 0x6C sector size as (1 << n)
pascal@24479 122 bpbSectorPerClusterBits DB 0 ; 0x6D sector per cluster as (1 << n)
pascal@24479 123 bpbNumberOfFATs DB 0 ; 0x6E always 1
pascal@24479 124 bpbDriveNumber DB 0 ; 0x6F alaways 0x80
pascal@24479 125 bpbAllocatedPercent DB 0 ; 0x70 percentage of allocated space
pascal@24476 126
pascal@24476 127 ;;;;;;;;;;;;;;;;;;;
pascal@24476 128 ;; BPB ends here ;;
pascal@24476 129 ;;;;;;;;;;;;;;;;;;;
pascal@24476 130
pascal@24476 131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 132 ;; Boot sector code starts here ;;
pascal@24476 133 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 134
pascal@24476 135 start:
pascal@24476 136 cld
pascal@24476 137
pascal@24476 138 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 139 ;; How much RAM is there? ;;
pascal@24476 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 141
pascal@24476 142 int 12h ; get conventional memory size (in KBs)
pascal@24476 143 mov cx, 106h
pascal@25460 144 dec ax ; reserve 1K bytes for the code and the stack
pascal@24476 145 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 146
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 150
pascal@24476 151 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@24476 152 mov ss, ax
pascal@24476 153 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@24476 154
pascal@24476 155 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 156 ;; Copy ourselves to top of memory ;;
pascal@24476 157 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 158
pascal@24476 159 mov si, 7C00h
pascal@24476 160 xor di, di
pascal@24476 161 mov ds, di
pascal@25450 162 push es
pascal@25450 163 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24476 164 rep movsw ; move 512 bytes (+ 12)
pascal@24476 165
pascal@24476 166 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 167 ;; Jump to the copy ;;
pascal@24476 168 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 169
pascal@24942 170 push word main
pascal@24476 171 retf
pascal@24476 172
pascal@24476 173 main:
pascal@24476 174 push cs
pascal@24476 175 pop ds
pascal@24476 176
pascal@24476 177 xor ebx, ebx
pascal@24476 178
pascal@24476 179 mov esi, [bx(bpbRootDirCluster)] ; esi=cluster # of root dir
pascal@24476 180
pascal@24479 181 push byte ImageLoadSeg
pascal@24942 182 pop es ; cx = 0
pascal@24476 183
pascal@24476 184 RootDirReadContinue:
pascal@24476 185 call ReadCluster ; read one sector of root dir
pascal@24476 186
pascal@24476 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 188 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 190
pascal@25454 191 ; es:di -> root entries array
pascal@24476 192
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194 ;; Looks for the file/dir ProgramName ;;
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196 ;; Input: ES:DI -> root directory array ;;
pascal@24476 197 ;; Output: ESI = cluster number ;;
pascal@24476 198 ;; dword [bx+FileSize] file size ;;
pascal@24476 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 200
pascal@25467 201 CurNameSize equ 03h ; 1 byte
pascal@25450 202 StartCluster equ 14h ; 4 bytes
pascal@25450 203 FileSize equ 18h ; 8 bytes
pascal@24476 204
pascal@24476 205 FindNameCycle:
pascal@24476 206 pusha
pascal@24476 207
pascal@25469 208 %if CheckAttrib != 0
pascal@25469 209 Attributes equ 0Bh ; 1 byte
pascal@25469 210 cmp byte [es:di], 85h ; EXFAT_ENTRY_FILE ?
pascal@25469 211 jne NotEntryFile
pascal@25469 212 mov al, [es:di+Attributes]
pascal@25550 213 mov [ProgramName+NameLength+1], al
pascal@25469 214 NotEntryFile:
pascal@25469 215 %endif
pascal@25450 216 %if NullEntryCheck != 0
pascal@24476 217 xor ax, ax
pascal@24476 218 or al, [es:di]
pascal@24476 219 je FindNameFailed
pascal@25467 220 cmp al, 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@25450 221 %else
pascal@25467 222 cmp byte [es:di], 0c0h ; EXFAT_ENTRY_FILE_INFO ?
pascal@25450 223 %endif
pascal@24476 224 jne NotFileInfo
pascal@24476 225
pascal@24942 226 mov bl, 31
pascal@24476 227 CopyInfo:
pascal@24942 228 mov al, [es:di+bx]
pascal@24942 229 mov [bx], al
pascal@24476 230 dec bx
pascal@25450 231 jnz CopyInfo ; keep BIOS boot drive number
pascal@24476 232
pascal@24476 233 NotFileInfo:
pascal@25467 234 %if NullEntryCheck != 0
pascal@24476 235 mov al, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@25467 236 %else
pascal@25467 237 mov ax, 0c1h ; EXFAT_ENTRY_FILE_NAME ?
pascal@25467 238 %endif
pascal@24476 239 mov cx, NameLength+1
pascal@24476 240 mov si, ProgramName ; ds:si -> program name
pascal@24476 241 CheckName:
pascal@24476 242 scasw ; compare UTF-16
pascal@24476 243 lodsb ; with ASCII
pascal@24476 244 loope CheckName
pascal@25467 245 %if CheckAttrib != 0
pascal@25467 246 VolumeLabel equ 8
pascal@25467 247 SubDirectory equ 10h
pascal@25467 248 jnz SkipFindName
pascal@25550 249 test byte [si], VolumeLabel+SubDirectory
pascal@25467 250 SkipFindName:
pascal@25467 251 %endif
pascal@24476 252 je FindNameFound ; cx = 0
pascal@24476 253 popa ; restore ax, cx, si, di
pascal@24476 254
pascal@24479 255 add di, byte 32
pascal@24945 256 cmp di, bp
pascal@24945 257 jne FindNameCycle ; next root entry
pascal@25458 258 loop RootDirReadContinue ; continue to the next root dir sector
pascal@25458 259 cmp esi, byte -10 ; carry=0 if last cluster, and carry=1 otherwise
pascal@24476 260 jc RootDirReadContinue ; continue to the next root dir cluster
pascal@24476 261 FindNameFailed: ; end of root directory (dir end reached)
pascal@25454 262 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 263 call Error
pascal@24476 264 db "File not found."
pascal@24476 265 FindNameFound:
pascal@24476 266 mov esi, [bx+StartCluster]
pascal@24476 267
pascal@24476 268 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 269 ;; Load the entire file ;;
pascal@25550 270 ;; Input: ESI = cluster ;;
pascal@25550 271 ;; CX = 0 ;;
pascal@24476 272 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 273
pascal@24476 274 push es
pascal@25458 275 %if SectorOf512Bytes == 0
pascal@24945 276 xor bp, bp
pascal@24476 277 FileReadContinue:
pascal@24476 278 shr bp, 4 ; bytes to paragraphs
pascal@24476 279 mov di, es
pascal@24476 280 add di, bp ; adjust segment for next sector
pascal@24476 281 mov es, di ; es:0 updated
pascal@25458 282 %else
pascal@25458 283 FileReadContinue:
pascal@25458 284 %endif
pascal@24943 285 call ReadCluster ; read one more sector of the boot file
pascal@25458 286 dec cx
pascal@25450 287 sub [bx+FileSize], ebp ; max FileSize is < 640KB : check low 32 bits only
pascal@25458 288 %if SectorOf512Bytes != 0
pascal@25458 289 mov bp, es
pascal@25458 290 lea bp, [bp+32]
pascal@25458 291 mov es, bp ; es:0 updated
pascal@25458 292 %endif
pascal@24476 293 ja FileReadContinue
pascal@25450 294 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@25454 295 xchg ax, di
pascal@24476 296 pop bp
pascal@24476 297
pascal@24476 298 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 299 ;; Type detection, .COM or .EXE? ;;
pascal@24476 300 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 301
pascal@24476 302 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24476 303
pascal@24476 304 add bp, [bx+08h] ; bp = image base
pascal@24476 305 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 306
pascal@24476 307 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 308 je RelocateEXE ; yes, it's an EXE program
pascal@24476 309
pascal@24476 310 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 311 ;; Setup and run a .COM program ;;
pascal@24476 312 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 313 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 314 ;; cmdline=void ;;
pascal@24476 315 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 316
pascal@24525 317 mov di, 100h ; ip
pascal@24476 318 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 319 mov ss, bp
pascal@24476 320 xor sp, sp
pascal@24476 321 push bp ; cs, ds and es
pascal@24476 322 jmp short Run
pascal@24476 323
pascal@24476 324 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 325 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 326 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 327 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 328 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 330
pascal@24476 331 ReloCycle:
pascal@24476 332 add [di+2], bp ; item seg (abs)
pascal@24476 333 les si, [di] ; si = item ofs, es = item seg
pascal@24476 334 add [es:si], bp ; fixup
pascal@24476 335 scasw ; di += 2
pascal@24476 336 scasw ; point to next entry
pascal@24476 337
pascal@24476 338 RelocateEXE:
pascal@24942 339 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 340 jns ReloCycle
pascal@24942 341
pascal@24945 342 les si, [bx+0Eh]
pascal@24945 343 add si, bp
pascal@24945 344 mov ss, si ; ss for EXE
pascal@24945 345 mov sp, es ; sp for EXE
pascal@24476 346
pascal@24476 347 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 348 push si ; containing the PSP structure
pascal@24476 349
pascal@24476 350 add bp, [bx+16h] ; cs for EXE
pascal@24525 351 mov di, [bx+14h] ; ip for EXE
pascal@24476 352 Run:
pascal@24476 353 pop ds
pascal@24476 354 push bp
pascal@24525 355 push di
pascal@24476 356 push ds
pascal@24476 357 pop es
pascal@24942 358 mov [80h], ax ; clear cmdline
pascal@24942 359 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 360
pascal@24476 361 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 362 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 363 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 364 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 365 mov si, 16381 ; prime number 2**14-3
pascal@24476 366 mov di, 32749 ; prime number 2**15-19
pascal@24476 367 mov bp, 65521 ; prime number 2**16-15
pascal@24476 368
pascal@24476 369 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 370 ;; All done, transfer control to the program now ;;
pascal@24476 371 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 372 retf
pascal@24476 373
pascal@25458 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 375 ;; Error Messaging Code ;;
pascal@25458 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 377
pascal@25458 378 Error:
pascal@25458 379 pop si
pascal@25458 380
pascal@25458 381 PutStr:
pascal@25458 382 mov ah, 0Eh
pascal@25458 383 mov bl, 7
pascal@25458 384 lodsb
pascal@25458 385 int 10h
pascal@25458 386 cmp al, "."
pascal@25458 387 jne PutStr
pascal@25458 388
pascal@25458 389 cbw
pascal@25458 390 int 16h ; wait for a key...
pascal@25458 391 int 19h ; bootstrap
pascal@25458 392
pascal@25458 393 Stop:
pascal@25458 394 hlt
pascal@25458 395 jmp short Stop
pascal@25458 396
pascal@24476 397 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 398 ;; Reads a exFAT cluster ;;
pascal@24476 399 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 400 ;; Input: EDX:EAX = LBA ;;
pascal@24476 401 ;; CX = sector cnt ;;
pascal@24476 402 ;; ESI = cluster no ;;
pascal@24476 403 ;; ES:0 -> buffer adrs ;;
pascal@25550 404 ;; Output: EDX:EAX = next LBA ;;
pascal@25550 405 ;; CX = sector cnt ;;
pascal@25550 406 ;; ESI = cluster no ;;
pascal@24476 407 ;; EBP = bytes/sector;;
pascal@25550 408 ;; Keep: EDI = 0 ;;
pascal@25550 409 ;; EBX = 0 ;;
pascal@24476 410 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 411
pascal@24476 412 ReadCluster:
pascal@24945 413 add eax, byte 1
pascal@24945 414
pascal@24476 415 inc cx ; jcxnz
pascal@24476 416 loop ReadSectorC
pascal@24476 417
pascal@24945 418 mul ebx ; edx:eax = 0
pascal@25458 419 %if SectorOf512Bytes != 0
pascal@25458 420 mov al, 128
pascal@25458 421 %else
pascal@25550 422 mov ah, 40h
pascal@25550 423 mov cx, [bx(bpbSectorSizeBits)]
pascal@25550 424 rol ax, cl ; eax=# of exFAT entries per sector
pascal@25458 425 %endif
pascal@24476 426 lea edi, [esi-2] ; edi=cluster #-2
pascal@24476 427 xchg eax, esi
pascal@24476 428 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 429
pascal@24525 430 imul si, dx, byte 4 ; si=entry # offset in sector
pascal@24476 431
pascal@24476 432 cdq
pascal@25452 433 add eax, [bx(bpbFatSectorStart)] ; sector # relative to exFAT
pascal@25454 434 call ReadSectorFAT ; read 1 exFAT sector, keep edx=0, set C
pascal@24476 435
pascal@24476 436 mov esi, [es:si] ; esi=next cluster #
pascal@24476 437
pascal@25550 438 %if SectorOf512Bytes != 0
pascal@25450 439 mov dl, [bx(bpbSectorPerClusterBits)]
pascal@25550 440 %else
pascal@25550 441 mov dl, ch
pascal@25550 442 %endif
pascal@25452 443 xor ecx, ecx
pascal@25450 444 bts ecx, edx ; 10000h max (32MB cluster)
pascal@24476 445 xchg eax, edi ; get cluster #-2
pascal@24476 446 mul ecx
pascal@24476 447
pascal@24476 448 add eax, [bx(bpbClusterSectorStart)]
pascal@24476 449 ReadSectorC:
pascal@25454 450 mov di, bx
pascal@25454 451 ReadSectorFAT:
pascal@24476 452 adc edx, ebx
pascal@24476 453
pascal@24476 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 455 ;; Reads a sector using BIOS Int 13h ;;
pascal@24476 456 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 457 ;; Input: EDX:EAX = LBA ;;
pascal@24476 458 ;; ES:0 -> buffer address ;;
pascal@25550 459 ;; Output: EBP = bytes/sector ;;
pascal@25550 460 ;; Keep: ESI = cluster ;;
pascal@25550 461 ;; EDI = FAT sector or 0 ;;
pascal@25550 462 ;; ECX = sector count ;;
pascal@25550 463 ;; EBX = 0 ;;
pascal@24476 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 465
pascal@25458 466 %if SectorOf512Bytes != 0
pascal@25458 467 lea ebp, [bx+512]
pascal@25458 468 %else
pascal@25458 469 lea ebp, [bx+1]
pascal@25458 470 %endif
pascal@24476 471
pascal@24476 472 pushad
pascal@24476 473
pascal@24476 474 add eax, [bx(bpbSectorStart)]
pascal@24476 475 adc edx, [bx(bpbSectorStart)+4]
pascal@24476 476
pascal@24476 477 push edx
pascal@24476 478 push eax
pascal@24476 479 push es
pascal@24476 480 push bx
pascal@25458 481 %if SectorOf512Bytes != 0
pascal@25458 482 push byte 1 ; sector count word = 1
pascal@25458 483 %else
pascal@24476 484 push bp ; sector count word = 1
pascal@25458 485 %endif
pascal@25454 486 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24476 487 ReadSectorRetry:
pascal@24476 488 mov si, sp
pascal@24476 489 mov ah, 42h ; ah = 42h = extended read function no.
pascal@25450 490 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 491 int 13h ; extended read sectors (DL, DS:SI)
pascal@24476 492
pascal@24476 493 jnc ReadSuccess
pascal@24476 494
pascal@25450 495 %if ReadRetry != 0
pascal@24476 496 xor ax, ax
pascal@24476 497 int 13h ; reset drive (DL)
pascal@25457 498 dec bp
pascal@25458 499 %if SectorOf512Bytes != 0
pascal@25458 500 jne ReadSectorRetry ; up to 511 tries
pascal@25458 501 %else
pascal@25457 502 jpe ReadSectorRetry ; up to 3 tries
pascal@25458 503 %endif
pascal@25450 504 %endif
pascal@24476 505
pascal@24476 506 call Error
pascal@24476 507 db "Read error."
pascal@24476 508
pascal@24476 509 ReadSuccess:
pascal@25458 510 %if SectorOf512Bytes == 0
pascal@24476 511 mov cl, [bx(bpbSectorSizeBits)]
pascal@24476 512 shl word [si+16+8], cl ; (e)bp si+16: EDI ESI EBP ESP EBX EDX ECX EAX
pascal@25458 513 %endif
pascal@24476 514 popa ; sp += 16
pascal@24476 515 popad ; real registers
pascal@24476 516 ret
pascal@24476 517
pascal@24942 518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 519 ;; Fill free space with zeroes ;;
pascal@24942 520 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 521
pascal@25458 522 times (512-13-($-$$)) db 0
pascal@24476 523
pascal@24476 524 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 525 ;; Name of the file to load and run ;;
pascal@24476 526 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 527
pascal@25463 528 NameLength equ 11
pascal@25463 529 ProgramName times NameLength db 0 ; name and extension
pascal@24476 530
pascal@24476 531 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 532 ;; End of the sector ID ;;
pascal@24476 533 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 534
pascal@24476 535 dw 0AA55h ; BIOS checks for this ID