wok annotate BootProg/stuff/boot32.asm @ rev 25697

dool: reduced size of package
author Hans-G?nter Theisgen
date Sun May 12 07:10:04 2024 +0100 (4 weeks ago)
parents 64471e67874e
children 82a123e54615
rev   line source
pascal@24476 1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 2 ;; ;;
pascal@24476 3 ;; "BootProg" Loader v 1.5 by Alexey Frunze (c) 2000-2015 ;;
pascal@24476 4 ;; 2-clause BSD license. ;;
pascal@24476 5 ;; ;;
pascal@24476 6 ;; ;;
pascal@24476 7 ;; How to Compile: ;;
pascal@24476 8 ;; ~~~~~~~~~~~~~~~ ;;
pascal@24476 9 ;; nasm boot32.asm -f bin -o boot32.bin ;;
pascal@24476 10 ;; ;;
pascal@24476 11 ;; ;;
pascal@24476 12 ;; Features: ;;
pascal@24476 13 ;; ~~~~~~~~~ ;;
pascal@24535 14 ;; - FAT32 supported using BIOS int 13h function 42h (IOW, it will only ;;
pascal@24535 15 ;; work with modern BIOSes supporting HDDs bigger than 8 GB) ;;
pascal@24476 16 ;; ;;
pascal@24476 17 ;; - Loads a 16-bit executable file in the MS-DOS .COM or .EXE format ;;
pascal@24476 18 ;; from the root directory of a disk and transfers control to it ;;
pascal@24476 19 ;; (the "ProgramName" variable holds the name of the file to be loaded) ;;
pascal@25460 20 ;; Its maximum size can be up to 637KB without Extended BIOS Data area. ;;
pascal@24476 21 ;; ;;
pascal@24476 22 ;; - Prints an error if the file isn't found or couldn't be read ;;
pascal@24476 23 ;; ("File not found" or "Read error") ;;
pascal@24476 24 ;; and waits for a key to be pressed, then executes the Int 19h ;;
pascal@24476 25 ;; instruction and lets the BIOS continue bootstrap. ;;
pascal@24476 26 ;; ;;
pascal@24476 27 ;; ;;
pascal@25564 28 ;; Known Limitation: ;;
pascal@25564 29 ;; ~~~~~~~~~~~~~~~~~ ;;
pascal@25564 30 ;; - Need a up to date field bpbHiddenSectors to work in a partition ; ;;
pascal@25564 31 ;; most formatters don't update it correcly in extended partitions. ;;
pascal@25564 32 ;; ;;
pascal@25564 33 ;; - Requires i80386 or better CPU. ;;
pascal@25564 34 ;; ;;
pascal@25564 35 ;; ;;
pascal@24476 36 ;; Known Bugs: ;;
pascal@24476 37 ;; ~~~~~~~~~~~ ;;
pascal@24476 38 ;; - All bugs are fixed as far as I know. The boot sector has been tested ;;
pascal@24476 39 ;; on my HDD and an 8GB USB stick. ;;
pascal@24476 40 ;; ;;
pascal@24476 41 ;; ;;
pascal@24476 42 ;; Memory Layout: ;;
pascal@24476 43 ;; ~~~~~~~~~~~~~~ ;;
pascal@24476 44 ;; The diagram below shows the typical memory layout. The actual location ;;
pascal@24476 45 ;; of the boot sector and its stack may be lower than A0000H if the BIOS ;;
pascal@24476 46 ;; reserves memory for its Extended BIOS Data Area just below A0000H and ;;
pascal@24476 47 ;; reports less than 640 KB of RAM via its Int 12H function. ;;
pascal@24476 48 ;; ;;
pascal@24476 49 ;; physical address ;;
pascal@24476 50 ;; +------------------------+ 00000H ;;
pascal@24476 51 ;; | Interrupt Vector Table | ;;
pascal@24476 52 ;; +------------------------+ 00400H ;;
pascal@24476 53 ;; | BIOS Data Area | ;;
pascal@24476 54 ;; +------------------------+ 00500H ;;
pascal@24476 55 ;; | PrtScr Status / Unused | ;;
pascal@24476 56 ;; +------------------------+ 00600H ;;
pascal@24476 57 ;; | Loaded Image | ;;
pascal@24476 58 ;; +------------------------+ nnnnnH ;;
pascal@24476 59 ;; | Available Memory | ;;
pascal@25460 60 ;; +------------------------+ A0000H - 1KB ;;
pascal@24476 61 ;; | Boot Sector | ;;
pascal@25460 62 ;; +------------------------+ A0000H - 0.5KB ;;
pascal@25460 63 ;; | 0.5KB Boot Stack | ;;
pascal@24476 64 ;; +------------------------+ A0000H ;;
pascal@24476 65 ;; | Video RAM | ;;
pascal@24476 66 ;; ;;
pascal@24476 67 ;; ;;
pascal@24476 68 ;; Boot Image Startup (register values): ;;
pascal@24476 69 ;; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ;;
pascal@24945 70 ;; ax = 0ffffh (both FCB in the PSP don't have a valid drive identifier), ;;
pascal@25454 71 ;; bx = 0, dl = BIOS boot drive number (e.g. 0, 80H) ;;
pascal@24476 72 ;; cs:ip = program entry point ;;
pascal@24476 73 ;; ss:sp = program stack (don't confuse with boot sector's stack) ;;
pascal@24476 74 ;; COM program defaults: cs = ds = es = ss = 50h, sp = 0, ip = 100h ;;
pascal@24476 75 ;; EXE program defaults: ds = es = EXE data - 10h (fake MS-DOS psp), ;;
pascal@24476 76 ;; cs:ip and ss:sp depends on EXE header ;;
pascal@24476 77 ;; Magic numbers: ;;
pascal@24476 78 ;; si = 16381 (prime number 2**14-3) ;;
pascal@24476 79 ;; di = 32749 (prime number 2**15-19) ;;
pascal@24476 80 ;; bp = 65521 (prime number 2**16-15) ;;
pascal@24476 81 ;; The magic numbers let the program know whether it has been loaded by ;;
pascal@24476 82 ;; this boot sector or by MS-DOS, which may be handy for universal, bare- ;;
pascal@24476 83 ;; metal and MS-DOS programs. ;;
pascal@24945 84 ;; The command line contains no arguments. ;;
pascal@24476 85 ;; ;;
pascal@24476 86 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 87
pascal@24491 88 %define bx(label) bx+label-boot
pascal@25449 89 %define si(label) si+label-boot
pascal@25485 90 ExtraBootSector equ 1
pascal@25449 91 ClusterMask equ 1 ; +9 bytes
pascal@25460 92 NullEntryCheck equ 1 ; +5 bytes
pascal@25572 93 CheckAttrib equ 0 ; +6 bytes
pascal@25569 94 NonMirroredFATs equ 1 ; +20 bytes
pascal@25569 95 ReadRetry equ 1 ; +6/7 bytes
pascal@25569 96 LBA48bits equ 1 ; +10 bytes
pascal@25569 97 CHSsupport equ 1 ; +35 bytes max 8GB
pascal@25569 98 CHSgeometryCheck equ 1 ; +20 bytes
pascal@25569 99 CHSsanityCheck equ 1 ; +9 bytes
pascal@25569 100 SectorOf512Bytes equ 0 ; -4 bytes
pascal@25458 101 Always2FATs equ 0 ; -4 bytes
pascal@25564 102 WaitForKey equ 0 ; +5 bytes
pascal@24491 103
pascal@24476 104 [BITS 16]
pascal@25564 105 [CPU 386]
pascal@24476 106
pascal@24478 107 ImageLoadSeg equ 60h ; <=07Fh because of "push byte ImageLoadSeg" instructions
pascal@25460 108 StackSize equ 512
pascal@24476 109
pascal@24476 110 [SECTION .text]
pascal@24476 111 [ORG 0]
pascal@24476 112
pascal@24476 113 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 114 ;; Boot sector starts here ;;
pascal@24476 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 116
pascal@24491 117 boot:
pascal@25458 118 DriveNumber equ boot+0
pascal@25458 119 HiLBA equ boot+2
pascal@24476 120 jmp short start ; MS-DOS/Windows checks for this jump
pascal@24476 121 nop
pascal@24476 122 bsOemName DB "BootProg" ; 0x03
pascal@24476 123
pascal@24476 124 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 125 ;; BPB1 starts here ;;
pascal@24476 126 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 127
pascal@25564 128 bpbBytesPerSector DW 0 ; 0x0B 512, 1024, 2048 or 4096
pascal@25564 129 bpbSectorsPerCluster DB 0 ; 0x0D 1, 2, 4, 8, 16, 32, 64 or 128
pascal@25564 130 bpbReservedSectors DW 0 ; 0x0E 32
pascal@25564 131 bpbNumberOfFATs DB 0 ; 0x10 2
pascal@25564 132 bpbRootEntries DW 0 ; 0x11 0
pascal@25564 133 bpbTotalSectors DW 0 ; 0x13 0
pascal@25564 134 bpbMedia DB 0 ; 0x15 F8, F0
pascal@25564 135 bpbSectorsPerFAT DW 0 ; 0x16 0
pascal@24479 136 bpbSectorsPerTrack DW 0 ; 0x18
pascal@24479 137 bpbHeadsPerCylinder DW 0 ; 0x1A
pascal@24479 138 bpbHiddenSectors DD 0 ; 0x1C
pascal@24479 139 bpbTotalSectorsBig DD 0 ; 0x20
pascal@24476 140
pascal@24476 141 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 142 ;; BPB1 ends here ;;
pascal@24476 143 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 144
pascal@24476 145 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 146 ;; BPB2 starts here ;;
pascal@24476 147 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 148
pascal@24479 149 bsSectorsPerFAT32 DD 0 ; 0x24
pascal@24479 150 bsExtendedFlags DW 0 ; 0x28
pascal@24479 151 bsFSVersion DW 0 ; 0x2A
pascal@24479 152 bsRootDirectoryClusterNo DD 0 ; 0x2C
pascal@24479 153 bsFSInfoSectorNo DW 0 ; 0x30
pascal@24479 154 bsBackupBootSectorNo DW 0 ; 0x32
pascal@24479 155 bsreserved times 12 DB 0 ; 0x34
pascal@24479 156 bsDriveNumber DB 0 ; 0x40
pascal@24479 157 bsreserved1 DB 0 ; 0x41
pascal@25564 158 bsExtendedBootSignature DB 0 ; 0x42 29
pascal@24479 159 bsVolumeSerialNumber DD 0 ; 0x43
pascal@25458 160 bsVolumeLabel times 11 DB " " ; 0x47 "NO NAME "
pascal@25458 161 bsFileSystemName times 8 DB " " ; 0x52 "FAT32 "
pascal@24476 162
pascal@24476 163 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 164 ;; BPB2 ends here ;;
pascal@24476 165 ;;;;;;;;;;;;;;;;;;;;
pascal@24476 166
pascal@24476 167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 168 ;; Boot sector code starts here ;;
pascal@24476 169 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 170
pascal@24476 171 start:
pascal@24476 172 cld
pascal@24476 173
pascal@24476 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 175 ;; How much RAM is there? ;;
pascal@24476 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 177
pascal@24476 178 int 12h ; get conventional memory size (in KBs)
pascal@25460 179 dec ax ; reserve 1K bytes for the code and the stack
pascal@24525 180 mov cx, 106h
pascal@24525 181 shl ax, cl ; and convert it to 16-byte paragraphs
pascal@24476 182
pascal@24476 183 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 184 ;; Reserve memory for the boot sector and its stack ;;
pascal@24476 185 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 186
pascal@24525 187 mov es, ax ; cs:0 = ds:0 = ss:0 -> top - 512 - StackSize
pascal@25485 188 %if ExtraBootSector == 0
pascal@24525 189 mov ss, ax
pascal@24525 190 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@25485 191 %endif
pascal@24476 192
pascal@24476 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 194 ;; Copy ourselves to top of memory ;;
pascal@24476 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 196
pascal@24476 197 mov si, 7C00h
pascal@24476 198 xor di, di
pascal@24476 199 mov ds, di
pascal@25449 200 push es
pascal@25449 201 mov [si(DriveNumber)], dx ; store BIOS boot drive number
pascal@24478 202 rep movsw
pascal@24476 203
pascal@24476 204 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 205 ;; Jump to the copy ;;
pascal@24476 206 ;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 207
pascal@25486 208 %if ExtraBootSector != 0
pascal@25486 209 push word main
pascal@25486 210 %else
pascal@25450 211 push byte main
pascal@25486 212 %endif
pascal@24476 213 retf
pascal@24476 214
pascal@25486 215 %if ExtraBootSector != 0
pascal@25486 216 %macro MovedCode 0
pascal@25486 217 %endif
pascal@24476 218 main:
pascal@25485 219 %if ExtraBootSector != 0
pascal@25485 220 add al, 32
pascal@25564 221 push ax
pascal@25564 222 %endif
pascal@25564 223 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 224 ;; Get drive parameters ;;
pascal@25564 225 ;; Update heads count ;;
pascal@25564 226 ;; for current BIOS ;;
pascal@25564 227 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 228
pascal@25564 229 %if CHSgeometryCheck != 0
pascal@25564 230 mov ah, 8 ; update AX,BL,CX,DX,DI, and ES registers
pascal@25564 231 int 13h ; may destroy SI,BP, and DS registers
pascal@25564 232 %endif
pascal@25564 233 push cs
pascal@25564 234 pop ds
pascal@25564 235 xor ebx, ebx
pascal@25564 236
pascal@25564 237 %if CHSgeometryCheck != 0
pascal@25564 238 and cx, byte 3Fh
pascal@25564 239 je BadParams ; verify updated and validity
pascal@25564 240 mov [bx(bpbSectorsPerTrack)], cx
pascal@25564 241 mov cl, dh
pascal@25564 242 inc cx
pascal@25564 243 mov [bx(bpbHeadsPerCylinder)], cx
pascal@25564 244 xor cx, cx
pascal@25564 245 BadParams:
pascal@25564 246 %endif
pascal@25564 247 %if ExtraBootSector != 0
pascal@25564 248 pop es
pascal@25564 249 mul ebx ; edx:eax = 0
pascal@25564 250 inc ax
pascal@25485 251 call ReadSectorBoot
pascal@25485 252 push ds
pascal@25485 253 pop ss
pascal@25485 254 mov sp, 512+StackSize ; bytes 0-511 are reserved for the boot code
pascal@25485 255 %endif
pascal@24476 256
pascal@25449 257 %if ClusterMask != 0
pascal@24491 258 and byte [bx(bsRootDirectoryClusterNo+3)], 0Fh ; mask cluster value
pascal@25449 259 %endif
pascal@24491 260 mov esi, [bx(bsRootDirectoryClusterNo)] ; esi=cluster # of root dir
pascal@24476 261
pascal@24478 262 push byte ImageLoadSeg
pascal@24478 263 pop es
pascal@25449 264
pascal@25449 265 RootDirReadContinue:
pascal@25458 266 call ReadClusterSector ; read one sector of the root dir
pascal@24476 267
pascal@24476 268 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 269 ;; Look for the COM/EXE file to load and run ;;
pascal@24476 270 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 271
pascal@24476 272 xor di, di ; es:di -> root entries array
pascal@24476 273
pascal@24476 274 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 275 ;; Looks for a file/dir by its name ;;
pascal@24476 276 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 277 ;; Input: DS:SI -> file name (11 chars) ;;
pascal@24478 278 ;; ES:DI -> root directory array ;;
pascal@24525 279 ;; BP = paragraphs in sector ;;
pascal@24476 280 ;; Output: ESI = cluster number ;;
pascal@24476 281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 282
pascal@24476 283 FindNameCycle:
pascal@25449 284 %if NullEntryCheck != 0
pascal@24525 285 cmp byte [es:di], bh
pascal@24478 286 je ErrFind ; end of root directory (NULL entry found)
pascal@25449 287 %endif
pascal@24478 288 pusha
pascal@25454 289 mov cl, NameLength
pascal@24525 290 mov si, ProgramName ; ds:si -> program name
pascal@24476 291 repe cmpsb
pascal@25467 292 VolumeLabel equ 8
pascal@25467 293 SubDirectory equ 10h
pascal@25564 294 %if CheckAttrib != 0
pascal@25467 295 jnz SkipFindName
pascal@25467 296 test byte [es:di], VolumeLabel+SubDirectory
pascal@25467 297 SkipFindName:
pascal@25467 298 %endif
pascal@24525 299 je FindNameFound
pascal@24478 300 popa
pascal@24525 301 add di, byte 32
pascal@24476 302 dec bp
pascal@24476 303 dec bp
pascal@24476 304 jnz FindNameCycle ; next root entry
pascal@25458 305 loop RootDirReadContinue ; next sector in cluster
pascal@25458 306 cmp esi, 0FFFFFF6h ; carry=0 if last cluster, and carry=1 otherwise
pascal@25458 307 jnc RootDirReadContinue ; continue to the next root dir cluster
pascal@24478 308 ErrFind:
pascal@24478 309 call Error ; end of root directory (dir end reached)
pascal@24476 310 db "File not found."
pascal@25564 311 %if ExtraBootSector != 0
pascal@25564 312 %endm
pascal@25564 313 %macro BootFileName 0
pascal@25564 314 %endif
pascal@24476 315 FindNameFound:
pascal@24525 316 push word [es:di+14h-11]
pascal@24525 317 push word [es:di+1Ah-11]
pascal@24478 318 pop esi ; esi = cluster no. cx = 0
pascal@24476 319
pascal@24525 320 dec dword [es:di+1Ch-11] ; load ((n - 1)/256)*16 +1 paragraphs
pascal@24525 321 imul di, [es:di+1Ch+1-11], byte 16 ; file size in paragraphs (full pages)
pascal@24476 322
pascal@24476 323 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 324 ;; Load the entire file ;;
pascal@24476 325 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 326
pascal@24476 327 push es
pascal@24476 328 FileReadContinue:
pascal@24476 329 push di
pascal@25458 330 call ReadClusterSector ; read one sector of the boot file
pascal@25458 331 dec cx
pascal@24476 332 mov di, es
pascal@24478 333 add di, bp
pascal@24478 334 mov es, di ; es:bx updated
pascal@24476 335 pop di
pascal@24478 336
pascal@24476 337 sub di, bp
pascal@24476 338 jae FileReadContinue
pascal@24943 339 xor ax, ax
pascal@24476 340 pop bp
pascal@24476 341
pascal@24476 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 343 ;; Type detection, .COM or .EXE? ;;
pascal@24476 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 345
pascal@24476 346 mov ds, bp ; bp=ds=seg the file is loaded to
pascal@24535 347
pascal@24476 348 add bp, [bx+08h] ; bp = image base
pascal@24476 349 mov di, [bx+18h] ; di = reloc table pointer
pascal@24476 350
pascal@24476 351 cmp word [bx], 5A4Dh ; "MZ" signature?
pascal@24476 352 je RelocateEXE ; yes, it's an EXE program
pascal@24476 353
pascal@24476 354 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 355 ;; Setup and run a .COM program ;;
pascal@24535 356 ;; Set CS=DS=ES=SS SP=0 IP=100h ;;
pascal@25454 357 ;; AX=0ffffh BX=0 DX=drive and ;;
pascal@25454 358 ;; cmdline=void ;;
pascal@24476 359 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 360
pascal@24535 361 mov di, 100h ; ip
pascal@24476 362 mov bp, ImageLoadSeg-10h ; "org 100h" stuff :)
pascal@24476 363 mov ss, bp
pascal@24476 364 xor sp, sp
pascal@24476 365 push bp ; cs, ds and es
pascal@25486 366 jmp short Run
pascal@25485 367 %if ExtraBootSector != 0
pascal@25486 368 %endm
pascal@25564 369 %macro BootCode 0
pascal@25485 370 %endif
pascal@24476 371
pascal@24476 372 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 373 ;; Relocate, setup and run a .EXE program ;;
pascal@24476 374 ;; Set CS:IP, SS:SP, DS, ES and AX according ;;
pascal@24476 375 ;; to wiki.osdev.org/MZ#Initial_Program_State ;;
pascal@25454 376 ;; AX=0ffffh BX=0 DX=drive cmdline=void ;;
pascal@24476 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 378
pascal@24476 379 ReloCycle:
pascal@24476 380 add [di+2], bp ; item seg (abs)
pascal@24476 381 les si, [di] ; si = item ofs, es = item seg
pascal@24476 382 add [es:si], bp ; fixup
pascal@24525 383 scasw ; di += 2
pascal@24525 384 scasw ; point to next entry
pascal@24476 385
pascal@24476 386 RelocateEXE:
pascal@24942 387 dec word [bx+06h] ; reloc items, 32768 max (128KB table)
pascal@24942 388 jns ReloCycle
pascal@24942 389
pascal@24945 390 les si, [bx+0Eh]
pascal@24945 391 add si, bp
pascal@24945 392 mov ss, si ; ss for EXE
pascal@24945 393 mov sp, es ; sp for EXE
pascal@24476 394
pascal@24476 395 lea si, [bp-10h] ; ds and es both point to the segment
pascal@24476 396 push si ; containing the PSP structure
pascal@24476 397
pascal@24476 398 add bp, [bx+16h] ; cs for EXE
pascal@24535 399 mov di, [bx+14h] ; ip for EXE
pascal@24476 400 Run:
pascal@24476 401 pop ds
pascal@24476 402 push bp
pascal@24535 403 push di
pascal@24476 404 push ds
pascal@24476 405 pop es
pascal@24942 406 mov [80h], ax ; clear cmdline
pascal@24942 407 dec ax ; both FCB in the PSP don't have a valid drive identifier
pascal@24476 408
pascal@24476 409 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 410 ;; Set the magic numbers so the program knows that it ;;
pascal@24476 411 ;; has been loaded by this bootsector and not by MS-DOS ;;
pascal@24476 412 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 413 mov si, 16381 ; prime number 2**14-3
pascal@24476 414 mov di, 32749 ; prime number 2**15-19
pascal@24476 415 mov bp, 65521 ; prime number 2**16-15
pascal@24476 416
pascal@24476 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 418 ;; All done, transfer control to the program now ;;
pascal@24476 419 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 420 retf
pascal@25485 421 %if ExtraBootSector != 0
pascal@25485 422 %endm
pascal@25485 423 %endif
pascal@24476 424
pascal@25458 425 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 426 ;; Error Messaging Code ;;
pascal@25458 427 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 428
pascal@25458 429 Error:
pascal@25458 430 pop si
pascal@25458 431 puts:
pascal@25458 432 mov ah, 0Eh
pascal@25458 433 mov bl, 7
pascal@25458 434 lodsb
pascal@25458 435 int 10h
pascal@25458 436 cmp al, '.'
pascal@25458 437 jne puts
pascal@25564 438 %if WaitForKey != 0
pascal@25458 439 cbw
pascal@25458 440 int 16h ; wait for a key...
pascal@25458 441 int 19h ; bootstrap
pascal@25564 442 %endif
pascal@25458 443
pascal@25458 444 Stop:
pascal@25458 445 hlt
pascal@25458 446 jmp short Stop
pascal@25458 447
pascal@25458 448 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 449 ;; Reads a FAT32 sector ;;
pascal@25458 450 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 451 ;; Inout: ES:BX -> buffer ;;
pascal@25458 452 ;; EAX = prev sector ;;
pascal@25458 453 ;; CX = rem sectors in cluster ;;
pascal@25458 454 ;; ESI = next cluster ;;
pascal@25458 455 ;; Output: EAX = current sector ;;
pascal@25458 456 ;; CX = rem sectors in cluster ;;
pascal@25458 457 ;; ESI = next cluster ;;
pascal@25458 458 ;; BP -> para / sector ;;
pascal@25458 459 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 460
pascal@25458 461 ReadClusterSector:
pascal@25458 462 %if SectorOf512Bytes != 0
pascal@25458 463 mov bp, 32 ; bp = paragraphs per sector
pascal@25458 464 %else
pascal@24525 465 mov bp, [bx(bpbBytesPerSector)]
pascal@24525 466 shr bp, 4 ; bp = paragraphs per sector
pascal@25458 467 %endif
pascal@25564 468 inc eax ; adjust LBA for next sector
pascal@24525 469 inc cx
pascal@24525 470 loop ReadSectorLBA
pascal@24525 471
pascal@25449 472 mul ebx ; edx:eax = 0
pascal@25458 473 %if SectorOf512Bytes != 0
pascal@25458 474 mov al, 128 ; ax=# of FAT32 entries per sector
pascal@25458 475 %else
pascal@24945 476 imul ax, bp, byte 4 ; ax=# of FAT32 entries per sector
pascal@25458 477 %endif
pascal@24525 478 lea edi, [esi-2] ; esi=cluster #
pascal@24476 479 xchg eax, esi
pascal@24478 480 div esi ; eax=FAT sector #, edx=entry # in sector
pascal@24476 481
pascal@24525 482 imul si, dx, byte 4 ; si=entry # in sector, clear C
pascal@25485 483 %if NonMirroredFATs != 0
pascal@25564 484 cdq
pascal@25485 485 or dl, byte [bx(bsExtendedFlags)]
pascal@25485 486 jns MirroredFATs ; Non-mirrored FATs ?
pascal@25485 487 and dl, 0Fh
pascal@25485 488 imul edx, dword [bx(bsSectorsPerFAT32)] ; we need to read the active one
pascal@25485 489 add eax, edx
pascal@25485 490 MirroredFATs:
pascal@25564 491 cdq
pascal@25485 492 %else
pascal@25485 493 %if LBA48bits != 0
pascal@25564 494 cdq
pascal@25485 495 %endif
pascal@25449 496 %endif
pascal@25458 497 call ReadSectorLBAfromFAT ; read 1 FAT32 sector
pascal@24476 498
pascal@25449 499 %if ClusterMask != 0
pascal@24478 500 and byte [es:si+3], 0Fh ; mask cluster value
pascal@25449 501 %endif
pascal@24478 502 mov esi, [es:si] ; esi=next cluster #
pascal@24476 503
pascal@25458 504 %if Always2FATs != 0
pascal@25458 505 imul eax, dword [bx(bsSectorsPerFAT32)], 2
pascal@25458 506 %else
pascal@24525 507 movzx eax, byte [bx(bpbNumberOfFATs)]
pascal@24525 508 mul dword [bx(bsSectorsPerFAT32)]
pascal@25458 509 %endif
pascal@24525 510
pascal@24525 511 xchg eax, edi
pascal@25454 512 movzx ecx, byte [bx(bpbSectorsPerCluster)] ; 8..128
pascal@24945 513 mul ecx ; edx:eax=sector number in data area
pascal@24525 514 add eax, edi
pascal@24476 515
pascal@25458 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 517 ;; Reads a sector form the start of FAT ;;
pascal@25458 518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25458 519
pascal@25458 520 ReadSectorLBAfromFAT:
pascal@25449 521 %if LBA48bits != 0
pascal@25564 522 push dx
pascal@25449 523 %endif
pascal@25454 524 mov dx, [bx(bpbReservedSectors)]
pascal@25564 525 add eax, edx
pascal@25565 526 %if LBA48bits != 0
pascal@25564 527 pop dx ; 16TB FAT32 max
pascal@25564 528 adc dx, bx
pascal@25564 529 ReadSectorBoot:
pascal@25564 530 mov [bx(HiLBA)], dx
pascal@25564 531 %endif
pascal@24476 532
pascal@24478 533 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24478 534 ;; Reads a sector using BIOS Int 13h fn 42h ;;
pascal@24478 535 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@25564 536 ;; Input: EAX+EDX = LBA ;;
pascal@24478 537 ;; ES:BX -> buffer address ;;
pascal@25564 538 ;; Keep: ESI = next cluster ;;
pascal@25564 539 ;; EDI = data cluster ;;
pascal@25564 540 ;; BP = paragraphs / sector ;;
pascal@25564 541 ;; CX = sector count ;;
pascal@24478 542 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 543
pascal@24476 544 ReadSectorLBA:
pascal@25449 545 %if LBA48bits != 0
pascal@25564 546 mov dx, [bx(HiLBA)]
pascal@25564 547 %else
pascal@25564 548 xor dx, dx ; 2TB FAT32 max
pascal@25564 549 ReadSectorBoot:
pascal@25449 550 %endif
pascal@25564 551 pushad
pascal@24476 552
pascal@25564 553 add eax, [bx(bpbHiddenSectors)]
pascal@25564 554 adc dx, bx ; 2TB partition offset max
pascal@25564 555
pascal@25564 556 push edx
pascal@24478 557 push eax
pascal@24476 558 push es
pascal@24476 559 push bx
pascal@24478 560 push byte 1 ; sector count word = 1
pascal@24525 561 push byte 16 ; packet size byte = 16, reserved byte = 0
pascal@24525 562
pascal@25449 563 %if CHSsupport != 0
pascal@25449 564 ; Busybox mkdosfs creates fat32 for floppies.
pascal@25449 565 ; Floppies may support CHS only.
pascal@25564 566 %if LBA48bits != 0
pascal@25564 567 ; The following check is only useful with bpbSectorsPerTrack < 8 with disk > 4TB...
pascal@25564 568 ; setnz dl ; force cylinder overflow without divide error
pascal@25458 569 %endif
pascal@25564 570 movzx ecx, word [bx(bpbSectorsPerTrack)]
pascal@25564 571 idiv ecx
pascal@25564 572 ; eax = LBA / SPT
pascal@25564 573 ; edx = LBA % SPT = sector - 1
pascal@25449 574 inc dx
pascal@25564 575 push dx ; save sector no.
pascal@25564 576 cdq
pascal@25564 577 mov cx, word [bx(bpbHeadsPerCylinder)]
pascal@25564 578 idiv ecx
pascal@25564 579 pop cx
pascal@25564 580 ; eax = (LBA / SPT) / HPC = cylinder
pascal@25564 581 ; dl = (LBA / SPT) % HPC = head
pascal@25449 582
pascal@25458 583 xchg ch, al ; clear al
pascal@25449 584 ; ch = LSB 0...7 of cylinder no.
pascal@25564 585 %if CHSsanityCheck != 0
pascal@25564 586 shl eax, 6
pascal@25564 587 %else
pascal@25564 588 shl ax, 6
pascal@25564 589 %endif
pascal@25564 590 or cl, ah
pascal@25449 591 ; cl = MSB 8...9 of cylinder no. + sector no.
pascal@25449 592 mov dh, dl
pascal@25449 593 ; dh = head no.
pascal@25449 594 %endif
pascal@25449 595
pascal@25454 596 ReadSectorRetry:
pascal@25564 597 mov dl, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24525 598 mov si, sp
pascal@24478 599 mov ah, 42h ; ah = 42h = extended read function no.
pascal@24478 600 int 13h ; extended read sectors (DL, DS:SI)
pascal@24478 601 jnc ReadSuccess ; CF = 0 if no error
pascal@24476 602
pascal@25449 603 %if CHSsupport != 0
pascal@25572 604 mov ax, 201h ; al = sector count = 1
pascal@25572 605 ; ah = 2 = read function no.
pascal@25564 606 %if CHSsanityCheck != 0
pascal@25564 607 cmp eax, 0FFFFh ; max cylinder = 1023
pascal@25564 608 ja SkipCHS
pascal@25564 609 %endif
pascal@25449 610 int 13h ; read sectors (AL, CX, DX, ES:BX)
pascal@25449 611
pascal@25449 612 jnc ReadSuccess ; CF = 0 if no error
pascal@25564 613 SkipCHS:
pascal@25449 614 %endif
pascal@25449 615 %if ReadRetry != 0
pascal@25458 616 %if CHSsupport != 0
pascal@25449 617 cbw ; ah = 0 = reset function
pascal@25458 618 %else
pascal@24945 619 xor ax, ax ; ah = 0 = reset function
pascal@25458 620 %endif
pascal@24476 621 int 13h ; reset drive (DL)
pascal@24476 622
pascal@25457 623 dec bp ; up to 32 retries
pascal@25454 624 jnz ReadSectorRetry
pascal@25449 625 %endif
pascal@24525 626
pascal@24476 627 call Error
pascal@24476 628 db "Read error."
pascal@24476 629
pascal@24478 630 ReadSuccess:
pascal@24476 631
pascal@24476 632 popa ; sp += 16
pascal@25564 633 popad
pascal@25564 634 mov dx, [bx(DriveNumber)] ; restore BIOS boot drive number
pascal@24476 635 ret
pascal@24476 636
pascal@25486 637 %if ExtraBootSector != 0
pascal@25486 638 MovedCode
pascal@25564 639 BootCode
pascal@25486 640 %endif
pascal@25486 641
pascal@24942 642 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 643 ;; Fill free space with zeroes ;;
pascal@24942 644 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24942 645
pascal@25458 646 times (512-13-($-$$)) db 0
pascal@24476 647
pascal@24476 648 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 649 ;; Name of the file to load and run ;;
pascal@24476 650 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 651
pascal@25463 652 NameLength equ 11
pascal@25463 653 ProgramName times NameLength db 0 ; name and extension
pascal@24476 654
pascal@24476 655 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 656 ;; End of the sector ID ;;
pascal@24476 657 ;;;;;;;;;;;;;;;;;;;;;;;;;;
pascal@24476 658
pascal@25564 659 dw 0AA55h ; BIOS checks for this ID
pascal@25485 660
pascal@25485 661 %if ExtraBootSector != 0
pascal@25564 662 dd 61415252h ; "RRaA"
pascal@25564 663 BootFileName
pascal@25564 664 times (996-($-$$)) db 0
pascal@25564 665 ; dd 41617272h ; "rrAa"
pascal@25485 666 %endif